1. Are you planning to upload your awesome spell or system to Hive? Please review the rules here.
    Dismiss Notice
  2. Updated Resource Submission Rules: All model & skin resource submissions must now include an in-game screenshot. This is to help speed up the moderation process and to show how the model and/or texture looks like from the in-game camera.
    Dismiss Notice
  3. DID YOU KNOW - That you can unlock new rank icons by posting on the forums or winning contests? Click here to customize your rank or read our User Rank Policy to see a list of ranks that you can unlock. Have you won a contest and still haven't received your rank award? Then please contact the administration.
    Dismiss Notice
  4. The reforging of the races is complete. Come see the 14th Techtree Contest Results.
    Dismiss Notice
  5. It's time to choose your horse in the race - the 32nd Modeling Contest Poll is up!
    Dismiss Notice
  6. Check out the Staff job openings thread.
    Dismiss Notice
Dismiss Notice
60,000 passwords have been reset on July 8, 2019. If you cannot login, read this.

MUI Advanced Equipment System (+Save/Load +Event)

Submitted by The_Witcher
This bundle is marked as approved. It works and satisfies the submission rules.
This is my Advanced Equipment System

It is based on the same idea like many others: click on an item and it gets equipped, click on it in the equipment screen to unequip it.

It is advanced because it has many special options available!
Prevent unit types from equipping certain items.
Items may change animations.
Save/load code integration
and many more...

For explaination of the included functions check the documentations included in the map

Features:
  • decide whether a weapon is one or twohanded
  • give a unit a special animation tag, depending on the equiped item
  • an offhand tag will overwrite all mainhand tags (a shield will always cause defend animation)
  • functions for forcing equip/unequip
  • functions for getting information
  • functions for prohibiting a unit from equipping an item (for example for race-only items)
  • Save/load code generator included
  • Register Events to your triggers, firing on item equip and unequip
  • items can give countless abilities



my system is MUI, so every unit can have its own equipment, and easy to customize.
full documentation included.

New improved "How to import" and "How to Use" included, too!!

YOU NEED JNGP AND JASS KNOWLEDGE TO GET THIS WORKING! WITHOUT JNGP AND JASS KNOWLEDGE IT IS IMPOSSIBLE!

I importet some files!!!
the icons and models don't violate any rules, because they are necessary to show what this system can do!! credits ingame.

comment and if you like it maybe +rep^^
give credits when used

have fun

IMPORTANT:
For all who ask me to make the system in a spellbook:
That would be much more work for the users of this system and highly inefficient!!
I will not change that so don't ask me to do that anymore!


Updates

Old Versions

UPDATE v.1.5:
I read vercas suggestions and improved my scripting.
Adding an item is now much more simple^^
thx to vercas for his review

UPDATE v.2.0:
Tige_R found a bug, reseting the shield animation when another item got unequipped
fixed that!!

UPDATE v.3.0: BIG thx to teldrassil who found a huge bug which was settled in all my systems!!! i managed to fix it and updated ALL my newer systems!!!

UPDATE v.4.0: now there is no need anymore that the equipable items are of one itemclass! added system code to the description here

UPDATE v.5.0: it's possible now, to make items give up to 3 abilities when equipped instead of 1 in the previous versions...

UPDATE v.6.0: The bug fixed in v.2.0 was still there... now its really gone AND the script is 1.24 compatible

UPDATE v.6.5: added a new function (IsEquipmentClassEmpty) to check whether a specific unit has something from class x equipped
more information in the code

UPDATE v.7.0: added a new function (GetEquipItemID) to get an items rawcode which is equipped
more information in the code

UPDATE v.8.0: added 3 new functions (GetEquipItemIndex, EquipItemByIndex and EquipItemByID) to get an items index which is equipped (not the same as rawcode) and to equip a item by this index, which helps with the usage of Save/Load Systems
the last function makes you able to equip an item by its rawcode.
more information in the code

UPDATE v.9.0: again 2 new functions for prohibiting a unit from equipping an item or allowing it again for it(EnableItemEquipByID and EnableItemEquipByIndex) and a new function for getting the index of an item (not of its rawcode) --> GetItemIndex
Also much better performance because of the use of hastables!

UPDATE v.10.0: all O(n) searches are now replaced by hashtables!! also there is a new function (TransferEquipment) to move the equipment from unit a to unit b

UPDATE v.11.0: made the item registeration useable outside the library, improved documentation

Update v.12.0: created a how to import and structured the code a little more. also improved the empty-slot-icons

Update v.13.0: New code for equipping items and a new workaround for twohanded items

Update v.14.0: Reworked the beginning of the code, changed variable names, and removed a last rest of german i left in the testmap...


NEW versions:
Update v.2.0: At first I'd like to thank you for your great support!!
As so many of you love it I decided to refresh this a little!
Well i got a lot more experience since i first uploaded this and decided to remake the code... now takes advantage of much more efficient struct usage, doesn't need any hashtable anymore, runs smoother, more ways to work with (if you understand vJass), and many more new things...
Whole new documentation and new methods to work with!
Of course I kept the old names for most of the functions to make it easier for you to apply the new update!
SO: Have fun :D

Update v.2.1: Added Save/Load system, fixed the unequip function, added unequipAll function

Update v.2.2: Added Events and updated the "how to use"

UPDATE v.2.3: Thanks to creativeRPG for finding a very bad bug! i fixed it and suggest everyone to only use the new code!! the one from 2.2 may not work and freeze your game!

Update v.2.4: creativeRPG found more deadly bugs: you could equip items with all units you wanted to the unit owning the inventory and when equipping a one handed weapon while a two handed weapon was equipped the "offhand slot not available" button didn't vanish... fixed now! redownload is necessary!!!!!

Update v.2.5: aaaand again creativeRPG found a bug when you have too many items in your map the index gets too high for the system and it stops working

Update v.3.0: I chagned the whole code for equipping and unequipping and improved the ability handling:
its possible to get up to 50 abilitites from each item
added disbtns for my icons

Update v.3.1: Fixed bugs with syncing the inventories causing mass item creation on the map, made items in the dummys inventory undropable

Update v.4.0: Reduced Abilities per item to 20, fixed a bug for multiplayer usage preventing a second player from using the system, fixed an animation bug where the shield animation didn't disappear

Update v.5.0: New code cause the old one was buggy as hell :D works like a charm now

Update v.5.1: Fixed a bug regarding set Equipment[].owner=

Update v.5.2: Fixed a bug causing standard items to unequip registered equipment


Code

Code (vJASS):
library AdvancedEquipmentSystem requires LinkedListModule, RegisterPlayerUnitEvent

    // The_Witcher's Equipment System
    //
    // This is my easy to use equipment system, which adds an equipment screen to any unit you want.
    //  equipped items can give up abilities to the owner and can change the animations of him...
    //
    //
    //       To learn how to use this system please read the "How To Use" delivered in the demo map
    //
    //
    // Requirements:
    //    JASS knowledge
    //    LinkedList (http://www.hiveworkshop.com/forums/jass-resources-412/snippet-linkedlistmodule-206552/)
    //    RegisterPlayerUnitEvent (http://www.hiveworkshop.com/forums/jass-resources-412/snippet-registerplayerunitevent-203338/)
    //
    // have fun^^

    //**************************************************
    //********************SETUP PART********************
    //**************************************************

    globals
        // this is the rawcode of the unit which works as inventory
        public constant integer INVENTORY_DUMMY = 'h007'
     
        // this is the class you selected as mainhand class
        public constant integer MAINHAND_CLASS = 0
     
        // this is the class you selected as offhand class
        public constant integer OFFHAND_CLASS = 1
       
        // this is the amount of total classes you have
        public constant integer CLASSES = 9
     
        // this is the ability to close the inventory
        public constant integer EXIT_ABILITY = 'A00G'
     
        // this is the ability to open the inventory
        public constant integer OPEN_ABILITY = 'A003'
       
        // this is the ability which gives the dummy the same inventory as your hero has
        public constant integer INVENTORY_ABILITY = 'AInv'
     
        // this is the icon ability shown in the offhand slot when a twhoanded weapon is equipeed
        public constant integer TWOHAND_ABILITY = 'A00Z'
        public constant boolean SHOW_TWOHAND_ABILITY = true
     
        // this is the text shown when a unit is trying to equip an item which it isnt allowed to
        // example: " can't equip " becomes ingame something like   Soldier can't equip Giant Sword
        public constant string UNABLE_TO_EQUIP_STRING = " can't equip "
    endglobals

    //************************************************************
    //********************SETUP PART ENDS HERE********************
    //************************************************************
    //*****************Don't edit anything below******************
    //************************************************************

    globals
        private trigger OnEquip
        private trigger OnUnequip
        private integer TriggeringItem
        private unit EquippingUnit
        private hashtable table
    endglobals
   
    private struct AbilityList extends array
        integer abi
        implement LinkedList
       
        static method create takes nothing returns thistype
            return .createNode()
        endmethod
       
        method remove takes nothing returns nothing
            call .removeNode()
            call .deallocate()
        endmethod
       
        method add takes integer abi returns nothing
            local thistype new = .allocate()
            set new.abi = abi
            call .insertNode(new)
        endmethod
    endstruct


    // **** struct EquipmentItem ****
    private struct EquipmentItem extends array
        readonly integer id
        readonly integer class
        readonly AbilityList abilities
        readonly integer icon
        readonly boolean twohanded
        readonly string tag

        static method operator [] takes integer itemid returns EquipmentItem
            return itemid - 'I000' + CLASSES + 1
        endmethod
   
        static method create takes integer id, integer icon, integer class, boolean twohanded, string animation returns EquipmentItem
            local EquipmentItem this = id - 'I000' + CLASSES + 1
            if id - 'I000' >= 0 then
                call SaveBoolean(table, id - 'I000', 0, true)
            endif
            set .id = id
            set .class = class
            set .icon = icon
            if id >= CLASSES + 1 then
                set .abilities = AbilityList.create()
                if class == MAINHAND_CLASS then
                    set .twohanded = twohanded
                else
                    set .twohanded = false
                endif
                if (class == MAINHAND_CLASS or class == OFFHAND_CLASS) and id != 0 then
                    set .tag = animation
                else
                    set .tag = ""
                endif
            endif
            return this
        endmethod
       
        method addAbility takes integer abi returns nothing
            call .abilities.add( abi)
        endmethod
       
        method applyAbilities takes unit u, boolean add returns nothing
            local AbilityList node = .abilities.next
            loop
                exitwhen node.head
                if add then
                    call UnitAddAbility(u, node.abi)
                else
                    call UnitRemoveAbility(u, node.abi)
                endif
                set node = node.next
            endloop
        endmethod
    endstruct

    public function RegisterNewClass takes integer emptyicon, integer class returns nothing
        call EquipmentItem.create('I000' - CLASSES - 1 + class, emptyicon, class, false, "")
    endfunction

    // **** struct Equipment ****    
    struct Equipment
        private static EquipmentItem twohandIcon
   
        private unit u
        private unit dummy
        readonly string animtag = ""
        readonly EquipmentItem array Item [12]
   
        static method operator [] takes unit u returns Equipment
            return LoadInteger(table, GetHandleId(u), 0)
        endmethod
   
        method operator owner takes nothing returns unit
            return .u
        endmethod
   
        method operator owner= takes unit new returns nothing
            local integer i = 0
            loop
                exitwhen i >= CLASSES
                if .Item[i] != 0 then
                    call .Item[i].applyAbilities(.u, false)
                    call .Item[i].applyAbilities(new, true)
                endif
                set i = i + 1
            endloop
            call AddUnitAnimationProperties(.u, .animtag, false)
            call UnitRemoveAbility(.u, OPEN_ABILITY)
            call AddUnitAnimationProperties(new, .animtag, true)
            call UnitAddAbility(new, OPEN_ABILITY)
            set .u = new
            call SaveInteger(table, GetHandleId(.u), 0, this)
            call SaveInteger(table, GetHandleId(.dummy), 0, this)
        endmethod
       
        method syncInventories takes nothing returns nothing
            local integer i = 0
            loop
                exitwhen i >= 6
                call RemoveItem(UnitItemInSlot(.dummy, i))
                call UnitAddItemToSlotById(.dummy, GetItemTypeId(UnitItemInSlot(.u, i)), i)
                call SetItemDroppable(UnitItemInSlot(.dummy, i), false)
                set i = i + 1
            endloop
        endmethod
   
        private method refreshAnimation takes nothing returns nothing
            local string a = .Item[MAINHAND_CLASS].tag
            if .Item[OFFHAND_CLASS] != 0 and .Item[OFFHAND_CLASS] != twohandIcon then
                set a = .Item[OFFHAND_CLASS].tag
            endif
            call AddUnitAnimationProperties(.u, .animtag, false)
            call AddUnitAnimationProperties(.u, a, true)
            set .animtag = a
        endmethod
       
        method equipEmptyClass takes integer class returns nothing
            call UnitAddAbility(.dummy, EquipmentItem(class).icon)
            set .Item[class] = 0
        endmethod
       
        method equipTwohandIcon takes nothing returns nothing
            call UnitAddAbility(.dummy, twohandIcon.icon)
            set .Item[OFFHAND_CLASS] = twohandIcon
        endmethod
   
        method unequip takes integer class returns nothing
            local integer i = 0
            local EquipmentItem toRemove = .Item[class]
            if toRemove != 0 then
                if toRemove.twohanded then
                    call UnitRemoveAbility(.dummy, TWOHAND_ABILITY)
                    call .equipEmptyClass(OFFHAND_CLASS)
                endif
                call toRemove.applyAbilities(.u, false)
                call UnitAddItemById(.u, toRemove.id)
                set TriggeringItem = toRemove.id
                set EquippingUnit = .u
                call TriggerEvaluate(OnUnequip)
                call UnitRemoveAbility(.dummy, toRemove.icon)
            else
                call UnitRemoveAbility(.dummy, EquipmentItem(class).icon)
            endif
            set .Item[class] = 0
            call .refreshAnimation()
        endmethod
       
        method equip takes integer id returns nothing
            local EquipmentItem toEquip = EquipmentItem[id]
            local EquipmentItem mainEquip = .Item[MAINHAND_CLASS]
            // remove existing
            if mainEquip != 0 then
                if toEquip.twohanded or (mainEquip.twohanded and (toEquip.class == OFFHAND_CLASS or toEquip.class == MAINHAND_CLASS)) then
                    call .unequip(MAINHAND_CLASS)
                    call .unequip(OFFHAND_CLASS)
                    if toEquip.class == MAINHAND_CLASS and not toEquip.twohanded then
                        call .equipEmptyClass(OFFHAND_CLASS)
                    elseif toEquip.class == OFFHAND_CLASS then
                        call .equipEmptyClass(MAINHAND_CLASS)
                    endif
                endif
            endif
            call .unequip(toEquip.class)
            // new is twohanded ?
            if toEquip.twohanded then
                call .unequip(OFFHAND_CLASS)
                call .equipTwohandIcon()
                if not SHOW_TWOHAND_ABILITY then
                    call UnitRemoveAbility(.dummy, twohandIcon.icon)
                endif
            endif
            // equip new
            call toEquip.applyAbilities(.u, true)
            call UnitAddAbility(.dummy, toEquip.icon)
            set .Item[toEquip.class] = toEquip
            call .refreshAnimation()
            // fire trigger
            set EquippingUnit = .u
            set TriggeringItem = id
            call TriggerEvaluate(OnEquip)
        endmethod
       
        static method disable takes integer itemId, integer unitType, boolean flag returns nothing
            call SaveBoolean(table, itemId - 'I000', unitType, flag)
        endmethod
       
        private method onDestroy takes nothing returns nothing
            local integer i = 0
            call RemoveUnit(.dummy)
            loop
                exitwhen i > 12
                if .Item[i] != 0 then
                    call .Item[i].applyAbilities(.u, false)
                endif
                set i = i + 1
            endloop
            call AddUnitAnimationProperties(.u, .animtag, false)
            call UnitRemoveAbility(.u, OPEN_ABILITY)
        endmethod
   
        static method create takes unit u returns Equipment
            local Equipment this = Equipment[u]
            local integer i = 0
            local integer id = GetPlayerId(GetOwningPlayer(u))
            if this != 0 then
                call RemoveUnit(.dummy)
            else
                set this = Equipment.allocate()
                call SaveInteger(table, GetHandleId(u), 0, this)
            endif
            set .u = u
            set .dummy = CreateUnit(GetOwningPlayer(u), INVENTORY_DUMMY, GetUnitX(u), GetUnitY(u), 0)
            call SaveInteger(table, GetHandleId(.dummy), 0, this)
            call UnitAddAbility(.dummy, INVENTORY_ABILITY)
            call UnitAddAbility(.dummy, EXIT_ABILITY)
            call UnitAddAbility(.u, OPEN_ABILITY)
            loop
                exitwhen i >= CLASSES
                call .equipEmptyClass(i)
                set i = i + 1
            endloop
            return this
        endmethod
       

    // **** Other Stuff ****
        private static method Access takes nothing returns boolean
            local unit u = GetTriggerUnit()
            local Equipment inv = Equipment[u]
            local integer class
            local integer i = 0
            if GetSpellAbilityId() == EXIT_ABILITY then
                if GetLocalPlayer() == GetOwningPlayer(inv.u) then
                    call ClearSelection()
                    call SelectUnit(inv.u, true)
                endif
            elseif GetSpellAbilityId() == OPEN_ABILITY then
                call SetUnitX(inv.dummy, GetUnitX(inv.u))
                call SetUnitY(inv.dummy, GetUnitY(inv.u))
                if GetLocalPlayer() == GetOwningPlayer(inv.u) then
                    call ClearSelection()
                    call SelectUnit(inv.dummy, true)
                endif
                call inv.syncInventories()
            elseif GetUnitTypeId(u) == INVENTORY_DUMMY then
                loop
                    exitwhen i >= CLASSES
                    if inv.Item[i].icon == GetSpellAbilityId() then
                        set class = i
                        set i = CLASSES
                    endif
                    set i = i + 1
                endloop
                call inv.unequip(class)
                call inv.equipEmptyClass(class)
                call inv.syncInventories()
            endif
            set u = null
            return false
        endmethod

        private static method ItemEquip takes nothing returns boolean
            local unit u = GetTriggerUnit()
            local item ite = GetManipulatedItem()
            local integer i = 0
            local Equipment inv = Equipment[u]
            local EquipmentItem invIte = EquipmentItem[GetItemTypeId(ite)]
            if GetItemTypeId(ite) - 'I000' >= 0 then
                if LoadBoolean(table, GetItemTypeId(ite) - 'I000', 0) then
                    if invIte != 0 and inv != 0 then
                        if not LoadBoolean(table, GetItemTypeId(ite) - 'I000', GetUnitTypeId(inv.u)) then
                            if u == inv.u then
                                call inv.equip(GetItemTypeId(ite))
                                call RemoveItem(ite)
                                call inv.syncInventories()
                            elseif u == inv.dummy then
                                loop
                                    exitwhen i >= 6
                                    if invIte.id == GetItemTypeId(UnitItemInSlot(inv.u, i)) then
                                        call UnitUseItem(inv.u, UnitItemInSlot(inv.u, i))
                                        call RemoveItem(ite)
                                        set i = 7
                                    endif
                                    set i = i + 1
                                endloop
                            endif
                        else
                            call DisplayTextToPlayer(GetOwningPlayer(inv.u), 0, 0, GetUnitName(inv.u) + UNABLE_TO_EQUIP_STRING + GetItemName(ite))
                        endif
                    endif
                endif
            endif
            set u = null
            set ite = null
            return false
        endmethod
       
        private static method onInit takes nothing returns nothing
            set OnEquip = CreateTrigger()
            set OnUnequip = CreateTrigger()
            call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_USE_ITEM, function Equipment.ItemEquip)
            call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_SPELL_CAST, function Equipment.Access)
            set .twohandIcon = EquipmentItem.create('I000' - 1, TWOHAND_ABILITY, 0, false, "")
            set table = InitHashtable()
        endmethod
       
        implement optional SaveLoadPlugin
   
    endstruct

    // **** Trigger Events ****
    function RegisterItemEquipEvent takes code func returns nothing
        call TriggerAddCondition(OnEquip, Filter(func))
    endfunction
   
    function RegisterItemUnequipEvent takes code func returns nothing
        call TriggerAddCondition(OnUnequip, Filter(func))
    endfunction
   
    function GetTriggeringItemId takes nothing returns integer
        return TriggeringItem
    endfunction
   
    function GetEquippingUnit takes nothing returns unit
        return EquippingUnit
    endfunction
   
   //wrappers
    function InitEquipment takes unit whichunit returns nothing
        call Equipment.create(whichunit)
    endfunction

    public function RegisterItem takes integer itemid, integer icon, integer class, boolean twohanded, string animation returns nothing
        call EquipmentItem.create(itemid, icon, class, twohanded, animation)
    endfunction
   
    public function AddItemAbility takes integer itemid, integer abi returns nothing
        call EquipmentItem[itemid].addAbility(abi)
    endfunction
   
    function EnableItemEquip takes integer itemId, integer unitType, boolean flag returns nothing
        call Equipment.disable(itemId, unitType, not flag)
    endfunction

    function IsEquipmentClassEmpty takes unit u, integer class returns boolean
        return Equipment[u].Item[class] == 0
    endfunction

    function EquipItem takes unit u, item ite returns nothing
        call Equipment[u].equip(GetItemTypeId(ite))
        call RemoveItem(ite)
    endfunction
    function EquipItemById takes unit u, integer itemId returns nothing
        call Equipment[u].equip(itemId)
    endfunction

    function UnequipItemById takes unit u, integer itemid returns nothing
        local integer class = EquipmentItem[itemid].class
        if Equipment[u].Item[class].id == itemid then
            call Equipment[u].unequip(EquipmentItem[itemid].class)
            call Equipment[u].equipEmptyClass(class)
        endif
    endfunction

    function UnequipItemByClass takes unit u, integer class returns nothing
        call Equipment[u].unequip(class)
        call Equipment[u].equipEmptyClass(class)
    endfunction

    function GetEquippedItemTypeId takes unit u, integer class returns integer
        return Equipment[u].Item[class].id
    endfunction

    function ChangeEquipmentOwner takes unit u, unit newowner returns nothing
        set Equipment[u].owner = newowner
    endfunction

    function UnequipAll takes unit u returns nothing
        local integer i = 1
        loop
            call Equipment[u].unequip(i)
            call Equipment[u].equipEmptyClass(i)
            exitwhen i >= CLASSES
            set i = i + 1
        endloop
    endfunction

endlibrary


//Code indented using The_Witcher's Script Language Aligner
//Download the newest version and report bugs at www.hiveworkshop.com
 


Keywords:
equipment, equip, system, item, hero, unit, bonus, stat, vjass, jngp, mui, mpi, animation, ability, save, load, hashtable, code, Event, events
Contents

Advanced Equipment System (Map)

Reviews
Moderator
20:01, 26th Oct 2009 TriggerHappy187: Approved because of so many minimod approvals and high ratings. I also couldn't see anything wrong inside the code.
  1. Beast(TrOg)

    Beast(TrOg)

    Joined:
    Nov 4, 2006
    Messages:
    148
    Resources:
    5
    Maps:
    3
    Spells:
    2
    Resources:
    5
    There are some bugs that I found:

    1) If you click items on the main hero fast enough, then duplicates will be created at the dummy's location.
    To see this yourself: grab two of the same shield and continuously equip the one in the first slot quickly.

    2) When the dummy is selected, you can right click an item and left click the dummy's portrait to drop the item at its location. Do this two or three times. After that, equip/unequip any items. Duplicates of items are created on the group every time.

    3) Moving items in the dummy's inventory doesn't change the item's position for the hero.

    PS: Are there more models that have lots of animations such as the one in the demo? :)
     
    Last edited: Jan 3, 2011
  2. codart

    codart

    Joined:
    Apr 26, 2010
    Messages:
    14
    Resources:
    0
    Resources:
    0
    That's fucking perfeck. From 3 abi to more than 50 :) thank you the witcher. You help my life easier. But i see some one find some bug. Can you fix all?
    -------------------------------------
    I have to create 1 trigger that remove item dropped from dummy unit inventory now to prevent items duplicating :D. But I belive The_Witcher will fix it soon :)
     
    Last edited: Jan 3, 2011
  3. The_Witcher

    The_Witcher

    Joined:
    Dec 29, 2008
    Messages:
    229
    Resources:
    13
    Tools:
    1
    Spells:
    12
    Resources:
    13
    thanks! fixed all yiour issues except (3)

    Update v.3.1: Fixed bugs with syncing the inventories causing mass item creation on the map, made items in the dummys inventory undropable
     
  4. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    Hey guys, I'm having some problems with making this for 5 players...
    Can anyone help me???
    This system will be used in Ketra ORPG !
     
  5. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    this system is fully MPI, so its supposed to work fine...

    anyway, what problem are you having? please explain more...
     
  6. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    I imported it and it's working perfectly, but i need to make it multiplayer (for players red/blue/teal/purple/yellos) how can i do that?
     
  7. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    just initialize each player's hero to use this system...
     
  8. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    I don't know how to do it since i don't know JASS :goblin_cry:
     
  9. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    read the instructions, its written there... I cannot DL the map ryt now and its not posted on the first page... just follow the things written on the How To Use... its there for a reason...
     
  10. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    I read all in "How to Use" but didn't found :grin:
    Ok here it is, can you tell me what is that what i need to do?
    Click here :D

    Code (vJASS):

    what this is:
    - Equipment System
    - MPI
    - in vJass

    what this not is:
    - Inventory System
    - in GUI/normal Jass
    - exportable to GUI or normal Jass
    - MUI(coming soon)

    --------- 1)    How to register items    (1 ---------

    this system isnt that perfekt that it can do everything on its own ;D
    with the following function you can register items to the system:

    call AdvancedEquipmentSystem_RegisterItem(itemid, abilities, icon, class, twohanded, animation)

      "itemid" is of course the rawcode of the item the rest is assigned to
     
      "icon" is the ability shown inside the Equipment when the item is equipped
     
      "class" is the slot the item jumps in (be sure to adjust the x/y coordinates inside the object editor according
                                             to the coordinates of the "empty slot" icon ability of the same class)
                                             
      "twohanded" is a boolean (i think self explaining) !!works only for mainhand items!!
     
      "animation" is a string which indicates the animation tag added when this item is equipped
         ATTENTION: offhand slot items animations always overwrite mainhand slot items animations
         
    Example:
      call AdvancedEquipmentSystem_RegisterItem('I004', 'A008', 1, false, "Alternate")
      registers item 'I004' to the system.
      the item gets equipped in slot 1 and is not twohanded
      as long as the unit has this item equipped it will play its "Alternate" animations

     
    until now your items have no effect when equipped...
    you can add up to 50 abilities to one itemtype!
    to add one use:

    call AdvancedEquipmentSystem_AddItemAbility( integer itemid, integer abi )

       "itemid" is the rawcode of the item the rest is assigned to
       
       "abi" is the rawcode of the ability the unit gets when it equips this item

    Example:
      call AdvancedEquipmentSystem_AddItemAbility('I004', 'A002')
      a unit will get the ability 'A002' when equipping an item of type 'I004'


    --------- 2)    How to use this system    (2 ---------

    well its very simple to use:

    call InitEquipment ( owner )
      owner is the unit that gets the equipment
     
    and thats all^^ whenever this unit uses a registered item, it will get equipped


    --------- 3)    Additional functions    (3 ---------

    EnableItemEquip takes player p, integer id, boolean flag returns nothing
      with this function, you can disable/enable the equipping of a special item
     
      Example:
        call EnableEquipment(Player(0), 'I001', false)
        => Player 1 cant equip the item 'I001' anymore, until it gets enabled again
       

       
    IsEquipmentClassEmpty takes player p, integer class returns boolean
      sometimes you amybe want to know whether a unit has something equipped in class xy...
     
      Example:
        If IsEquipmentClassEmpty(Player(0),2) then
           ...
        endif
        => only if the unit owned by Player 1 which has the Equipment has nothing equipped in slot 2
            the if then else block releases his actions


    EquipItem takes player p, item ite returns nothing
      to force equipping of a special item use this function
     
      Example:
        call EquipItem( Player(0),GetManipulatedItem() )
        => the unit owned by Player 1 which has the Equipment equips the manipulated item
       
       
    function UnequipItemById takes player p, integer itemid returns nothing
    function UnequipItemByClass takes player p, integer class returns nothing
      two functions which do the same but with different parameters:
      player p is always the owner of the unit with the destination equipment
      first function uses itemid... it is the rawcode of the item which gets unequipped (system searches the class)
      second function uses class... it is the number of the class of which the equipped item gets unequipped
     
      Examples:
        call UnequipItemById(Player(0),'I002') => if equipped, item of type 'I002' is unequipped now
        call UnequipItemByClass(Player(0),2) => item equipped in class 2 is unequipepd now



    GetEquippedItemTypeId takes player p, integer class returns integer
      this function returns the rawcode of the item equipped in the given class
     
      Example:
        If GetEquippedItemTypeId(Player(0),1) == 'I005' then
          ...
        endif
        => only if the unit owned by Player 1 which has the Equipment, has a item of type 'I005'
            in slot 1, the if then else block releases his actions
            (useful for: if unit blaa has equipped sword xy then...)
           

    ChangeEquipmentOwner takes  player p, unit newOwner returns nothing
      if you have to transfer the Equipment to another unit use this function
     
      Example:
        call ChangeEquipmentOwner(Player(0), GetTriggerUnit() )
        => the triggering unit gets the Equipment the unit of Player 1 has at the moment
       
    --------- 4)    Save/Load Codes    (4 ---------
    I added functions for getting and applying save and load codes to this system
     
        function SaveEquipment takes player p returns string
          this function returns the current load code from the equipment of player p
         
        function LoadEquipment takes player p, string LoadCode returns nothing
          this function loads a given code "LoadCode" into player ps equipment

    --------- 5)    Trigger Events    (5 ---------
    you can register events to triggers which fire when a item is equipped or unequipped

        function TriggerRegisterItemEquipEvent takes trigger t returns nothing
       
        and
       
        function TriggerRegisterItemUnequipEvent takes trigger t returns nothing
       
        are pretty self explaining...
       
        use GetTriggeringItemId and GetEquippingUnit to get the involved units

    --------- 6)    To all vJassers out there    (6 ---------
    well as we understand vJass we can do things much easier ^^

    the above mentioned functions are all simple wrappers for the included structs methods:
    struct EquipmentItem
      methods
        create takes integer id, integer abi1,integer abi2,integer abi3, integer icon, integer class, boolean twohanded, string animation returns EquipmentItem
           => same as AdvancedEquipmentSystem_RegisterItem
      members
        readonly integer id     => the item rawcode
        readonly integer class  => the assigned class
        readonly integer abi1   => the first ability this item adds
        readonly integer abi2   => the second ability this item adds
        readonly integer abi3   => the third ability this item adds
        readonly integer icon   => the icon ability added to the dummy
        readonly boolean twohanded  => whether the item is twohanded or not (always false for non mainhand items)
        readonly string  tag    => the animation tag added when the unit equips this (always "" for non main- and offhand items)
       
    struct Equipment
      methods
        create takes unit u returns Equipment  => creates a new Equipment for unit u
        destroy takes nothing returns nothing  => destroys an existing Equipment
        equip takes item ite returns nothing   => equips a special item
        unequip takes integer class returns nothing => unequips whatever is in the given class
      members
        readonly unit dummy  => the equipment dummy unit
        readonly boolean array enabled  => boolean whether this unit can equip item xy (inside the array is the items rawcode)
        readonly EquipmentItem array Item  => the equipped EquipmentItem in the slot given as array
                 unit owner => self explaining... use set yourequipment.owner = yourunit to transfer the Equipment to another unit



    ---------     Thanks to all who gave useful critism or tips for improvement     ---------

    The_Witcher

     
     
  11. baassee

    baassee

    Joined:
    Nov 14, 2008
    Messages:
    3,220
    Resources:
    17
    Spells:
    14
    Tutorials:
    3
    Resources:
    17
    This. Change owner to your unit.
     
  12. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    Look guys i have this trigger:
    -When unit enters set "u" to triggering unit and some custom script (owner of enterning is red)
    -Can this be made for 5 players?
    Because i need to make when unit enters the "WORLD" he gets equipment, after that i turn off the trigger and so on for 4 more players...
     
  13. baassee

    baassee

    Joined:
    Nov 14, 2008
    Messages:
    3,220
    Resources:
    17
    Spells:
    14
    Tutorials:
    3
    Resources:
    17
    in guy it will be like this

    just have unit enters playablemaparea as event

    then you have a condition that if it is a hero unit

    then the action is just a custom script with call InitEquipment(GetTriggerUnit())
     
  14. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    Thanks, it's working +REP :p !
    ---EDIT
    Found a bug: I tryed in Multiplayer, and when my friend click on equipment it get's removed ... :(
     
    Last edited: Jan 6, 2011
  15. baassee

    baassee

    Joined:
    Nov 14, 2008
    Messages:
    3,220
    Resources:
    17
    Spells:
    14
    Tutorials:
    3
    Resources:
    17
    it works for me, you can always upload the map
     
  16. aki15

    aki15

    Joined:
    Sep 27, 2009
    Messages:
    587
    Resources:
    3
    Icons:
    2
    Maps:
    1
    Resources:
    3
    It worked when i made red to be computer and test a map as blue(or others).
    But when tried on Garena it got bugged...
     
  17. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    maybe a garena problem...
     
  18. xorkatoss

    xorkatoss

    Joined:
    Jul 12, 2010
    Messages:
    1,586
    Resources:
    7
    Models:
    5
    Maps:
    1
    Spells:
    1
    Resources:
    7
    i finaly got JNGP and now i can use it!!
    one of the best rpg systems ever!! 5/5 :thumbs_up:
     
  19. Dominic74

    Dominic74

    Joined:
    Jul 17, 2010
    Messages:
    139
    Resources:
    0
    Resources:
    0
    But can this work without set U on a unit.?
     
  20. The_Witcher

    The_Witcher

    Joined:
    Dec 29, 2008
    Messages:
    229
    Resources:
    13
    Tools:
    1
    Spells:
    12
    Resources:
    13
    the function InitEquipment simply requires a unit as parameter!
    the equipment will be created for the unit and can only be controlled by the owner!

    without any basic jass knowledge i highly recommend to forget that you ever saw this system or go to the tutorials section and learn the jass basics so you know what youre doing!