Keyboard Event + Unit Selection

[sethmachine]

Hi,

How do I make this trigger in JASS?

1. a player selects a unit (of a pre-determined type, e.g. 'hfoo')
2. the player then presses the ESC key

3. do some action if 1,2 are true

 

[IcemanBo]

scope Test initializer init

globals
    private constant integer UNIT_TYPE = 'hfoo'
endglobals

function Selection takes nothing returns boolean
    if GetUnitTypeId(GetTriggerUnit()) == UNIT_TYPE then
        call ForceUICancelBJ(GetTriggerPlayer())
        call BJDebugMsg("A " + GetObjectName(UNIT_TYPE) + " has been selected.")
        // some more actions...
    endif
    return false
endfunction

function init takes nothing returns nothing
    local trigger t = CreateTrigger()
    local integer i = 0
    loop
        call TriggerRegisterPlayerUnitEvent(t, Player(i), EVENT_PLAYER_UNIT_SELECTED, null)
        set i = i + 1
        exitwhen i > 11
    endloop
    call TriggerAddCondition(t, Filter(function Selection))
endfunction

endscope

Something like this?

 

[sethmachine]

Where is the checking that ESC key is pressed? I do not understand this...

 

[IcemanBo]

call ForceUICancelBJ(GetTriggerPlayer()) forces the player to press 'Esc'. Where is the problem?

(or maybe it's me who doesn't understand something?)

 

[Zwiebelchen]

I guess he wants to know the event for the esc button, which is "Player - Cinematic cancelled".

 

[PurgeandFire]

Hi,

How do I make this trigger in JASS?

1. a player selects a unit (of a pre-determined type, e.g. 'hfoo')
2. the player then presses the ESC key

3. do some action if 1,2 are true

I would first register when ESC is pressed (EVENT_PLAYER_END_CINEMATIC), and then I would GroupEnumUnitsSelected an see if they have that unit-type selected. It is better IMO, and easier.

 

[sethmachine]

I would first register when ESC is pressed (EVENT_PLAYER_END_CINEMATIC), and then I would GroupEnumUnitsSelected an see if they have that unit-type selected. It is better IMO, and easier.

I've never used Groups before, what does this function do?

 

[PurgeandFire]

It just enumerates through the units selected by a player and adds them to a group. You can also supply a filter to limit what units will be contained in the group. This is a rough skeleton of what the code would look like:

library SelectEscape initializer Init
    
    globals
        private group selected = CreateGroup()
    endglobals

    private function FilterGroup takes nothing returns boolean
        /* ensure that the selected unit(s) have an id of 'hfoo' */
        return GetUnitTypeId(GetFilterUnit()) == 'hfoo'
    endfunction

    private function Escape takes nothing returns boolean
        /* enumerate the units selected by the player */
        call GroupEnumUnitsSelected(selected, GetTriggerPlayer(), Filter(function FilterGroup))
        if FirstOfGroup(selected) != null then 
            /* one or more of the selected units follow the condition */
        endif
        return false
    endfunction 

    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        local integer i = 0
        loop
            exitwhen i == 12
            call TriggerRegisterPlayerEvent(t, Player(i), EVENT_PLAYER_END_CINEMATIC)
            set i = i + 1
        endloop
        call TriggerAddCondition(t, Condition(function Escape))
    endfunction

endlibrary

 

[IcemanBo]

Oh boy, stupid me. With PaF I've also understood it now.