What. The. actual. fuck

How have I missed this native O_O
Honestly, this is a must have in any RPG map.

I think the init could be improved greatly however.
Instead of making copy pasted function calls after every variable, use an array of names and loop through them at the end. This will make the trigger considerably shorter

 

Good catch. Will add that as well as more documentation I suppose, either later today or more likely tomorrow.

It's a bit bare bones at the moment but I'm not sure what more configurable or use cases that are needed. I'd appreciate any ideas.

Update: 0.03

Added support for Unit Indexer event, as well as different ways to set a random name of a unit. You can now also give a specific name to any unit, and keep track of the default name or the rp name of a unit using two variables.

I'm considering adding show/hide unit name functionality as a final thing, which made me wonder if local unit name changes would work or cause a desync. Something like this:

Code (vJASS):

if (p == GetLocalPlayer()) then
     call BlzSetUnitName(u, name)
endif

Update: 0.06

I consider it somewhat finished now, don't have any pressing changes that I wish to add other than enabling prioritization of unused names over used ones, but that's something I'm not looking to start on any time soon.

 

I still think you're complicating the setup.

I'd imagine the following:
unit = paladin
name[1] = "something"
name[2] = "something else"
call setupUnit()

setupUnit would loop through the name variable and store the names with the unit id as primary key.

number of custom scripts (that the user have to use) should be limited for GUI systems

 

The biggest argument for this would be to reduce the number of function calls (which if the setup is long might be a problem). But the downside would be that you'd have to edit 2 things instead of 1 (name and number) if you want something changed. You'd also need a array list for the unit-types in case you want multiple units with similar names. Can't really decide which optimization I prefer.

 

What about a //! call that allows you to load an external .txt file with unit types and names in like a csv format? I'm not all about that but there has to be a way to parse the file into arrays of unit names. Maybe even a few proper user-end textmacroes would help here.

 

It is just that I'd never used this, thinking back to when I was a filthy GUI user.
Editing custom scripts was a huge turnoff and was something I only would consider if I was really desperate.

So, I think you should decide on your target audience here.
If you target jass users this is a bothersome way of doing it, and for pure GUIers it is also not ideal.
So it is kinda inconvenient for both instead of good for one and bad for the other.

 

I would love to see something like that and can think of many use cases for it, but I'm afraid I won't be the one able to implement it.

The options are the following each with pros and cons, perhaps the left and right ones being the clearer options. I can see why a jasser would prefer the left one as text editing isnt as annoying but I would probably just add parameters to the existing functions or lifting out the HashSaving entierly rather than storing them in temporary variables.


What about this one then?

 

I'd think of having them just run a trigger that ends up calling said function. The drawback is that the function must be moved to the map header.
It's something I learned while making GUI Friendly systems.

 

Could I get any feedback on the vJass version i made? I attached a test map to it and code below temporarily until I decide what to do with the two versions.

1) Index/deindex event. Currently there is no such thing but there are API-functions to easily configure that to whatever the user has.

2) How to manage units that are not touched by the system. For example if the player uses "GetUnitNormalName" should it return null or say, GetUnitName() if not yet recorded...?

3) Is it necessary to have first name and last name as separate strings, perhaps just assume that the first name is always one word?

4) How to configure the customizeable parts

5) Would adding the possibility of picking name by frequency be a valuable addition or mostly bloat?

vJass version

Code (vJASS):

/*
    UnitNaming v 0.12
        by Pinzu
    Giving units proper hero names and other naming utilities.
 
    Requirements:
        Table by Bribe
          https://hiveworkshop.com/threads/snippet-new-table.188084/
        WorldBounds by Nestharus
          https://github.com/nestharus/JASS/blob/master/jass/Systems/WorldBounds/script.j
     
        Fantasy Name Generators by nerds all over
          http://www.fantasynamegenerators.com/
       
    Configuraton
 
        1)  After copying the library to your map you can change public globals to your chosing.
        2)  At the bottom of the code there is the Setup function, you may chose to exclude a few of
            the textmacros in case you don't wish to include things as destroy name onDeath, name
            unit onEnterMap or name all preplaced units.
    API
    ------------
    struct NamePool
    |
    | static method create takes nothing returns NamePool
    |     create a new NamePool
    |  
    | method destroy takes nothing returns nothing
    |     destroy it
    |  
    | method getRandomName takes nothing returns FullName
    |     returns a random struct containing the proper name that was configured
    |  
    | method addType takes integer unitTypeId returns thistype
    |     Adds a unit-type to this name pool, used for identification by the system
    |  
    | method removeType takes integer unitTypeId returns boolean
    |     Removes a unit-type by index from the name pool
    |  
    | method addName takes string name returns thistype
    |     Simple add (hero) name to pool, does not have any configured last name
    |  
    | method addProperName takes string firstName, string lastName returns thistype
    |     Adds a (hero) name to pool where the first name is separated from the last
    |
    | method getName takes integer index returns string
    |     Returns a proper (hero) name saved at a specific index
    |
    | method removeName takes integer index returns boolean
    |     Removes a name at a specific index
    |
    ----------------
    |
    | function SetUnitNormalName takes unit u, string normalname returns nothing
    |     Basically the same as 'BlzSetUnitName' except that it keeps the proper name if any such is set
    |
    | function GetUnitNormalName takes unit u returns string
    |     Basically the same as 'GetUnitName', excludes the proper names if such exist
    |     Note that it only works for units that have been configured by the system
    |
    | function SetUnitProperName takes unit u, string firstname, string lastname returns nothing
    |     Same as setting a heroes name, devided in first and last names
    |
    | function GetUnitProperName takes unit u returns string
    |     Returns the units proper name with both first and last name if such exist
    |
    | function GetUnitFirstName takes unit u returns string
    |     Returns the first name of the unit
    |
    | function SetUnitFirstName takes unit u, string firstname returns nothing
    |     Changes the units first name
    |
    | function GetUnitLastName takes unit u returns string
    |     Returns the last name of the unit
    |
    | function SetUnitLastName takes unit u, string lastname returns nothing
    |     Changes the units last name
    |
    | function SetUnitRandomName takes unit u returns boolean
    |     Gives a unit a random name based on the unit-type
    |     Note that if the unit-type is not configured to any unit pool the unit wont be affected
    |
    | function HasUnitName takes unit u returns boolean
    |     If the unit exists in the systems records it will return true
    |
    | function DestroyUnitName takes unit u returns nothing
    |     Used to deallocate unit names from units. Should be used on deindex event.
    |
    | function UnitTypeIsInPool takes integer unitTypeId returns boolean
    |     If the unit type has been configured to any unit pool it will return true
    ----------------
*/
library UnitNaming initializer Init uses Table, WorldBounds
    globals
        // Configuration
        public boolean keepNormalNames     = true        // considering moving this to each pool
        public boolean colorHeroes         = true         // considering moving this to each pool
        public string color                = "|cffffcc00" // considering  moving this to each pool
     
        private Table uTable  
        private integer MAX_STR_LEN        = 1000
    endglobals
 
    private struct FullName
        string first
        string last
    endstruct
 
    struct NamePool
        private Table names
        private integer namesIndex
        private Table types
        private integer typesIndex
     
        method getRandomName takes nothing returns FullName
            local integer rdm = GetRandomInt(0, .namesIndex - 1)
            return .names[rdm]
        endmethod
        private method indexOfType takes integer unitTypeId returns integer
            local integer i = 0
            loop
                exitwhen i == .typesIndex
                if (.types[i] == unitTypeId) then
                    return i
                endif
                set i = i + 1
            endloop
            return -1
        endmethod
     
        method removeType takes integer unitTypeId returns boolean
            if (uTable[unitTypeId] == this) then
                call uTable.remove(unitTypeId)
                set .typesIndex = .typesIndex - 1
                set .types[.indexOfType(unitTypeId)] = .types[.typesIndex]
                call .types.remove(.typesIndex)
                return true
            endif
            return false
        endmethod
     
        method addType takes integer unitTypeId returns thistype
            local NamePool prev = uTable[unitTypeId]
            if (uTable[unitTypeId] != null) then
                call prev.removeType(unitTypeId)
            endif
            set uTable[unitTypeId] = this
            set .types[.typesIndex] = unitTypeId
            set .typesIndex = .typesIndex + 1
            return this
        endmethod
 
        method getName takes integer index returns string
            local FullName name
            if (index >= namesIndex or index < 0) then
                return null
            endif
            set name = .names[index]
            return name.first + " " + name.last
        endmethod
     
        method addProperName takes string firstName, string lastName returns thistype
            local FullName fullName = FullName.create()
            set fullName.first =  firstName
            set fullName.last = lastName
            set .names[.namesIndex] = fullName
            set .namesIndex = .namesIndex + 1
            return this
        endmethod
     
        method addName takes string name returns thistype
            call .addProperName(name, "")
            return this
        endmethod
     
        method removeName takes integer index returns boolean
            local integer i
            local FullName fullName
            if (index >= .namesIndex or index < 0) then
                return false
            endif
            set fullName = .names[index]
            call fullName.destroy()
            loop
                exitwhen index == .namesIndex
                set .names[index] = .names[index + 1]
                set index = index + 1
            endloop
            set .namesIndex = .namesIndex - 1
            call .names.remove(.namesIndex)
            return true
        endmethod
     
        static method create takes nothing returns thistype
            local thistype this = .allocate()
            set this.names = Table.create()
            set this.namesIndex = 0
            set this.types = Table.create()
            set this.typesIndex = 0
            return this
        endmethod
     
        method onDestroy takes nothing returns nothing
            call .names.destroy()
            call .types.destroy()
        endmethod
    endstruct
 
    private struct UnitName
        string nfirst
        string nlast
        string normal
     
        method onDestroy takes nothing returns nothing
            set .nfirst = null
            set .nlast = null
            set .normal = null
        endmethod
     
        static method create takes unit u, string first, string last returns thistype
            local thistype this = .allocate()
            set this.nfirst = first
            set this.nlast = last
            if (keepNormalNames) then
                set this.normal = GetUnitName(u)
            else
                set this.normal = ""
            endif
            set uTable[GetHandleId(u)] = this
            return this
        endmethod
     
        static method get takes unit u returns thistype
            local integer id = GetHandleId(u)
            if (uTable.has(id)) then
                return uTable[id]
            endif
            return 0
        endmethod
        method setFirst takes string name returns thistype
            set .nfirst = name
            return this
        endmethod
     
        method setLast takes string name returns thistype
            set .nlast = name
            return this
        endmethod
     
        method setNormal takes string name returns thistype
            set .normal = name
            return this
        endmethod
     
        method apply takes unit u returns nothing
            if (IsUnitType(u, UNIT_TYPE_HERO)) then
                call BlzSetUnitName(u, .normal)
                if (colorHeroes) then
                    call BlzSetHeroProperName(u, color + .nfirst +  " " + .nlast + "|r")
                else
                    call BlzSetHeroProperName(u, .nfirst +  " " + .nlast)
                endif
            else
                if (StringLength(.nfirst) > 0 or StringLength(.nlast) > 0) then
                    call BlzSetUnitName(u, color + .nfirst + " " + .nlast + "|r" + "|n" + .normal)
                else
                    call BlzSetUnitName(u, .normal)
                endif
            endif
        endmethod
    endstruct
 
    function SetUnitNormalName takes unit u, string normalname returns nothing
        local UnitName uname
        local integer id = GetHandleId(u)
        if (not(uTable.has(id))) then
            if (IsUnitType(u, UNIT_TYPE_HERO)) then
                set uname = UnitName.create(u, GetHeroProperName(u), "")
            else
                set uname = UnitName.create(u, "", "")
            endif
        else
            set uname = uTable[id]
        endif
        call uname.setNormal(normalname).apply(u)
    endfunction
 
    function SetUnitProperName takes unit u, string firstname, string lastname returns nothing
        local UnitName uname
        local integer id = GetHandleId(u)
        if (not(uTable.has(id))) then
            set uname = UnitName.create(u, firstname, lastname)
        else
            set uname = uTable[id]
        endif
        call uname.setFirst(firstname).setLast(lastname).apply(u)
    endfunction
 
    function UnitTypeIsInPool takes integer unitTypeId returns boolean
        return uTable.has(unitTypeId)
    endfunction
 
    function HasUnitName takes unit u returns boolean
        return uTable.has(GetHandleId(u))
    endfunction
 
    function SetUnitRandomName takes unit u returns boolean
        local UnitName uname
        local FullName name
        local NamePool np
        local integer id = GetUnitTypeId(u)
        if (not(UnitTypeIsInPool(id))) then
            return false
        endif
        set np = uTable[id]
        set name = np.getRandomName()
        if (HasUnitName(u)) then
            set uname = uTable[GetHandleId(u)]
            call BlzSetUnitName(u, uname.normal)
            call uname.setFirst(name.first).setLast(name.last).apply(u)
        else
            set uname = UnitName.create(u, name.first, name.last)
            call uname.apply(u)
        endif
        return true
    endfunction
 
    function GetUnitProperName takes unit u returns string
        local integer id = GetHandleId(u)
        local UnitName uname
        if (not(HasUnitName(u))) then
            if (IsUnitType(u, UNIT_TYPE_HERO)) then
                return GetHeroProperName(u) // The unit doesn't have a record
            endif
            return null
        endif
        set uname = uTable[id]
        return uname.nfirst + " " + uname.nlast
    endfunction
 
    function SetUnitFirstName takes unit u, string firstname returns nothing
        local UnitName uname
        if (not(HasUnitName(u))) then
            set uname = UnitName.create(u, firstname, "")
        else
            set uname = uTable[GetHandleId(u)]
            set uname.nfirst = firstname
        endif
        call uname.apply(u)
    endfunction
 
    function SetUnitLastName takes unit u, string lastname returns nothing
        local UnitName uname
        if (not(HasUnitName(u))) then
            set uname = UnitName.create(u, "", lastname)
        else
            set uname = uTable[GetHandleId(u)]
            set uname.nlast = lastname
        endif
        call uname.apply(u)
    endfunction
 
    function GetUnitFirstName takes unit u returns string
        local UnitName uname
        if (not(HasUnitName(u))) then
            return null
        endif
        set uname = uTable[GetHandleId(u)]
        return uname.nfirst
    endfunction
 
    function GetUnitLastName takes unit u returns string
        local UnitName uname
        if (not(HasUnitName(u))) then
            return null
        endif
        set uname = uTable[GetHandleId(u)]
        return uname.nlast
    endfunction
 
    function GetUnitNormalName takes unit u returns string
        local integer id = GetHandleId(u)
        local UnitName uname
        if (not(HasUnitName(u))) then
            return GetUnitName(u) // The unit doesn't have a record
        endif
        set uname = uTable[id]
        return uname.normal
    endfunction
 
    function DestroyUnitName takes unit u returns nothing
        local integer id = GetHandleId(u)
        local UnitName uname = uTable[id]
        call uname.destroy()
        call uTable.remove(id)
    endfunction
 
    private function Init takes nothing returns nothing
        set uTable = Table.create()
    endfunction
endlibrary
 

New Setup

Code (vJASS):

scope UnigNamingSetup initializer Init
    globals
        NamePool array np[10]
    endglobals
 
    private function Main takes nothing returns nothing
        local trigger t = GetTriggeringTrigger()
        local integer i
 
        // Allocating the name pool
        set i = 0
        set np[i] = NamePool.create()
 
        // Here we are adding which unit-types will be attached to this name pool
        call np[i].addType('hfoo').addType('hkni').addType('Hpal')
 
        // We can either set up names like this,
        // which will set the proper name to only consit of a first name
        call np[i].addName("Pinzu, Just Pinzu")
 
        // Or like, which sets up names as first and last names respectivly.
        // This can then be used to address units by their first name or last name.
        // However, if you don't need this feature I'd recommend you stick to the first option.
        call np[i].addProperName("Pinzu", "San")
        set i = 1
        set np[i] = NamePool.create()
        call np[i].addType('nvil').addType('nvl2')
        call np[i].addName("Kendall Werner").addName("Raul Tindall").addName("Rodhlann Brent")
        call np[i].addName("Rodhlann Brent").addName("Quinten Reed").addName ("Wingate Burlingame")
        call np[i].addName("Jefrem Swett").addName("Hayo Dryden").addName("Tyeson Harley")
        call np[i].addName("Jan Lee").addName("Ogden Acton")
        set i = 2
        set np[i] = NamePool.create()
        call np[i].addType('nvlw').addType('nhef').addType('hsor')
        call np[i].addName("Cher Whitney").addName("Merry Sue").addName("Ashli Cooper").addName("Joanna Smythe")
        call np[i].addName("Marquise Kendall").addName("Sahra Astley").addName("Lisbeth Salander")
 
        set i = 3
        set np[i] = NamePool.create()
        call np[i].addType('nvlk').addType('nvk2')
        call np[i].addName("Dinbush Quietneedle").addName("Teendic Mekkamix").addName("Fucuzz Puddleheart").addName("Henidu Battlebrake")
 
        // deallocating the name pool
        call np[9].destroy()
 
        // Read the full API list for more functions and methods to use
 
        call DisableTrigger(t)
        call DestroyTrigger(t)
        set t = null
    endfunction
 
    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterTimerEvent(t, 0.01, false)
        call TriggerAddAction(t, function Main)
        set t = null
    endfunction
endscope
 

Sample Usage

Code (vJASS):

scope UnitNamingTest initializer Init
 
    globals
        private string array commands
        private integer array len
        private group g = CreateGroup()
        private integer max
    endglobals
 
    function GetOneSelectedPlayerUnit takes player p returns unit
        local integer count = 0
        local unit u
        local unit found
        call SyncSelections()
        call GroupEnumUnitsSelected(g, p, null)
        loop
            set u = FirstOfGroup(g)
            exitwhen u == null
            call GroupRemoveUnit(g, u)
            if GetOwningPlayer(u) == p then
                set count = count + 1
                if count == 1 then
                    set found = u
                else
                    set found = null
                endif
            endif
        endloop
        return found
    endfunction
 
    /* Changes first name */
    private function cmd0 takes string s returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call SetUnitFirstName(u, s)
        set u = null
    endfunction
 
    /* Changes last name */
    private function cmd1 takes string s returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call SetUnitLastName(u, s)
        set u = null
    endfunction
 
    /* Changes unit name */
    private function cmd2 takes string s returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call SetUnitNormalName(u,s)
        set u = null
    endfunction
 
    /* Changes unit proper name  */
    private function cmd3 takes string s returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call SetUnitProperName(u, "Proper firstname", "Proper lastname")
        set u = null
    endfunction
 
    /* Set new random name */
    private function cmd4 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        local boolean success = SetUnitRandomName(u)
        if (not(success)) then
            call BJDebugMsg("This unit cannot be renamed")
        else
            call BJDebugMsg("Renaming unit from " + GetUnitNormalName(u))
        endif
        set u = null
    endfunction
 
    /* Retrieves first name */
    private function cmd5 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call BJDebugMsg("First name: " + GetUnitFirstName(u))
        set u = null
    endfunction
 
    /* Retrieves first name */
    private function cmd6 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call BJDebugMsg("Last name: " + GetUnitLastName(u))
        set u = null
    endfunction
 
    /* Retrieves unit name */
    private function cmd7 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call BJDebugMsg("Unit name: " + GetUnitNormalName(u))
        set u = null
    endfunction
 
    /* Retrieves unit name */
    private function cmd8 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call BJDebugMsg("Proper name: " + GetUnitNormalName(u))
        set u = null
    endfunction
 
    /* Checkes the unit state as it relates to the system */
    private function cmd9 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        if (HasUnitName(u)) then
            call BJDebugMsg("Has name")
        else
            call BJDebugMsg("No name")
        endif
        if (UnitTypeIsInPool(GetUnitTypeId(u))) then
            call BJDebugMsg("Unit type exists")
        else
            call BJDebugMsg("Unit type doesn't exist")
        endif
        set u = null
    endfunction
 
    /* Destroys UnitName (does not affect the current unit name though) */
    private function cmd10 takes nothing returns nothing
        local unit u = GetOneSelectedPlayerUnit(GetTriggerPlayer())
        call BJDebugMsg("Proper name: " + GetUnitNormalName(u))
        set u = null
    endfunction
 
    private function Main takes nothing returns nothing
        local string s = GetEventPlayerChatString()
        local integer i = 0
        loop
            exitwhen i == max + 1
            if (SubString(s, 0, len[i]) == commands[i]) then
                if (i == 0) then
                    call cmd0(SubString(s, len[i] + 1, 33))
                elseif (i == 1) then
                    call cmd1(SubString(s, len[i] + 1, 33))
                elseif (i == 2) then
                    call cmd2(SubString(s, len[i] + 1, 33))
                elseif (i == 3) then
                    call cmd3(SubString(s, len[i] + 1, 33))
                elseif(i == 4) then
                    call cmd4()
                elseif(i == 5) then
                    call cmd5()
                elseif(i == 6) then
                    call cmd6()
                elseif(i == 7) then
                    call cmd7()
                elseif(i == 8) then
                    call cmd8()
                elseif(i == 9) then
                    call cmd9()
                elseif(i == 10) then
                    call cmd10()
                endif
            endif
            set i = i + 1
        endloop
    endfunction
    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterPlayerChatEvent(t, Player(0), "-", false)
        call TriggerAddAction(t, function Main)
 
        set commands[0] = "-setfirst"
        set len[0] = StringLength(commands[0])
        set commands[1] = "-setlast"
        set len[1] = StringLength(commands[1])
        set commands[2] = "-setuname"
        set len[2] = StringLength(commands[2])
        set commands[3] = "-setproper"
        set len[3] = StringLength(commands[3])
        set commands[4] = "-random"
        set len[4] = StringLength(commands[4])
        set commands[5] = "-getfirst"
        set len[5] = StringLength(commands[5])
        set commands[6] = "-getlast"
        set len[6] = StringLength(commands[6])
        set commands[7] = "-getuname"
        set len[7] = StringLength(commands[7])
        set commands[8] = "-getproper"
        set len[8] = StringLength(commands[8])
        set commands[9] = "-check"
        set len[9] = StringLength(commands[9])
        set commands[10] = "-destroy"
        set len[10] = StringLength(commands[10])
        set max = 10
 
    endfunction
endscope
 

 

This would help you load unit names from an external .txt file without having to use lua objectmerger calls: [vJASS] - FileIO