[JASS] Setting Ability For Unit

[Linaze]

I've made a trigger that runs when the time becomes 6.00. It should change the level of an ability for a non-hero unit, but the level doesn't change. What've I done wrong this time?

scope Day initializer Init
    private function TypeFilter takes nothing returns boolean
       return GetUnitTypeId(GetFilterUnit()) == 'n003'
    endfunction
    
    private function Actions takes nothing returns nothing
        local group g = CreateGroup()
        local unit u
        call GroupEnumUnitsOfPlayer(g,Player(0),Condition(function TypeFilter))
        loop
            set u = FirstOfGroup(g)
            exitwhen u == null
            call SetUnitAbilityLevel(u,'A004',2)
            call SetUnitAbilityLevel(u,'A00I',2)
            call GroupRemoveUnit(g,u)
        endloop
        call DestroyGroup(g)
    endfunction

    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterGameStateEvent(t,GAME_STATE_TIME_OF_DAY,EQUAL,6.)
        call TriggerAddAction(t,function Actions)
    endfunction
endscope

 

[watermelon_1234]

That code should work fine. Are you sure you're testing with correct raw ids/player?

Also, this would be an optimized version of that: (Basically made the group enumeration do everything in the filter and changed trigger actions to trigger conditions.)

scope Day initializer Init
    globals
        private group g = CreateGroup()
    endglobals
    
    private function TypeFilter takes nothing returns boolean
        local unit u = GetFilterUnit()
        if GetUnitTypeId(u) == 'n003' and GetWidgetLife(u) > 0.405 then
            call SetUnitAbilityLevel(u,'A004',2)
            call SetUnitAbilityLevel(u,'A00I',2)
        endif
        set u = null
        return false       
    endfunction
    
    private function Actions takes nothing returns boolean
        call GroupEnumUnitsOfPlayer(g,Player(0),Condition(function TypeFilter))
        return false
    endfunction

    private function Init takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterGameStateEvent(t,GAME_STATE_TIME_OF_DAY,EQUAL,6.)
        call TriggerAddCondition(t,function Actions)
    endfunction
endscope

 

[Titanhex]

Looks fine to me too. Check your rawcodes, make sure you're doing the right player (Player 1), then check to make sure no other code is interferring (Check your other code that happens at 6.0). Finally, if nothing has worked, try skipping the time forward at the end of the actions to 6.01. (I suggest condensing all your @ 6.00 code into one for this.)

 

[Linaze]

The raw codes are all right (unfortunately).
There is only one trigger that runs when the time of day becomes 6.00 (there is one for 18.00, also).
If you want to set an ability's level to 2, do you set it to 1 or 2 (like Player 1 (Red) is Player(0) in JASS)?

 

[PurplePoot]

Yes, ability levels start at 1, not 0, for some reason. Have you debugged this to make sure the trigger is firing? To make sure a unit or multiple units are being enumerated? To make sure that those units have the required abilit(y/ies)?

 

[Linaze]

I've made sure all units that should be enumerated are being enumerated, yes. All that doesn't work is changing the two abilities' level.

 

[Maker]

The script works just fine for me. I used 'h000' and 'A000' raw codes for obvious reasons. So it must be something else.

Do the units have the ability? Does the ability have levels? Disable the unit type and life condition and test it.

 

[PurplePoot]

I suspect it's another trigger interacting with this one. Debugging is continuing in the chat for now.

 

[Titanhex]

            call UnitAddAbility(u,'A004')
            call UnitAddAbility(u,'A00I')
            call SetUnitAbilityLevel(u,'A004',2)
            call SetUnitAbilityLevel(u,'A00I',2)

Try that. It's not gonna hurt anything after all.

 

[Linaze]

Removing the ability, adding it back and then changing it's level actually worked. I realize it may not be the best method. But I'll use it until someone finds another way.

 

[Dr Super Good]

Try making the ability not permant for the unit. Although that probably will do nothing.

 

[Linaze]

"not permant"?

 

[Bribe]

Do you add them initially through triggers or did you set them in the object editor?

If it's through the object editor, the abilities are permanent by default. You can try: UnitMakeAbilityPermanent(u, false, 'ABIL')

 

[Dr Super Good]

That is what I meant, my spelling really is bad... Sorry lol...

It might be that you can not modify Permanent abilities. You can remove permanent abilities and added abilities are not permanent by default.

 

[Linaze]

Making it not permanent didn't work either.
Still sticking to removing and adding.