[JASS] Newbie syntax questions

[Deon]

Greetings, after a lot of time being away I finally decided to return to WC3 modding but this time I try to not to touch GUI and I've started to learn JASS.
That's the story.

Now to facts.

I want to make a trigger which loops though players, checks if they are present and gives "selector units" (currently wisps) to buy heroes from a tavern.

I have two syntax errors regarding function( parameter ), without ( parameter ) it produces no syntax errors but then it doesn't pass the parameter "i" to the function. I feel like I am doing something really stupid here, but can you answer me, why can't I use a parameter here if I specify "takes integer i" in the functions'?

//===========================================================================
// Trigger: GiveSelectors
//===========================================================================
function Trig_GiveSelectors_Conditions takes integer i returns boolean
    if ( not ( GetPlayerSlotState(Player(i)) == PLAYER_SLOT_STATE_PLAYING ) ) then
        return false
    endif
    return true
endfunction

function Trig_GiveSelectors_Actions takes integer i returns nothing
    call CreateNUnitsAtLocFacingLocBJ( 1, 'ewsp', Player(i), GetRectCenter(gg_rct_HumansSpawn), GetRectCenter(GetPlayableMapRect()) )
endfunction

//===========================================================================
function InitTrig_GiveSelectors takes nothing returns nothing
    local integer i = 0
    set gg_trg_GiveSelectors = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_GiveSelectors, 1.00 )
    loop
    exitwhen i > 9
(!)     call TriggerAddCondition( gg_trg_GiveSelectors, Condition( function Trig_GiveSelectors_Conditions(i) ) )
(!)     call TriggerAddAction( gg_trg_GiveSelectors, function Trig_GiveSelectors_Actions(i) )
    set i = i + 1
    endloop
endfunction

//===========================================================================

(!) indicate 2 strings with errors (there're not present in the actual jass text).

 

[Pharaoh_]

Why do you set that i from the loop into a parenthesis for the conditions and the actions part? They are already supposed to be in the loop, meaning instantly affected by it.

 

[Deon]

Damn it... Does it mean that the functions I use within the InitTrig_GiveSelectors function use all the local variables of InitTrig_GiveSelectors automatically? I thought you have to pass the desired variables as parameters.

 

[Pharaoh_]

It depends; I mean, if you had this:

call GroupEnumUnitsOfPlayer( ENUM, Player( i ), b )

Then yes, that "i" should be inserted, because you clearly make a reference to all those players.

 

[Deon]

Let me rephrase the question and please try to ask it carefully, or I could misunderstand it...

For example I have this:

function MyMainFunction takes nothing returns nothing
    local integer MyVar
    call TriggerAddCondition( gg_trg_MyTrigger, Condition( function Trig_Mytrigger_Conditions ) )
endfunction

Does it mean that if Trig_Mytrigger_conditions is defined as:

function Trig_MyTrigger_Conditions takes integer MyVar returns boolean

then it automatically "takes integer MyVar" and any other variable it takes from the MyMainFunction without a need to specify it as a parameter?

I have some kind of a habit from C programming language: if a function is defined to take some parameter and the parameter is not defined in function(parameter), then it's considered to be NULL.

Also, how do I make a function to take multiple variables in a right way?

function AwesomeSauce takes integer MyVar1, string MyVar2, boolean Bool1 returns nothing

^^ like this?

P.S. And a bit offtopic question, but it still relates to JASS. How should I save my scripts to a map file? I've extracted war3map.j and changed it, but JassCraft gives me an access violation related to SFmpq.dll and doesn't want to save.

 

[krisserz]

^^ like this?

Yes, it`s like that.

Also I`d make loop inside actions instead of trigger initialization.

 

[Pharaoh_]

No, no, you need them, I'm sorry I misunderstood completely. You really need the (i) ones, they do not get automatically applied on the actions and conditions, I'm sorry for the misleading.

Now wait a min, I am working on it.

 

[Deon]

The problem is that those (i) cause syntax error.

Also, how do I get the JASS code into the map?

 

[krisserz]

CnP into converted trigger.

EDIT: This trigger shoud work

//===========================================================================
// Trigger: GiveSelectors
//===========================================================================
function Condition1 takes player WhichPlayer returns boolean
    return GetPlayerSlotState (WhichPlayer) == PLAYER_SLOT_STATE_PLAYING
endfunction

function Actions takes nothing returns nothing
    local integer i = 0
    local player p
    
    loop 
            exitwhen i > 9
        set p = Player (i)
            if Condition1 (p) then
                call CreateUnitAtLoc (p, 'hpea', GetRectCenter (GetPlayableMapRect()), 0.)
            endif
        set i = i+1
            
    endloop
    set p =null
endfunction

//===========================================================================
function InitTrig_GiveSelectors takes nothing returns nothing
    set gg_trg_GiveSelectors = CreateTrigger(  )
    call TriggerRegisterTimerEventSingle( gg_trg_GiveSelectors, 1.00 )
    call TriggerAddAction (gg_trg_GiveSelectors, function Actions)
endfunction

//===========================================================================

 

[Pharaoh_]

Yes, good job Krisserz, I was up to something like that myself, that (i) tortured me :S

 

[Deon]

It looks nice. I guess I should learn some "simply thinking" to avoid shitcoding.

Still ,can you answer me please, how to get my code in the map please?

 

[Pharaoh_]

He told you already
Create a new trigger, go to Edit -> Convert to Custom text, delete them all and paste the code in the blank code sheet.

 

[krisserz]

CnP into converted trigger.

That`s the answer, isn`t it?

 

[Deon]

NEVERMIND. One big baargh. Sorry.

 

[krisserz]

Is the name of the trigger you created 'GiveSelectors'?

 

[Pharaoh_]

Yes, you do
View attachment lolen.w3m

 

[Deon]

Is the name of the trigger you created 'GiveSelectors'?

Yes it is.

But the problem was that I've managed to modify war3map.j in the testmap.w3x and made a few erros there.

You never know where noobs fail again .

Thank you very much, everyone! You were really helpful.

 

[watermelon_1234]

If you really intend to use Jass, you are also able to optimize your code:

//===========================================================================
// Trigger: GiveSelectors
//===========================================================================
function Actions takes nothing returns nothing
    local integer i = 0
    loop 
        exitwhen i > 9
        if GetPlayerSlotState(Player(i)) == PLAYER_SLOT_STATE_PLAYING then
            call CreateUnit(Player(i), 'hpea', GetRectCenterX(bj_mapInitialPlayableArea),GetRectCenterY(bj_mapInitialPlayableArea) , 0.)
        endif
        set i = i+1            
    endloop
endfunction
//===========================================================================
function InitTrig_GiveSelectors takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterTimerEvent( t, 1.00, false)
    call TriggerAddAction (t, function Actions)
endfunction
//===========================================================================

This code gets rid of the usage of BJ's, functions that call the natives to perform, and locations, which can cause leaks in your code if not handled properly.
You should also notice that you can directly implement Condition1 into the if-statement.
I also get rid of player p as it was used only two times in the function, but that's pretty much optional.
Though it wasn't done in my example, you can alternatively use TriggerAddCondition and made the function Actions act like one. The changes would be

function Actions takes nothing returns boolean

with
return false right before endfunction
and use call TriggerAddCondition (t, Condition(function Actions)) instead of TriggerAddAction. The reason for doing so is that trigger conditions are faster than trigger actions.
You may also want to learn vJass to make coding easier.