[General] [JASS] Refresh, doesn't work

FRENGERS · Apr 7, 2016

FIXED!
Here's the code, thanks to TriggerHappy & Bribe!

JASS:

scope refresh initializer chat
    globals
        private constant string string = "-refresh"
    endglobals
    private function pick takes nothing returns nothing
        local unit u
        call groupenumunitsofplayer(bj_lastcreatedgroup, gettriggerplayer(), null)
        loop
            set u = firstofgroup(bj_lastcreatedgroup)
            exitwhen u == null
            call groupremoveunit(bj_lastcreatedgroup, u)
            call setwidgetlife(u, 999999)
            call setunitstate(u, unit_state_mana, 999999)
            call unitresetcooldown(u)
        endloop
    endfunction
    private function chat takes nothing returns nothing
        local trigger t = createtrigger()
        local integer i = 12
        loop
            set i = i - 1
            call triggerregisterplayerchatevent(t, player(i), string, true)
            exitwhen i == 0
        endloop
        call triggeraddaction(t, function pick)
        set t = null
    endfunction
endscope

QUESTION:

JASS:

scope Refresh initializer Chat
    globals
        private constant string STRING = "-refresh"
        private constant player PLAYER = Player(0)
    endglobals
    private function Fresh takes nothing returns nothing
        call SetUnitLifePercentBJ(GetTriggerUnit(), 100)
        call SetUnitManaPercentBJ(GetTriggerUnit(), 100)
        call UnitResetCooldown(GetTriggerUnit())
    endfunction
    private function Pick takes nothing returns nothing
        call ForGroupBJ(GetUnitsOfPlayerAll(PLAYER), function Fresh)
    endfunction
    private function Chat takes nothing returns nothing
        call TriggerRegisterPlayerChatEvent(gg_trg_Refresh, PLAYER, STRING, true)
        call TriggerAddAction(gg_trg_Refresh, function Pick)
    endfunction
endscope

Those code was made by ME

It's got no syntax error!!

but it doesn't work
Here's what I want with that code:
1. Player enters chat "-refresh"
2. All unit owned by chatting player will be reseted it cooldowns, hp & mana

TriggerHappy · Apr 7, 2016

gg_trg_Refresh is a generated variable, are you sure it's created/initialized?

Using a local trigger would probably be best anyway, so this would work:

JASS:

scope Refresh initializer Chat

    globals
        private constant string STRING = "-refresh"
        private constant player PLAYER = Player(0)
    endglobals
    
    private function Pick takes nothing returns boolean
        local group g = CreateGroup()
        local unit u
        
        call GroupEnumUnitsOfPlayer(g, whichPlayer, null)
        
        loop
            set u = FirstOfGroup(g)
            exitwhen u == null
            
            call SetWidgetLife(u, 999999)
            call SetUnitState(u, UNIT_STATE_MANA, 999999)
            call UnitResetCooldown(u)

            call GroupRemoveUnit(g, u)
        endloop
        
        call DestroyGroup(g)
        set g = null
        
        return false
    endfunction
    
    private function Chat takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterPlayerChatEvent(t, PLAYER, STRING, true)
        call TriggerAddCondition(t, function Pick)
    endfunction
endscope

Bribe · Apr 7, 2016

Change GetTriggerUnit to GetEnumUnit. You also need to create the trigger before it can have any events. Also, this only works for Player 0 as it doesn't have any events for the other players.

FRENGERS · Apr 7, 2016

TriggerHappy said:

gg_trg_Refresh is a generated variable, are you sure it's created/initialized?

Using a local trigger would probably be best anyway, so this would work:

JASS:

scope Refresh initializer Chat

    globals
        private constant string STRING = "-refresh"
        private constant player PLAYER = Player(0)
    endglobals
    
    private function Pick takes nothing returns boolean
        local group g = CreateGroup()
        local unit u
        
        call GroupEnumUnitsOfPlayer(g, whichPlayer, null)
        
        loop
            set u = FirstOfGroup(g)
            exitwhen u == null
            
            call SetWidgetLife(u, 999999)
            call SetUnitState(u, UNIT_STATE_MANA, 999999)
            call UnitResetCooldown(u)
        endloop
        
        call DestroyGroup(g)
        set g = null
        
        return false
    endfunction
    
    private function Chat takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterPlayerChatEvent(t, PLAYER, STRING, true)
        call TriggerAddCondition(t, function Pick)
    endfunction
endscope

wow thanks, so gg_trg is just the variable, I didn't know it until now hehe thanks

well, gg_trg is my Trigger name

Change GetTriggerUnit to GetEnumUnit. You also need to create the trigger before it can have any events. Also, this only works for Player 0 as it doesn't have any events for the other players.

How to make it Chatting player??

EDIT:

Umm, TriggerHappy
It didn't work :/ :/

JASS:

scope Refresh initializer Chat
    globals
        private constant string STRING = "-refresh"
        private constant player PLAYER = Player(0)
    endglobals
    private function Fresh takes nothing returns boolean
        local group GROUP = CreateGroup()
        local unit UNITS
        call GroupEnumUnitsOfPlayer(GROUP, PLAYER, null)
        loop
            set UNITS = FirstOfGroup(GROUP)
            exitwhen UNITS == null
            call SetWidgetLife(UNITS, 9999999)
            call SetUnitState(UNITS, UNIT_STATE_MANA, 9999999)
            call UnitResetCooldown(UNITS)
        endloop
        call DestroyGroup(GROUP)
        set GROUP = null
        return false
    endfunction
    private function Chat takes nothing returns nothing
        local trigger THIS = CreateTrigger()
        call TriggerRegisterPlayerChatEvent(THIS, PLAYER, STRING, true)
        call TriggerAddCondition(THIS, function Fresh)
    endfunction
endscope

TriggerHappy · Apr 7, 2016

FRENGERS said:
wow thanks, so gg_trg is just the variable, I didn't know it until now hehe thanks
well, gg_trg is my Trigger name

Yeah when you create a new trigger in the editor it will generate a global variable for you.

This is normally initialized inside the generated InitTrig function and it would look like set gg_trg_Refresh = CreateTrigger( )

FRENGERS · Apr 7, 2016

TriggerHappy said:
Yeah when you create a new trigger in the editor it will generate a global variable for you.

This is normally initialized inside the generated InitTrig function and it would look like set gg_trg_Refresh = CreateTrigger( )

yups, but it didn't work for now, I've been following your code thou.....
EDIT:
It works now, thanks

Bribe · Apr 7, 2016

Here is what TriggerHappy made, but fixed several issues with it and added support for all human players.

JASS:

scope Refresh initializer Chat

    globals
        private constant string STRING = "-refresh"
    endglobals
    
    private function Pick takes nothing returns nothing
        local unit u
        
        call GroupEnumUnitsOfPlayer(bj_lastCreatedGroup, GetTriggerPlayer(), null)
        
        loop
            set u = FirstOfGroup(bj_lastCreatedGroup)
            exitwhen u == null
            call GroupRemoveUnit(bj_lastCreatedGroup, u)
            
            call SetWidgetLife(u, 999999)
            call SetUnitState(u, UNIT_STATE_MANA, 999999)
            call UnitResetCooldown(u)
        endloop
    endfunction
    
    private function Chat takes nothing returns nothing
        local trigger t = CreateTrigger()
        local integer i = 12
        loop
            set i = i - 1
            call TriggerRegisterPlayerChatEvent(t, Player(i), STRING, true)
            exitwhen i == 0
        endloop
        call TriggerAddAction(t, function Pick)
        set t = null
    endfunction
endscope

TriggerHappy · Apr 7, 2016

Yeah sorry forgot to remove the unit from the group in my script. Fixed.

I didn't run it through JassHelper either

FRENGERS · Apr 7, 2016

bribe said:

here is what triggerhappy made, but fixed several issues with it and added support for all human players.

JASS:

scope refresh initializer chat

    globals
        private constant string string = "-refresh"
    endglobals
    
    private function pick takes nothing returns nothing
        local unit u
        
        call groupenumunitsofplayer(bj_lastcreatedgroup, gettriggerplayer(), null)
        
        loop
            set u = firstofgroup(bj_lastcreatedgroup)
            exitwhen u == null
            call groupremoveunit(bj_lastcreatedgroup, u)
            
            call setwidgetlife(u, 999999)
            call setunitstate(u, unit_state_mana, 999999)
            call unitresetcooldown(u)
        endloop
    endfunction
    
    private function chat takes nothing returns nothing
        local trigger t = createtrigger()
        local integer i = 12
        loop
            set i = i - 1
            call triggerregisterplayerchatevent(t, player(i), string, true)
            exitwhen i == 0
        endloop
        call triggeraddaction(t, function pick)
        set t = null
    endfunction
endscope

THANKS!! Works perfectly

DracoL1ch · Apr 7, 2016

why would you like to use those functions to dead units? locusts? better exclude them from

FRENGERS · Apr 7, 2016

DracoL1ch said:
why would you like to use those functions to dead units? locusts? better exclude them from

hi DOTA Test Map maker

how to exclude them??

DracoL1ch · Apr 7, 2016

JASS:

loop
            set u = firstofgroup(bj_lastcreatedgroup)
            exitwhen u == null
            call groupremoveunit(bj_lastcreatedgroup, u)
            if GetHandleId(u)>0 and GetWidgetLife(u)>0.5 and GetUnitAbilityLevel(u,'Aloc')==0 then
            call setwidgetlife(u, 999999)
            call setunitstate(u, unit_state_mana, 999999)
            call unitresetcooldown(u)
endif
        endloop

Bribe · Apr 7, 2016

JASS:

scope Refresh initializer Chat

    globals
        private constant string STRING = "-refresh"
    endglobals
    
    private function Pick takes nothing returns nothing
        local unit u
        
        call GroupEnumUnitsOfPlayer(bj_lastCreatedGroup, GetTriggerPlayer(), null)
        
        loop
            set u = FirstOfGroup(bj_lastCreatedGroup)
            exitwhen u == null
            call GroupRemoveUnit(bj_lastCreatedGroup, u)
            
            if GetUnitAbilityLevel(u, 'Aloc') == 0 and not IsUnitType(u, UNIT_TYPE_DEAD) then
                call SetWidgetLife(u, 999999)
                call SetUnitState(u, UNIT_STATE_MANA, 999999)
                call UnitResetCooldown(u)
            endif
        endloop
    endfunction
    
    private function Chat takes nothing returns nothing
        local trigger t = CreateTrigger()
        local integer i = 12
        loop
            set i = i - 1
            call TriggerRegisterPlayerChatEvent(t, Player(i), STRING, true)
            exitwhen i == 0
        endloop
        call TriggerAddAction(t, function Pick)
        set t = null
    endfunction
endscope

DracoL1ch · Apr 7, 2016

those flag isn't enough to say if the unit is dead for sure. it may be non-existant or reincarnating

IcemanBo · Apr 7, 2016

Please don't remove the initial question. It is just confusing for people who read the thread later.

Bribe · Apr 7, 2016

DracoL1ch said:
those flag isn't enough to say if the unit is dead for sure. it may be non-existant or reincarnating

It is impossible to enumerate a removed ir decayed unit in a group. You only need that check if the unit was removed from the game after it was removed from the group. Not only that, but removed units will result "null" when using FirstOfGroup in those cases, which is why Captain Griffon added GroupRefresh.

FRENGERS · Apr 7, 2016

DracoL1ch said:
those flag isn't enough to say if the unit is dead for sure. it may be non-existant or reincarnating

DracoL1ch said:

JASS:

loop
            set u = firstofgroup(bj_lastcreatedgroup)
            exitwhen u == null
            call groupremoveunit(bj_lastcreatedgroup, u)
            if GetHandleId(u)>0 and GetWidgetLife(u)>0.5 and GetUnitAbilityLevel(u,'Aloc')==0 then
            call setwidgetlife(u, 999999)
            call setunitstate(u, unit_state_mana, 999999)
            call unitresetcooldown(u)
endif
        endloop

Bribe said:

JASS:

scope Refresh initializer Chat

    globals
        private constant string STRING = "-refresh"
    endglobals
    
    private function Pick takes nothing returns nothing
        local unit u
        
        call GroupEnumUnitsOfPlayer(bj_lastCreatedGroup, GetTriggerPlayer(), null)
        
        loop
            set u = FirstOfGroup(bj_lastCreatedGroup)
            exitwhen u == null
            call GroupRemoveUnit(bj_lastCreatedGroup, u)
            
            if GetUnitAbilityLevel(u, 'Aloc') == 0 and not IsUnitType(u, UNIT_TYPE_DEAD) then
                call SetWidgetLife(u, 999999)
                call SetUnitState(u, UNIT_STATE_MANA, 999999)
                call UnitResetCooldown(u)
            endif
        endloop
    endfunction
    
    private function Chat takes nothing returns nothing
        local trigger t = CreateTrigger()
        local integer i = 12
        loop
            set i = i - 1
            call TriggerRegisterPlayerChatEvent(t, Player(i), STRING, true)
            exitwhen i == 0
        endloop
        call TriggerAddAction(t, function Pick)
        set t = null
    endfunction
endscope

Which one I should choose??

DracoL1ch · Apr 7, 2016

bribe's full version. My versions are based on my experience with complex, outdated and mainly retarded code. Im trying to cover all possible cases, regardless how low chance of that to happen

Bribe · Apr 7, 2016

Mine, yes, and there are syntax errors in his version.

FRENGERS · Apr 7, 2016

By the way, I was using dracolich then and found no errors.
But okay, I'll follow Bribe's one

[General] [JASS] Refresh, doesn't work

Similar threads