[JASS] spell help

[CrueIIntentions]

Hello friend Hivers.

I am having some difficulty with this minor ability i am making. What the inteded purpose is, attacked unit moves instantly behind attacking unit.

This is what I have:

Jass

function Trig_TrigStep_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local unit c = GetAttacker()
    local real dist = 500
    local real angle = Atan2(GetUnitY(u) - GetUnitY(c), GetUnitX(u) - GetUnitX(c))
    local real x = (Cos(angle) * dist)
    local real y = (Sin(angle) * dist)
    local real a = GetUnitState(c, UNIT_STATE_LIFE) - 100
    local integer temp = GetRandomInt(1, 100)
    if temp > 15 then
        set u = null
        set c = null
        return
    endif
    call AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Blink\\BlinkTarget.mdl", u, "chest")
    call DestroyEffect( bj_lastCreatedEffect )
    call SetUnitPosition(u, x, y)
    call SetUnitState(c, UNIT_STATE_LIFE, a)
    set u = null
    set c = null
endfunction

Now, the trigger fires. But Im sent to a spot way accross the map, nowhere near the opponent. Any Ideas ( I think the " local real angle = Atan2(GetUnitY(u) - GetUnitY(c), GetUnitX(u) - GetUnitX(c))" Is what is messing my script.)?

 

[Sesamia]

The AngleBetweenPoints function is:

function AngleBetweenPoints takes location locA, location locB returns real
    return bj_RADTODEG * Atan2(GetLocationY(locB) - GetLocationY(locA), GetLocationX(locB) - GetLocationX(locA))
endfunction

The way you have it set up right now takes the angle from the attacker to the attacked unit, which would move your attacked unit a distance of 500 in the opposite direction you want to move him.

Some other things:
It seems like this could be added in a condition,

local integer temp = GetRandomInt(1, 100)
if temp > 15 then
    set u = null
    set c = null
    return
endif

function Conditions takes nothing returns boolean
    return GetRandomInt(1,100)<=15
endfunction

Instead of GetUnitState/SetUnitState for getting and setting life, you should use the function GetWidgetLife/SetWidgetLife.

local real a = GetUnitState(c, UNIT_STATE_LIFE) - 100
call SetUnitState(c, UNIT_STATE_LIFE, a)

to...

local real a=GetWidgetLife(c)-100
call SetWidgetLife(c,a)

I imagine that you want the caster to damage the enemy. Setting the unit life isn't damaging it, so the caster will not receive the kill for the unit if the unit dies. You should use UnitDamageTarget instead:

call SetWidgetLife(c,a)// change this to call UnitDamageTarget(u,c,100.,true,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_NORMAL,null)
local real a=GetWidgetLife(c)-100//Remove this line

and,

    call AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Blink\\BlinkTarget.mdl", u, "chest")
    call DestroyEffect( bj_lastCreatedEffect )

should be

    call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\NightElf\\Blink\\BlinkTarget.mdl", u, "chest"))

Edit: After looking at it again, I noticed this.

    local real x = (Cos(angle) * dist)
    local real y = (Sin(angle) * dist)
    call SetUnitPosition(u, x, y)

That's the other reason why it's not moving where you want.

 

[Maker]

    local unit u1 = GetTriggerUnit()
    local unit u2 = GetAttacker()
    local real r1 = GetUnitFacing(u1)
    local real r2 = GetUnitX(u1)
    local real r3 = GetUnitY(u1)
    local real r4 = (r1 - 180) * bj_DEGTORAD
    set r2 = r2 + 128 * Cos(r4)
    set r3 = r3 + 128 * Sin(r4)

    call SetUnitX(u2 , r2)
    call SetUnitY(u2 , r3)

    call SetUnitPosition(u2 , r2 , r3)

    call SetUnitFacing(u2 , r1)

This moves the attacking unit to the back of the attacked unit, offset by 128, based on the facing of the attacked unit.

Use either those SetUnitX/Y or SetUnitPosition. SetUnitPosition checks for collision, SetUnitX/Y does not.

I didn't remove leaks.

 

[baassee]

Doesn't SetUnitPosition interrupt the unit orders too? Very nice one Maker.

 

[Maker]

Yeah, it does. Totally forgot that

 

[xzeth]

SetUnitX and SetUnitY don't pause the unit (so don't interrupt the units orders), right?

 

[baassee]

Nothing pauses, just PauseUnit pauses a unit Nope SetUnitX/Y do not interrupts anything.

 

[Berb]

Well SetUnitPosition interrupts its current orders; even if you were moving the unit repeatedly to its own coordinates it would still maintain a "paused" state. I believe that is what was meant when xzeth commented on how SetUnitX and SetUnitY do not have any sort of pause or interruption stringed to the execution of the native.

 

[xzeth]

^ Yeah, that's what I meant.

Thanks for the information about SetUnitPosition. I thought the function pause the unit like PauseUnit.

 

[baassee]

Yeah I got it but just had to clearify else you could just order the unit to stop and count it as a "pause"