library Table
//***************************************************************
//* Table object 3.0
//* ------------
//*
//* set t=Table.create() - instanceates a new table object
//* call t.destroy() - destroys it
//* t[1234567] - Get value for key 1234567
//* (zero if not assigned previously)
//* set t[12341]=32 - Assigning it.
//* call t.flush(12341) - Flushes the stored value, so it
//* doesn't use any more memory
//* t.exists(32) - Was key 32 assigned? Notice
//* that flush() unassigns values.
//* call t.reset() - Flushes the whole contents of the
//* Table.
//*
//* call t.destroy() - Does reset() and also recycles the id.
//*
//* If you use HandleTable instead of Table, it is the same
//* but it uses handles as keys, the same with StringTable.
//*
//* You can use Table on structs' onInit if the struct is
//* placed in a library that requires Table or outside a library.
//*
//* You can also do 2D array syntax if you want to touch
//* mission keys directly, however, since this is shared space
//* you may want to prefix your mission keys accordingly:
//*
//* set Table["thisstring"][ 7 ] = 2
//* set Table["thisstring"][ 5 ] = Table["thisstring"][7]
//*
//***************************************************************
//=============================================================
globals
private constant integer MAX_INSTANCES=8100 //400000
//Feel free to change max instances if necessary, it will only affect allocation
//speed which shouldn't matter that much.
//=========================================================
private hashtable ht
endglobals
private struct GTable[MAX_INSTANCES]
method reset takes nothing returns nothing
call FlushChildHashtable(ht, integer(this) )
endmethod
private method onDestroy takes nothing returns nothing
call this.reset()
endmethod
//=============================================================
// initialize it all.
//
private static method onInit takes nothing returns nothing
set ht = InitHashtable()
endmethod
endstruct
//Hey: Don't instanciate other people's textmacros that you are not supposed to, thanks.
#bigdef TABLE_MACRO(NAME, TYPE, KEY)
struct NAME extends GTable
method operator [] takes TYPE key returns integer
return LoadInteger(ht, integer(this), KEY)
endmethod
method operator []= takes TYPE key, integer value returns nothing
call SaveInteger(ht, integer(this) ,KEY, value)
endmethod
method flush takes TYPE key returns nothing
call RemoveSavedInteger(ht, integer(this), KEY)
endmethod
method exists takes TYPE key returns boolean
return HaveSavedInteger( ht, integer(this) ,KEY)
endmethod
static method flush2D takes string firstkey returns nothing
call NAME(- StringHash(firstkey)).reset()
endmethod
static method operator [] takes string firstkey returns NAME
return NAME(- StringHash(firstkey) )
endmethod
endstruct
#endbigdef
TABLE_MACRO(Table, integer, key)
TABLE_MACRO(StringTable, string, StringHash(key))
TABLE_MACRO(HandleTable, handle, GetHandleId(key))
endlibrary
