[System] Tree Revival

[busterkomo]

A simple tree revival system.

Requirements:
TimerUtils, by Vexorian.
IsDestructableTree by PitzerMike

Code:

Library

library TreeRevival initializer Init requires TimerUtils, DestructableLib

globals
    //**Configuration***********************
    private constant boolean BIRTH_ANIMATION = true
    private constant real REVIVAL_TIME = 30.
endglobals

private function Conditions takes nothing returns boolean
    return true
endfunction
//**************************************
    
globals
    public trigger Trigger = CreateTrigger()
endglobals

private struct Data
    destructable d
endstruct

private function Enum takes nothing returns nothing
    call TriggerRegisterDeathEvent(Trigger, GetEnumDestructable())
endfunction

private function TreeFilter takes nothing returns boolean
    return IsDestructableTree(GetFilterDestructable())
endfunction

private function ReviveTree takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local Data d = GetTimerData(t)
    call DestructableRestoreLife(d.d, GetDestructableMaxLife(d.d), BIRTH_ANIMATION)
    call ReleaseTimer(t)
    call d.destroy()
    set t = null
endfunction

private function Actions takes nothing returns nothing
    local timer t = NewTimer()
    local Data d = Data.create()
    set d.d = GetDyingDestructable()
    call TimerStart(t, REVIVAL_TIME, false, function ReviveTree)
    call SetTimerData(t, d)
    set t = null
endfunction

private function Init takes nothing returns nothing
    call EnumDestructablesInRect(bj_mapInitialPlayableArea, Filter(function TreeFilter), function Enum)
    call TriggerAddAction(Trigger, function Actions)
    call TriggerAddCondition(Trigger, Condition(function Conditions))
endfunction

endlibrary

 

[TriggerHappy]

Pretty simple, not much flaws (if any) in it.

You may want to make bj_mapInitialPlayableArea configurable, some people may not want trees to revive on the whole map.

I honestly think BoolexprUtils is useless, you can literally write a true function in 5 seconds (and store it).

 

[Element of Water]

BoolexprUtils saves on memory. If everyone who needs a true boolexpr for whatever reason made their own, and you had 50 or systems in your map which did that, you'd have 50 boolexpr's created. If every spell and system used BoolexprUtils, you'd only have one. Besides, it's standard, and it's modular.

 

[aznricepuff]

Might wanna let the user specify which types of destructibles he wants to revive. He might not want to revive all trees, and not all destructibles are trees.

 

[Yixx]

Seems like an ok system, though i have a question for you:
You use BoolexprUtils, nothing wrong with it, but why still write your own Condition, always returning true then? You can either use the BOOLEXPR_TRUE, or just add no condition, right? Or is the condition there for a reason?

 

[busterkomo]

It's for configuration (someone might want the trees to only revive when their are no heroes around, for example).

 

[aznricepuff]

Man, I keep getting the feeling I've seen a system like this somewhere...but until I can verify that:

I'd like to see some more documentation, like some instructions telling people that the Conditions function is called on destructable death so they know wut it's doing there in the config section.

I'd also like to see some more flexibility when it comes to revival delay. Right now you have it so that all destructables must have the same delay.

 

[TriggerHappy]

Man, I keep getting the feeling I've seen a system like this somewhere...but until I can verify that:

I'd like to see some more documentation, like some instructions telling people that the Conditions function is called on destructable death so they know wut it's doing there in the config section.

I'd also like to see some more flexibility when it comes to revival delay. Right now you have it so that all destructables must have the same delay.

Acehart made Regrowing Trees.

 

[busterkomo]

Updated.

 

[TriggerHappy]

I really don't understand the point of this function;

//Function takes the destructable ID as a parameter and returns the time it takes to revive.
private constant function REVIVAL_TAKE takes integer i returns real
    return 30.
endfunction

 

[busterkomo]

You might want the time it takes to revive to depend on the type of tree.

 

[TriggerHappy]

You might want the time it takes to revive to depend on the type of tree.

I don't see how that would work, it always returns 30.

 

[busterkomo]

Then configure it?

 

[TriggerHappy]

Then configure it?

Dude it still makes no sense, you say it takes the destructables ID as a parameter but it does nothing, and always returns 30..

 

[Element of Water]

TriggerHappy, that function is for CONFIGURATION. You might want different types of destructables to take longer to revive, so you can put if-then-else-blocks in there to filter out different destructables. It's better than having to change the actual code.

 

[aznricepuff]

Acehart made Regrowing Trees.

Hmmm, yea I looked at the code and this script has more versatility.

My only issue with this now is that the revival time function shouldnt be constant. You don't know what people will put in there and it's completely likely that somebody might add something that invalidates it as a constant function.

 

[busterkomo]

Updated.

 

[aznricepuff]

Ok. Approved.

 

[busterkomo]

Updated to be slightly more efficient and no longer require BoolexprUtils. I still don't like how weird this looks, but there isn't really a better approach.

 

[watermelon_1234]

Is there any point for the Conditions function? (I'm just being curious.)

 

[busterkomo]

No, it's just for configuration. Someone at WC3C suggested it, and I didn't think it was a bad idea so I did it. It's for configuration.

 

[watermelon_1234]

Ah I see. Good idea then. ;D

 

[Bribe]

This doesn't look as weird:

library TreeRevival initializer Init requires TimerUtils, DestructableLib
    
//**Configuration***********************
    
    globals
        private constant boolean BIRTH_ANIMATION = true
        private constant real REVIVAL_TIME = 30.00
    endglobals

    private function Evaluate takes destructable dyingDest returns boolean
        return true
    endfunction
    
//**************************************
            
    globals
        private trigger Trigger = CreateTrigger()
        private destructable Dest = null
        private timer Timer = null
        private Data Dat = Data(0)
    endglobals

    private struct Data
        destructable d
    endstruct

    private function TreeFilter takes nothing returns boolean
        set Dest = GetFilterDestructable()
        if IsDestructableTree(Dest) then
            call TriggerRegisterDeathEvent(Trigger, Dest)
        endif
        return false
    endfunction

    private function ReviveTree takes nothing returns nothing
        set Timer = GetExpiredTimer()
        set Dat = GetTimerData(Timer)
        set Dest = Dat.d
        call DestructableRestoreLife(Dest, GetDestructableMaxLife(Dest), BIRTH_ANIMATION)
        call ReleaseTimer(Timer)
        call Dat.destroy()
    endfunction

    private function Setup takes nothing returns boolean
        set Dest = GetTriggerDestructable()
        if Evaluate(Dest) then
            set Timer = NewTimer()
            set Dat = Data.create()
            set Dat.d = Dest
            call TimerStart(Timer, REVIVAL_TIME, false, function ReviveTree)
            call SetTimerData(Timer, integer(Dat))
        endif
        return false
    endfunction

    private function Init takes nothing returns nothing
        call EnumDestructablesInRect(bj_mapInitialPlayableArea, Condition(function TreeFilter), null)
        call TriggerAddCondition(Trigger, Condition(function Setup))
    endfunction

endlibrary

 

[Prince.Zero]

it should not revive trees if units are close, you don't want units trapped in.

 

[busterkomo]

That's what the configurable condition is for.

 

[Prince.Zero]

a gui user would feel dumb by that reply
Just use one more constant boolean
and static if's in that condition whether to not revive trees if units are close.

 

[busterkomo]

I'm probably going to end up completely re-writing this script.

 

[Bribe]

Yes, please completely re-write this script.

 

[busterkomo]

Don't count on it.

 

[Nestharus]

Well, you want to be using TimerQueue for this, not TimerUtils.

I'd have to look through it more to find other probs, but that's the biggest one I see so far ;D, and the speed increase would be marginal (but it'd be nicer than spamming timers no?).

 

[Bribe]

Here is a fine re-write of this library:

library TreeReviver initializer Init requires DestructableLib, Tq

private function TreeFilter takes nothing returns boolean
    return IsDestructableTree(GetFilterDestructable())
endfunction

private struct Data extends array
    static constant real INTERVAL = 30. // Revival time
    static constant boolean SHOW_BIRTH_ANIMATION = true
    static trigger trig
    destructable d
    method expire takes nothing returns nothing
        call DestructableRestoreLife(this.d, GetDestructableMaxLife(this.d), SHOW_BIRTH_ANIMATION)
        call Tq_D(this)
    endmethod
    implement Tq
endstruct

private function TreeDeath takes nothing returns boolean
    set Data.allocate().d = GetTriggerDestructable()
    return false
endfunction

private function TreeSetup takes nothing returns nothing
    call TriggerRegisterDeathEvent(Data.trig, GetEnumDestructable())
endfunction

private function Init takes nothing returns nothing
    set Data.trig = CreateTrigger()
    call EnumDestructablesInRect(bj_mapInitialPlayableArea, Filter(function TreeFilter), function TreeSetup)
    call TriggerAddCondition(Data.trig, Condition(function TreeDeath))
endfunction

endlibrary

http://www.hiveworkshop.com/forums/jass-functions-413/system-timerqueue-187502/

 

[azlier]

I don't understand why you don't just give trig the initial value of CreateTrigger.

 

[Bribe]

The reasoning is thread OP limits. A large globals block full of CreateTriggers and InitHashtable, if packed enough, can crash the thread. This is coming from Vexorian :-/

Library initializers are called from ExecuteFunc, therefore... no thread crashing. And since this already needs an initializer (not wasting an entire thread just to create the trigger), I figure I should combine all things in one.

 

[D4RK_G4ND4LF]

not all trees have the same birth animation duration
example:
Doodads\Ashenvale\Plants\AshenCanopyTree\AshenCanopyTree0.mdl
60 seconds
Doodads\Terrain\AshenTree\AshenTree0.mdl
3 seconds
probably this even affects gameplay because of selection
no big deal but should be pointed out

 

[Bribe]

These two functions could be combined (just use the code, and use null as the filter) for less generated code and a faster initialization:

function TreeFilter, function TreeSetup.

This only works for pre-placed trees.

This doesn't destroy events of removed trees, but is there ever such a case?

 

[Switch33]

This doesn't destroy events of removed trees, but is there ever such a case?

Yes, terrain generation through triggers. Where there are new trees created later on and old ones removed.

 

[Bribe]

I suppose that could be an argument for giving this an improvement to support dynamic trees then.

 

[Bribe]

I'm going to consider this deprecated by:

http://www.hiveworkshop.com/forums/spells-569/tree-revival-1-2-3-1-a-203430/