[System] Stun

[iAyanami]

library StunSystem uses Table

//********************************************************************************
//              Stun - Version 1.2.0.0 - By iAyanami aka Ayanami
//********************************************************************************
//
//    Stun:
//         - An easy to use system that stuns units
//         - Able to keep track of the remaining stun duration
//
//    Requirements:
//         - JASS NewGen
//         - Table
//
//    Functions:
//         - Stun.apply takes unit whichUnit, real duration, boolean stack returns nothing
//           * whichUnit is the target to be stunned
//           * duration is the duration of the stun
//           * stack is to determine if the stun should be a stacking one or not
//           * true - the stun will stack, the duration of the stun will add up with the previous duration
//           * false - the stun will not stack, the unit will be stunned for the longer stun duration
//
//         - Stun.getDuration takes unit whichUnit returns real
//           * whichUnit is the target to check
//           * returns the remaining stun duration
//
//         - Stun.stop takes unit whichUnit returns nothing
//           * removes stun from the target
//
//    How to import:
//         - Copy the whole "Stun" Trigger Folder into your map
//         - Save the map. Close and re-opem the map.
//         - You should have a new unit (Stun Dummy), ability (Stun (System)) and buff (Stun (System)) created
//         - Read through the Configuration part of the code
//
//    Credits:
//         - Bribe for Table
//
//********************************************************************************
//                                CONFIGURABLES
//********************************************************************************

globals
    // timer period. lower the value, the more accurate but might cause decrease in
    // performance
    private constant real PERIOD = 0.03125

    // raw code of ability "Stun (System)"
    private constant integer ABILID = 'ASTN'
    
    // raw code of buff "Stun (System)"
    private constant integer BUFFID = 'BSTN'
    
    // raw code of unit "Stun Dummy"
    private constant integer STUNID = 'sTUN'
endglobals

//********************************************************************************
//                                     CODE
//********************************************************************************

// initialization
module Init
    private static method onInit takes nothing returns nothing
        set table = Table.create()
        set caster = CreateUnit(Player(13), STUNID, 0, 0, 0)
        
        call UnitAddAbility(caster, ABILID)
    endmethod
endmodule

struct Stun extends array
    private unit u
    private real dur

    private thistype next
    private thistype prev
    
    private static Table table
    private static timer t = CreateTimer()
    private static unit caster
    private static integer count = 0
    
    // remove the stun and deallocate
    private method destroy takes nothing returns nothing
        call UnitRemoveAbility(this.u, BUFFID)
        
        if this.next != 0 then
            set this.next.prev = this.prev
        endif
            
        set this.prev.next = this.next
        set this.dur = 0
        set this.prev = thistype(0).prev
        set thistype(0).prev = this
        
        if thistype(0).next == 0 then
            call PauseTimer(t)
        endif
            
        call table.remove(GetHandleId(this.u))
    endmethod
    
    // iterating through all instances every PERIOD
    private static method iterate takes nothing returns nothing
        local thistype this = thistype(0)
        
        loop
            set this = this.next
            exitwhen this == 0
            if this.dur <= 0 or IsUnitType(this.u, UNIT_TYPE_DEAD) or GetUnitTypeId(this.u) == 0 then
                call this.destroy()
            else
                set this.dur = this.dur - PERIOD
            endif
        endloop
    endmethod
    
    // immediately removes stun for the specified unit
    // ex: call Stun.stop(whichTarget)
    static method stop takes unit u returns nothing
        local integer id = GetHandleId(u)
        
        if table.has(id) then
            call thistype(table[id]).destroy()
        endif
    endmethod
    
    // gets the duration left for stun, not stunned units always return 0
    // ex: local real r = Stun.getDuration(whichTarget)
    static method getDuration takes unit u returns real
            return thistype(table[GetHandleId(u)]).dur
    endmethod
    
    // stunning specified target and to see if the stun is a stacking one or not
    // ex: call Stun.apply(whichTarget, 5.0, false)
    static method apply takes unit u, real dur, boolean b returns nothing
        local thistype this
        local integer id = GetHandleId(u)
        
        if table.has(id) then
            set this = table[id]
        else    
            if thistype(0).prev == 0 then
                set count = count + 1
                set this = count
            else
                set this = thistype(0).prev
                set thistype(0).prev = thistype(0).prev.prev
            endif
            
            if thistype(0).next == 0 then
                call TimerStart(t, PERIOD, true, function thistype.iterate)
            else
                set thistype(0).next.prev = this
            endif
            
            set this.next = thistype(0).next
            set thistype(0).next = this
            set this.prev = thistype(0)
            set table[id] = this
            set this.u = u
            set this.dur = 0
            
            call IssueTargetOrder(caster, "firebolt", this.u)
        endif
        
        if b and dur > 0 then
            set this.dur = this.dur + dur
        else
            if this.dur < dur then
                set this.dur = dur
            endif
        endif
    endmethod

    implement Init
endstruct

endlibrary

Examples:

Basic ability that stuns a target for 2.0 seconds and non-stacking.

• Stun
  • Events
    • Unit - A unit Starts the effect of an ability
  • Conditions
    • (Ability being cast) Equal to Stun
  • Actions
    • Custom script: call Stun.apply(GetSpellTargetUnit(), 2.0, false)

This time, a more flexible stun. Stuns depending on the caster's agility and non-stacking.

• Stun
  • Events
    • Unit - A unit Starts the effect of an ability
  • Conditions
    • (Ability being cast) Equal to Stun
  • Actions
    • Set TempInt = (Agility of (Triggering unit) (Include bonuses))
    • Custom script: call Stun.apply(GetSpellTargetUnit(), udg_TempInt, false)

Basic ability that stuns a target for 2.0 seconds and stacks.

• Stun
  • Events
    • Unit - A unit Starts the effect of an ability
  • Conditions
    • (Ability being cast) Equal to Stun
  • Actions
    • Set TempInt = (Agility of (Triggering unit) (Include bonuses))
    • Custom script: call Stun.apply(GetSpellTargetUnit(), udg_TempInt, true)

Closing:
I'm open to any more possible functions that can be implemented into this system. Do suggest some. Thanks!

Changelogs:
Version 1.2.0.0:
- Removed Alloc
- Renamed .get to .getDuration
- Renamed .use to .apply
- Made a check to start/pause timer accordingly, rather than letting it run forever
- Added a GetUnitTypeId(this.u) == 0 check
- Used a module initializer
Version 1.1.0.0:
- Fixed minor bugs
- Renamed library to StunSystem
- Added a boolean parameter to Stun.use function to allow user to specify if the stun is a stacking one or not
- Added a new function, Stun.stop which removes stun from the specified unit
Version 1.0.0.0:
- Release.

 

[Magtheridon96]

I don't recommend using the UnitAlive native (WC3 Optimizer breaks it)
Here's an idea for a function: static method stop takes nothing returns nothing

edit

You should change the first line to this: library StunSystem requires Table, Alloc (Since Stun is too generic and it's already used by J4L)

 

[Adiktuz]

hmmm... a custom stun system... might be usefull... ^_^

 

[PurgeandFire]

set u = null

Parameters don't need to be nulled.

----

Also, I didn't test it, but your system might break under certain circumstances. For example, consider this situation:

Unit gets stunned for 6 seconds. Immediately afterward, the same unit gets stunned for 1 second. The stun ends up lasting only 1 second.

You'll probably have to do something like:

if this.dur < dur then
    set this.dur = dur
endif

Or something along those lines.

EDIT: Sorry I accidentally used ljass tags instead of jass tags.

 

[iAyanami]

set u = null

Parameters don't need to be nulled.

----

Also, I didn't test it, but your system might break under certain circumstances. For example, consider this situation:

Unit gets stunned for 6 seconds. Afterward, the same unit gets stunned for 1 second. The stun ends up lasting only 1 second.

You'll probably have to do something like:
if this.dur < dur then set this.dur = dur endif

Or something along those lines.

I always used to think that a new stun would override the old one. Guess I was wrong @_@. Will fix it.

EDIT
Updated to Version 1.1.0.0

EDIT
Just want to ask, does this belong here or would the Spell Submission Section be better?

 

[Magtheridon96]

It definitely belongs here
Any vJass system/snippet that has no object data (other than an externalblock that is) belongs here

edit

Basicly, the Jass section allows you to implement systems into your maps without having to go through the trouble of handling a testmap

 

[Nestharus]

I'll make an Lua/UnitIndexer version of this =).

 

[Magtheridon96]

I'll make an Lua/UnitIndexer version of this =).

D:< That's mean!

 

[Bribe]

"if this.dur <= 0 or IsUnitType(this.u, UNIT_TYPE_DEAD) then"

This line should be appended with "or GetUnitTypeId(this.u) == 0" because, if a unit is removed or exploded, UNIT_TYPE_DEAD will return "false".

Either this or use the UnitAlive native.

 

[Magtheridon96]

Either this or use the UnitAlive native.

I'd go with "this"
The UnitAlive native should be avoided until LuckyParser is released

 

[Bribe]

If you set "dur" to 0 from within the destroy method, you can shorten this:

    static method get takes unit u returns real
        local integer id = GetHandleId(u)
        
        if table.has(id) then
            return thistype(table[id]).dur
        else
            return 0.
        endif
    endmethod

To this:

    static method get takes unit u returns real
        return thistype(table[GetHandleId(u)]).dur
    endmethod

Also, 0.03125 is more practical for the timer.

This still needs to have the GetUnitTypeId == 0 check to compliment the UNIT_TYPE_DEAD.

The timer should not *always* be running.

The initializer should be a module.

You don't need to require Alloc from this. If you recycle using the "prev" variable then you can also eliminate an array that Alloc generates.

Stun.get -> Stun.getDuration

Stun.use -> Stun.apply

 

[Adiktuz]

would using

GetUnitTypeId(u) == 0

be the same as just using

u == null?

 

[Bribe]

No, because the handle ID is not 0, because remember variables are pointers to handle IDs.

 

[iAyanami]

Updated to v1.2.0.0

 

[Bribe]

I like it. Approved.

 

[-Kobas-]

Epic script indeed
But I must report small error, in your examples you use wrong method.
Instead something likecall Stun.use(GetSpellTargetUnit(), udg_TempInt, true)
there should be call Stun.apply(GetSpellTargetUnit(), udg_TempInt, true)
It isn't big deal but still it can make trouble to some people

 

[Magtheridon96]

Nestharus, you posted in the wrong thread again ._.
Also, you should really go to sleep bro D:

 

[Nestharus]

Yea, I know, I'm hella tired =o. Haven't gone to bed yet and it's 7 am and I've been up for like 4 days straight ^)^.

 

[Laiev]

I'm with you Nestharus, you know -.- while is 11 pm to you, is 4 am for me D: and I'm always talking with you lol.

 

[Nestharus]

Design implementation of this is incorrect.

Needs to be rewritten. The design implementation of my own Stun resource is also incorrect, so both should be graveyarded in light of a good implementation.


The good implementation is a core that takes effects and applies them using a dummy caster. From here, the effect resources are just simple Lua scripts or maps with objects in them =). As there are only a limited number of effects, one thread can be created that contains all of them similar to j4l's Status resource (but better of course).


I don't have time to code this now, so whoever gets it coded first wins (unless ofc their implementation is bad, in which case I will overtake you with my own and tell you that you have been pwned, fuahahhaa). Let the best one win and let this one and mine rest in peace in the graveyard where they belong.

 

[Vinz]

Amazing.

 

[muzzel]

Congratulations, you digged out a 1.5 years old thread only to post a useless comment \o/

Btw, i dont see why anyone would need this system, as there are more powerful ones:

http://www.wc3c.net/showthread.php?p=1112491
http://www.thehelper.net/threads/status.121686/

 

[edo494]

the first one is bad because it uses hook in AutoIndex and stuff, while Nes's UnitIndexer uses check for Defend
the second one has like 600 other things that if you just want to stun units are totally useless, but it seems fine overall

 

[Magtheridon96]

Status is pretty decent for large maps with lots of spells. I rewrote it to fit my needs a long time ago~

 

[Adiktuz]

@muzzel - well, if you only need Stun and not any other, it is certainly helpful that this exist... and it's quite really easy to use too

 

[tadekza20]

sorry for my question please answer me.

When I downloaded a Jass , vJass map and testing it,I can play the map[Includ Stun System T T ],if i testing in Wolrd Editor , UMSWE the game will neviagate me to main screen of Wc3
I would like many system that Jass Vjass but i can use this Please Help Me.




[Sorry again for my English i'm verry of verry weak]

 

[edo494]

normal world editor cannot read or save maps with vJass scripts, and I think neither can UMSWE

you shoul download JNGP, which allows you to compile vJass
http://www.hiveworkshop.com/forums/...en-pack-2-0-x-beta-recruiting-testing-233145/

 

[Garodar]

Wish I can learn how to use LUA.

 

[-Kobas-]

Once again, awesome resource.
I'm using it in my new secret project and it works flawlessly so far.

I have edited code a little, and doing so I realized you could do same.
If interested you can add few lines of code that could be used displaying floating texts etc.

Now there are many systems related to ft as well so I just suggest empty function that people can use to handle them.

static method ThisNewFunction takes unit target, real duration returns nothing
     //CreateAdvancedTextTag(...
     //bla bla bla etc
     //or maybe can be used for just handling special effect on stun effect and so on
     //may be useful with some damage systems or something as well
endmethod


// static method apply takes unit u, real dur, boolean b returns nothing
// ...
     call IssueTargetOrder(caster, "firebolt", this.u)
     call ThisNewFunction(u, dur)
// ...

Just an suggestion.

 

[BPower]

Personally I dislike the idea of allowing users to change the code within the stun library.
I think it would be better to fire an Event.
Of course if you know 100% what you are doing, a simple function call is much faster.

I agree Stun is very good, aslong as you use a small clock interval (~0.03125).
However if you want to achieve a maximum of timer fidelity, you have to create one timer per unit coupled with any unit indexer.

You could add function IsUnitStunned takes unit who returns boolean

 

[iAyanami]

You could add function IsUnitStunned takes unit who returns boolean

That would be the same as getDuration() == 0, no? I mean it does look nicer on a separate function I guess.

 

[Bannar]

Many standard libraries in multiple languages, especialy libraries regarded to "containers" do have: empty/isEmpty and size/count.
How usual implementation of the former looks like? <moment of silence> Thats right, its just:

return ( m_count == 0 )

Thus I see no real reason why IsUnitStunned should not be included.

 

[BPower]

That would be the same as getDuration() == 0 , no? I mean it does look nicer on a separate function I guess.

Yes, I must have missed that one :/.

Another possibility would be to check for the the stun buff.

 

[gorillabull]

ok so why not pause the unit and create an sfx instead of require object editor data @_@

 

[muzzel]

pause is not the same as stun

Also object data is not such a bad thing.. ok when you are required to create it manually its kinda annoying, but if its generated there is not really a problem with it :>

 

[Adiktuz]

and pausing a unit produces lots of undesirable effects you know...

for a fast example: pause a unit and cast impale on it (make sure that the pause is of enough time for the impale to take effect)

Or add a timed life to a unit and pause it, the timed life will be paused too. You wouldn't want the stun to do that don't you?

 

[Almia]

Pausing a unit pauses buffs :>

ooh gorillabull wat s hapen 2 yo

 

[gorillabull]

so its a "special" stun that freezez the time around the unit i dont see a problem

 

[muzzel]

The problem is: You want a stun and you get pause.

Its like you want to buy a banana but you get an apple. Its both fruit but not the same thing.

 

[gorillabull]

ok but there are other ways to stun a unit without needing object editor data. for example you can issue it an order in short intervals for a duration

 

[Adiktuz]

You don't see a problem??? How come does a stun that pauses buff timers, delays effects of some spells (Impale for example), etc IS NOT A PROBLEM???

for example you can issue it an order in short intervals for a duration

So you'd better sacrifice in-game performance just to get rid of object data when the object data method is far more useful?

 

[Bannar]

@gorillabull Adiktuz, muzzel already given you plenty of reasons why pause != stun, I could give you plenty more, more awakrd ones thus no, pausing a unit is an unappropriate option.

 

[Menag]

Use Wurst and compiletime functions and object data is no problem. Or just go for my awesome system!

 

[Daffa]

I'm not sure if there are any more recent implementations that is stable, so I think I will select this for my stun needs for now. Looks simple enough and with 1.31+ vJass support, the whole fest of vJass needs JNGP is over. If there are newer implementations with more reliable results, I think it might be a good idea to provide links.

 

[Elprede]

@Daffa Since you are on patch 1.31, PauseUnitEx may prove to be a better alternative. No dummy units or abilities needed. However, the snippet is just the foundation.

 

[Daffa]

Holy! That's a blessing! Thanks!