[vJASS] RectEvent

[mckill2009]

As we all know creating a region in jass is a pain in the ass, coz we cant do it directly like in GUI...we need to add the region to a rect first in order to function, this on the other hand is very straightforward...

I just need suggestions on what to add and remove, pls dont ask me to use textmacros (I wont)...

Hidden

/*
===RectEvent
===by Mckill2009

Use GetFilterUnit() for the unit that's entering and leaving

API:
    static method enter takes rect r, code cond returns nothing
    static method leave takes rect r, code cond returns nothing
    static method removeEnter takes rect r returns nothing
    static method removeLeave takes rect r returns nothing
    static method destroyAll takes rect r returns nothing
*/

library RectEvent

struct RectEvent extends array
    private static hashtable ht = InitHashtable()
    private static integer enterID = 0
    private static integer leaveID = 10
    
    static method enter takes rect r, code cond returns nothing
        local integer rID = GetHandleId(r)
        local trigger t
        local region reg
        if HaveSavedHandle(ht,rID,enterID) then
            debug call BJDebugMsg("RectEvent.enter ERROR: Trying allocate a double rect!")       
        else
            set t = CreateTrigger()
            set reg = CreateRegion()
            call SaveTriggerHandle(ht,rID,enterID,t) //uses 0
            call SaveRegionHandle(ht,rID,enterID+1,reg) //uses 1
            call RegionAddRect(reg,r)
            call TriggerRegisterEnterRegion(t,reg,Filter(cond))
            set t = null
            set reg = null
        endif
    endmethod
    
    static method leave takes rect r, code cond returns nothing
        local integer rID = GetHandleId(r)
        local trigger t
        local region reg
        if HaveSavedHandle(ht,rID,leaveID) then
            debug call BJDebugMsg("RectEvent.leave ERROR: Trying allocate a double rect!")       
        else
            set t = CreateTrigger()
            set reg = CreateRegion()
            call SaveTriggerHandle(ht,rID,leaveID,t) //uses 10
            call SaveRegionHandle(ht,rID,leaveID+1,reg) //uses 11
            call RegionAddRect(reg,r)
            call TriggerRegisterLeaveRegion(t,reg,Filter(cond))
            set t = null
            set reg = null
        endif
    endmethod
    
    static method removeEnter takes rect r returns nothing
        local integer rID = GetHandleId(r)
        if HaveSavedHandle(ht,rID,enterID) then
            call DestroyTrigger(LoadTriggerHandle(ht,rID,enterID))
            call RegionClearRect(LoadRegionHandle(ht,rID,enterID+1),r)
            call RemoveSavedHandle(ht,rID,enterID)
        else
            debug call BJDebugMsg("RectEvent.removeEnter ERROR: Trying to remove an invalid rect!")            
        endif
    endmethod
    
    static method removeLeave takes rect r returns nothing
        local integer rID = GetHandleId(r)
        if HaveSavedHandle(ht,rID,leaveID) then
            call DestroyTrigger(LoadTriggerHandle(ht,rID,leaveID))
            call RegionClearRect(LoadRegionHandle(ht,rID,leaveID+1),r)
            call RemoveSavedHandle(ht,rID,leaveID)
        else
            debug call BJDebugMsg("RectEvent.removeLeave ERROR: Trying to remove an invalid rect!")            
        endif
    endmethod
    
    static method destroyAll takes rect r returns nothing
        local integer rID = GetHandleId(r)
        if HaveSavedHandle(ht,rID,enterID) or HaveSavedHandle(ht,rID,leaveID) then
            call DestroyTrigger(LoadTriggerHandle(ht,rID,enterID))
            call RegionClearRect(LoadRegionHandle(ht,rID,enterID+1),r)  
            call DestroyTrigger(LoadTriggerHandle(ht,rID,leaveID))
            call RegionClearRect(LoadRegionHandle(ht,rID,leaveID+1),r) 
            call FlushChildHashtable(ht,rID)            
        else
            debug call BJDebugMsg("RectEvent.destroyAll ERROR: Trying to destroy an invalid rect!")            
        endif   
    endmethod
endstruct

endlibrary

USAGE:

struct test
    static method enterBIG takes nothing returns nothing
        call BJDebugMsg("ENTERING BIG") 
    endmethod
    
    static method leaveBIG takes nothing returns nothing
        call BJDebugMsg("LEAVING BIG") 
    endmethod
    
    static method onInit takes nothing returns nothing 
        call RectEvent.enter(gg_rct_RegBig,function thistype.enterBIG)
        call RectEvent.leave(gg_rct_RegBig,function thistype.leaveBIG)
    endmethod
endstruct

 

[Dr Super Good]

we need to add the region to a rect first in order to function, this on the other hand is very straightforward...

Sorry but that is illegal...

A rect is a rectangular area of the map.
A region is a collection of map cells.

A region can be filled with cells contained by a rect.
A rect cannot be made from a region as there is no restriction forcing a region to be rectangular.

 

[baassee]

Why hashtable and not Table Oo we're coding in vJASS you know, not shitty GUI-create-one-hash-per-resource.

 

[Yixx]

@ DSG, I guess that is what he meant, but still you are correct.

Furthermore, I have to agree with Baassee, because there is a 256 limit on the amount of hashtables. Thus it would certainly be benificial to use Tables.

Then, why do you limit the amount of pieces of code to be assigned to each rect?

 

[mckill2009]

@DSG
I meant >>> RegionAddRect, region TO a rect, if the native was RectAddregion, then I would say rect TO a region ...

about the Table, Im considering it...

Then, why do you limit the amount of pieces of code to be assigned to each rect?

what?, you mean one rect one full function/code?...

 

[edo494]

it is RegionAddRect because you are taking region to which region and rect whichrect to be added
for instance, UnitAddAbility doesnt add unit to ability but ability to unit

 

[baassee]

Still considering?! No no no no no!

 

[edo494]

why do you do the same thing twice in row in DestroyAll(DestroyTrigger and RegionClearRects) ?

 

[mckill2009]

coz if you clear the rect, the trigger is not used and thus leak...

 

[edo494]

            call DestroyTrigger(LoadTriggerHandle(ht,rID,enterID))
            call RegionClearRect(LoadRegionHandle(ht,rID,enterID+1),r)  
            call DestroyTrigger(LoadTriggerHandle(ht,rID,leaveID))
            call RegionClearRect(LoadRegionHandle(ht,rID,leaveID+1),r)

I mean this, destroying destroyed trigger?

 

[baassee]

different childkeys

 

[mckill2009]

as baassee already pointed out, I purposely use different child keys to avoid overwriting the other...
btw, Im considering 100% to use TableArray, that way it's much more cleaner ...

 

[Yixx]

@DSG
what?, you mean one rect one full function/code?...

This is illegal from your point of view:

call RectEvent.enter(myRect, function Enter1)
call RectEvent.enter(myRect, function Enter2)

I know it is not smart to do, but sometimes you want your different actions within different scopes of encapsulation, and thus you would want to enable adding different code to the same rect..

 

[mckill2009]

Since when did someone having the same rect contains 2 or more functions?, it's not good to see that kind, so just do a condition check inside the one function itself...