[General] Is specific builidng under construction

[ZiBitheWand3r3r]

hey,
any idea how check it, if possble - easy way
its for public resource so should be as general as possible
already saw 'Blight Dispel Small' trick on The Helper, but maybe anything else?

 

[Kaijyuu]

The blight dispel trick is the most reliable way. I don't know of any trigger-only ways to do it; perhaps you could somehow take advantage of its different armor type while under construction (though that also might not be general enough).

 

[IcemanBo]

You can use [vJASS] - BuilderTrack ; it tracks buildings that strart/finish construction.

 

[ZiBitheWand3r3r]

thanks guys,
armor check is to complicated;
dispel trick is fine for map specific solutions, but for public resource is annoying;
but from BuilderTrack I guess I can take just this small part for IsConstructed, cause I only need this.
So by use EVENT_PLAYER_UNIT_CONSTRUCT_FINISH and onIndex event and setting isContructed=false, and on EVENT_PLAYER_UNIT_CONSTRUCT_START setting to "true" it will work for all possible events? Like pre-placed units, normal construction, build by item ability (tiny castle) or created by user by CreateNUnitAtLoc in GUI? did you maybe tested when checking your BuilderTrack ?

 

[IcemanBo]

Like pre-placed units

why/what is the potential issue here?

build by item ability (tiny castle)

should yes

or created by user by CreateNUnitAtLoc in GUI?

Does this GUI wrapper do something special? Idk what you exactly want create, or it even differs from native logic. Can't test it atm, too.

 

[ZiBitheWand3r3r]

Solved

Spoiler: code

// requires Unit Event by Bribe
// use boolean isBuildingUnderConstruction[UnitUserData] to check
globals
    boolean array               isBuildingUnderConstruction
endglobals

function OnConstruct_Start_Cond takes nothing returns boolean
    set isBuildingUnderConstruction[GetUnitUserData(GetConstructingStructure())]=true
    return false
endfunction

function OnConstruct_Finish_Cond takes nothing returns boolean
    set isBuildingUnderConstruction[GetUnitUserData(GetConstructedStructure())]=false
    return false
endfunction

function OnBuilding_Enters_Cond takes nothing returns boolean
    if IsUnitType(udg_UDexUnits[udg_UDex], UNIT_TYPE_STRUCTURE) then
        set isBuildingUnderConstruction[udg_UDex]=false
    endif
    return false
endfunction
//===================================================================
function InitTrig_IsBuildingUnderConstruction takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_CONSTRUCT_START)
    call TriggerAddCondition(t, Condition(function OnConstruct_Start_Cond))
   
    set t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_CONSTRUCT_FINISH)
    call TriggerAddCondition(t, Condition(function OnConstruct_Finish_Cond))
   
    set t = CreateTrigger()
    call TriggerRegisterVariableEvent(t, "udg_UnitIndexEvent", EQUAL, 1.00)
    call TriggerAddCondition(t, Condition(function OnBuilding_Enters_Cond))
    set t=null
endfunction

 

[UmbraUnda]

Woah that JASS is looking real good mate