[JASS] Texttag problem

[Ciebron]

Why does this give a "|c" in the start of the texttag where i create the bar?

library BarSystem needs ARGB, Table

    globals
        private integer DEFAULT_BACKGROUND_COLOR = 0xFF808080
        private integer DEFAULT_BAR_COLOR        = 0xFFFF0000
    endglobals

    interface BarInterface
        
    endinterface

    struct Bar extends BarInterface
        texttag Text
    
        unit Target
        
        integer BarSize
        integer PlayerIndex
        
        real TextSize
        
        string Txt
        string PText
        
        string BarType
        
        ARGB Color
        ARGB BackColor
        
        private boolean Locked = false
        private static integer Index = 0
        private static integer array IndexStack
        private static timer Time = CreateTimer()
        
        static method create takes string BarType,  integer BarSize, real TextSize, real x, real y returns thistype
            local thistype this  = thistype.allocate()
            
            set .Text            = CreateTextTag()
            set .BarSize         = BarSize
            set .BarType         = BarType
            set .Color           = ARGB(DEFAULT_BAR_COLOR)
            set .BackColor       = ARGB(DEFAULT_BACKGROUND_COLOR)
            set .TextSize        = TextSize
            
            call .BuildBar()
            
            call SetTextTagText(.Text, .PText, .TextSize)
            call SetTextTagColor(.Text, .BackColor.red, .BackColor.green, .BackColor.blue, .BackColor.alpha)
            call SetTextTagPos(.Text, x, y, -400)
            
            return this
        endmethod
        
        method BuildBar takes nothing returns nothing
            local integer index = 0
            
            set .PText           = ""
            
            loop
                exitwhen index >= .BarSize
                
                set .PText       = .PText + .BarType
                
                set index       = index + 1
            endloop
        endmethod
        
        method operator Value= takes integer value returns nothing
            
            if value > .BarSize then
                set value   = .BarSize
                debug call BJDebugMsg(SCOPE_PREFIX+" value > then BarSize")
            endif
            
            set .Txt        = ""
            
            set .Txt        = .Color.str(SubString(.PText,0, value))
            set .Txt        = .Txt + SubString(.PText, value, .BarSize)
            
            call SetTextTagText(.Text, .Txt, .TextSize)
        endmethod
            
        method LockToUnit takes unit u returns nothing
            set .Target = u
            set .Locked = true
            
            set .IndexStack[.Index] = this
            set .Index = .Index + 1
            
            if .Index == 1 then
                call BJDebugMsg("START")
                call TimerStart(.Time, 0.03,true,function thistype.MoveBar)
            endif
        endmethod
        
        static method MoveBar takes nothing returns nothing
            local thistype this
            local integer index = .Index - 1
            
            loop
                exitwhen index < 0
                
                set this = .IndexStack[index]
                
                call SetTextTagPos(.Text,GetUnitX(.Target),GetUnitY(.Target),-400)
                
                set index = index - 1
            endloop
        endmethod

endlibrary

 

[TriggerHappy]

It looks like the PText member is null upon creation, and you're trying to set the text to null.
That may have something to do with it, I'm not sure how texttags handle null strings.

Also, can we see the Color struct, or is that part of ARGB?

 

[Ciebron]

No its not null i set it to "" before adding the "bar text"

color and backcolor is a part of ARGB

EDIT:

well when i set the value to something the "|c" disapers.

 

[Deaod]

Let me guess, youre using "|" as the bar's base string? Well, in most WC3 strings that are displayed, "|" is used like an escape char, so to get a single "|" you actually have to use "||".

 

[Bribe]

You may eventually need to set the height-offset of those text tags depending on the elevation. I don't know how SetTextTagPos works so it could already factor in elevation, though to be sure, this is the model you would use:

globals
    private location loc = Location(0.0, 0.0)
endglobals

        static method MoveBar takes nothing returns nothing
            local thistype this
            local integer index = .Index - 1
            local real x
            local real y
            
            loop
                exitwhen index < 0
                
                set this = .IndexStack[index]
                
                set x = GetUnitX(.Target)
                set y = GetUnitY(.Target)
                call MoveLocation(loc, x, y)
                call SetTextTagPos(.Text, x, y, GetLocationZ(loc) - 400.0)
                
                set index = index - 1
            endloop
        endmethod

 

[Ciebron]

Let me guess, youre using "|" as the bar's base string? Well, in most WC3 strings that are displayed, "|" is used like an escape char, so to get a single "|" you actually have to use "||".

Nope i use " . " and " ' "

Bribe, thats not the problem but thanks anyway