Damage Engine 5.A.0.0

[Vovetc]

Is there a method to make system work with negative damage from abilities, created via Object Editor? For me it convets all negative damage to positive. I tried to use DamageEvent = 1.00, then check if DamageEventAmount < 0, but it doesnt work, looks like system converts damage prior that event.

 

[Bribe]

Yeah it does that because the system uses negative damage to determine if a spell is damaging or if it's physical/triggered.

Why are you using negative Object Editor Damage? Maybe there's another way to do what you're trying (ie. build that stuff into Damage Event triggers).

 

[Vovetc]

I try to make flexible leveling system for neutral creeps and for their spells - and your system makes it incredibly easy (just one trigger, which scale all creep spell damage from mana pool). Problem is healing, because i need to scale amount of healing from mana pool of source of healing. So i use spells with negative damage instead of heals like Rejuvenation.

I find a solution for this, but it is very clumsy. I check if spell damage was dealt to ally by unit, which have passive "Healer" and revert it to healing via DamageEvent = 1.00 trigger. It works fine, but with downside - a can't create creep with abilities to heal and damage allies
simultaneously.

 

[Bribe]

You may want to look into Heal Event for GUI, version 1.1.1.1 for the healing and just trigger your heals via spells that way.

 

[Bribe]

@MindWorX the map in the first quoted post has this issue. I've also quoted from Tasyen who reports the same.

For those who are on the 1.29 patch, this version of Damage Engine (attached) is now using the SetEventDamage native.

Benefits: no longer needs Cheat Death Ability, no longer needs custom fixes for Life Drain and Finger of Death, no longer creates a trigger for each damage instance.

Also, the Damage Return Value on Locust Swarm can be switched back to its default 0.75 instead of -0.75 which was previously needed.

Disadvantages: not compatible with code pre-1.29, may have bugs which I haven't spotted (though unlikely).

For now, I will leave the actual resource unchanged, but if enough people request it I will make this 1.29 version the default Damage Engine version.

//===========================================================================
// Damage Engine lets you detect, amplify, block or nullify damage. It even
// lets you detect if the damage was physical or from a spell. Just reference
// DamageEventAmount/Source/Target or the boolean IsDamageSpell, to get the
// necessary damage event data.
//
// - Detect damage: use the event "DamageEvent Equal to 1.00"
// - To change damage before it's dealt: use the event "DamageModifierEvent Equal to 1.00"
// - Detect damage after it was applied, use the event "AfterDamageEvent Equal to 1.00"
// - Detect spell damage: use the condition "IsDamageSpell Equal to True"
// - Detect zero-damage: use the event "DamageEvent Equal to 2.00" (an AfterDamageEvent will not fire for this)
//
// You can specify the DamageEventType before dealing triggered damage, then run the trigger "ClearDamageEvent (Checking Conditions)" after dealing triggered damage from within a damage event:
// - Set NextDamageType = DamageTypeWhatever
// - Unit - Cause...
// - Trigger - Run ClearDamageEvent (Checking Conditions)
//
// You can modify the DamageEventAmount and the DamageEventType from a "DamageModifierEvent Equal to 1.00" trigger.
// - If the amount is modified to negative, it will count as a heal.
// - If the amount is set to 0, no damage will be dealt.
//
// If you need to reference the original in-game damage, use the variable "DamageEventPrevAmt".
//
//===========================================================================
// Programming note about "integer i" and "udg_DmgEvRecursionN": integer i
// ranges from -1 upwards. "udg_DmgEvRecursionN" ranges from 0 upwards.
// "integer i" is always 1 less than "udg_DmgEvRecursionN"
//
function DmgEvResetVars takes nothing returns nothing
    local integer i = udg_DmgEvRecursionN - 2
    set udg_DmgEvRecursionN = i + 1
    if i >= 0 then
        set udg_DamageEventPrevAmt  = udg_LastDmgPrevAmount[i]
        set udg_DamageEventAmount   = udg_LastDmgValue[i]
        set udg_DamageEventSource   = udg_LastDmgSource[i]
        set udg_DamageEventTarget   = udg_LastDmgTarget[i]
        set udg_IsDamageSpell       = udg_LastDmgWasSpell[i]
        set udg_DamageEventType     = udg_LastDmgPrevType[i]
    endif
endfunction
function ClearDamageEvent takes boolean clear returns nothing
    if clear then
        set udg_NextDamageOverride = false
        set udg_NextDamageType = 0
    endif
    if udg_DmgEvQueued then
        //The 0-second timer has expired, or there had been multiple sequential damage events running in parallel.     
        set udg_DmgEvQueued = false
        set udg_AfterDamageEvent = 0.00
        set udg_AfterDamageEvent = 1.00 //No longer fires with Unit State Event detection - this is
        set udg_AfterDamageEvent = 0.00 //lighter on the system but will fire slightly later than before.
                                        //It now only serves for counter-damage after the initial damage.
        call ClearDamageEvent(true) //Check for any potential failed recursive damage from the previous event.
        call DmgEvResetVars()
    endif
endfunction
function DmgEvOnAOEEnd takes nothing returns nothing
    if udg_DamageEventAOE > 1 then
        set udg_AOEDamageEvent = 0.00
        set udg_AOEDamageEvent = 1.00
        set udg_AOEDamageEvent = 0.00
        set udg_DamageEventAOE = 1
    endif
    set udg_DamageEventLevel = 1
    set udg_EnhancedDamageTarget = null
    call GroupClear(udg_DamageEventAOEGroup)
endfunction
 
function DmgEvOnExpire takes nothing returns nothing
    set udg_DmgEvStarted = false //The timer has expired. Flag off to allow it to be restarted when needed.
    call ClearDamageEvent(true) //Check for any lingering damage
    //Reset things so they don't perpetuate for AoE/Level target detection
    call DmgEvOnAOEEnd()
    set udg_DamageEventTarget = null
    set udg_DamageEventSource = null
endfunction
function PreClearDamageEvent takes nothing returns boolean
    call ClearDamageEvent(true)
    return false
endfunction
function OnUnitDamage takes nothing returns boolean
    local boolean override = udg_DamageEventOverride
    local integer i
    local integer e = udg_DamageEventLevel
    local integer a = udg_DamageEventAOE
    local string s
    local unit u
    local unit f
    call ClearDamageEvent(false) //in case the 0.00 second timer hasn't yet expired
    set i = udg_DmgEvRecursionN - 1 //Had to be moved here due to false recursion tracking
    if i < 0 then
        //Added 25 July 2017 to detect AOE damage or multiple single-target damage
        set u                       = udg_DamageEventTarget
        set f                       = udg_DamageEventSource
    elseif i < 16 then
        set udg_LastDmgPrevAmount[i]= udg_DamageEventPrevAmt
        set udg_LastDmgValue[i]     = udg_DamageEventAmount
        set udg_LastDmgSource[i]    = udg_DamageEventSource
        set udg_LastDmgTarget[i]    = udg_DamageEventTarget
        set udg_LastDmgWasSpell[i]  = udg_IsDamageSpell
        set udg_LastDmgPrevType[i]  = udg_DamageEventType
    else
        set s = "WARNING: Recursion error when dealing damage! Make sure when you deal damage from within a DamageEvent trigger, do it like this:"
        set s = s + "Trigger - Turn off (This Trigger)"
        set s = s + "Unit - Cause..."
        set s = s + "Trigger - Run ClearDamageEvent (Checking Conditions)"
        set s = s + "Trigger - Turn on (This Trigger)"
    
        //Delete the next couple of lines to disable the in-game recursion crash warnings
        call ClearTextMessages()
        call DisplayTimedTextToPlayer(GetLocalPlayer(), 0.00, 0.00, 999.00, s)
        return false
    endif
    set udg_DmgEvRecursionN     = i + 2
    set udg_DamageEventAmount   = GetEventDamage()
    set udg_DamageEventTarget   = GetTriggerUnit()
    set udg_DamageEventSource   = GetEventDamageSource()
 
    set udg_DamageEventType     = udg_NextDamageType
    set udg_NextDamageType      = 0
    set udg_DamageEventOverride = udg_NextDamageOverride
    set udg_NextDamageOverride  = false
 
    if i < 0 then
        //Added 25 July 2017 to detect AOE damage or multiple single-target damage
        if udg_DamageEventType == 0 then
            if f == udg_DamageEventSource then
                //Source has damaged more than once
                if IsUnitInGroup(udg_DamageEventTarget, udg_DamageEventAOEGroup) then
                    //Added 5 August 2017 to improve tracking of enhanced damage against, say, Pulverize
                    set udg_DamageEventLevel = udg_DamageEventLevel + 1
                    set udg_EnhancedDamageTarget = udg_DamageEventTarget
                else
                    //Multiple targets hit by this source - flag as AOE
                    set udg_DamageEventAOE = udg_DamageEventAOE + 1
                endif
            else
                //New damage source - unflag everything
                set u = udg_DamageEventSource
                set udg_DamageEventSource = f
                call DmgEvOnAOEEnd()
                set udg_DamageEventSource = u
            endif
            call GroupAddUnit(udg_DamageEventAOEGroup, udg_DamageEventTarget)
        endif
        if not udg_DmgEvStarted then
            set udg_DmgEvStarted = true
            call TimerStart(udg_DmgEvTimer, 0.00, false, function DmgEvOnExpire)
        endif
    endif
 
    if udg_DamageEventAmount == 0.00 then
        if not udg_HideDamageFrom[GetUnitUserData(udg_DamageEventSource)] then
            set udg_DamageEventPrevAmt = 0.00
            set udg_DamageEvent = 0.00
            set udg_DamageEvent = 2.00
            set udg_DamageEvent = 0.00
        endif
        call DmgEvResetVars()
    else
        set u = udg_DamageEventTarget
        set udg_IsDamageSpell = udg_DamageEventAmount < 0.00
        if udg_IsDamageSpell then
            set udg_DamageEventAmount = -udg_DamageEventAmount
            if IsUnitType(u, UNIT_TYPE_ETHEREAL) and not IsUnitType(u, UNIT_TYPE_HERO) then
                set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_ETHEREAL //1.67
            endif
            if GetUnitAbilityLevel(u, 'Aegr') > 0 then
                set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_ELUNES //0.80
            endif
            if udg_DmgEvBracers != 0 and IsUnitType(u, UNIT_TYPE_HERO) then
                //Inline of UnitHasItemOfTypeBJ without the potential handle ID leak.
                set i = bj_MAX_INVENTORY
                loop
                    set i = i - 1
                    if GetItemTypeId(UnitItemInSlot(u, i)) == udg_DmgEvBracers then
                        set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_BRACERS //0.67
                        exitwhen true
                    endif
                    exitwhen i == 0
                endloop
            endif
        endif
        set udg_DamageEventPrevAmt = udg_DamageEventAmount
        set udg_DamageModifierEvent = 0.00
        if not udg_DamageEventOverride then
            set udg_DamageModifierEvent = 1.00 //Primary modification - multiplication, blocking, reversing, etc.
            set udg_DamageModifierEvent = 2.00 //Secondary Modification - addition/subtraction
            set udg_DamageModifierEvent = 3.00 //Similar to 2.00 but with knowing all previous addition/subtraction have run.
        endif
        if udg_DamageEventAmount > 0.00 then
            set udg_DamageModifierEvent = 4.00 //Apply finite damage modification such as Mana Shield or Anti-Magic Shell.
        endif
        set udg_DamageEventOverride = override
        set udg_DamageModifierEvent = 0.00
        if not udg_HideDamageFrom[GetUnitUserData(udg_DamageEventSource)] then
            set udg_DamageEvent = 0.00
            set udg_DamageEvent = 1.00
            set udg_DamageEvent = 0.00
        endif
        call ClearDamageEvent(true) //in case the unit state event failed from a recursive damage event
    
        //All events have run and the damage amount is finalized.
        call SetEventDamage(udg_DamageEventAmount)
        set udg_DmgEvQueued = true
        if udg_DamageEventType < 0 and GetWidgetLife(u) - udg_DamageEventAmount <= 0.405 then
            call SetUnitExploded(u, true) //In 1.29 Finger of Death works as intended.
        endif
    endif
    set u = null
    set f = null
    return false
endfunction
function CreateDmgEvTrg takes nothing returns nothing
    set udg_DamageEventTrigger = CreateTrigger()
    call TriggerAddCondition(udg_DamageEventTrigger, Filter(function OnUnitDamage))
endfunction
function SetupDmgEv takes nothing returns boolean
    local integer i = udg_UDex
    local unit u = udg_UDexUnits[i]
    if GetUnitAbilityLevel(u, 'Aloc') == 0 and TriggerEvaluate(gg_trg_Damage_Engine_Config) then
        set udg_UnitDamageRegistered[i] = true
        call TriggerRegisterUnitEvent(udg_DamageEventTrigger, u, EVENT_UNIT_DAMAGED)
        call UnitAddAbility(u, udg_SpellDamageAbility)
        call UnitMakeAbilityPermanent(u, true, udg_SpellDamageAbility)
    endif
    set u = null
    return false
endfunction
function RemoveDmgEv takes nothing returns boolean
    local integer i = udg_UDex
    set udg_HideDamageFrom[i] = false
    if udg_UnitDamageRegistered[i] then
        set udg_UnitDamageRegistered[i] = false
        set udg_DamageEventsWasted = udg_DamageEventsWasted + 1
        if udg_DamageEventsWasted == 32 then //After 32 registered units have been removed...
            set udg_DamageEventsWasted = 0
            
            //Rebuild the mass EVENT_UNIT_DAMAGED trigger:
            call DestroyTrigger(udg_DamageEventTrigger)
            call CreateDmgEvTrg()
            set i = udg_UDexNext[0]
            loop
                exitwhen i == 0
                if udg_UnitDamageRegistered[i] then
                    call TriggerRegisterUnitEvent(udg_DamageEventTrigger, udg_UDexUnits[i], EVENT_UNIT_DAMAGED)
                endif
                set i = udg_UDexNext[i]
            endloop
        endif
    endif
    return false
endfunction
 
//===========================================================================
function InitTrig_Damage_Engine takes nothing returns nothing
    local unit u = CreateUnit(Player(bj_PLAYER_NEUTRAL_EXTRA), 'uloc', 0, 0, 0)
    local integer i = bj_MAX_PLAYERS //Fixed in 3.8
 
    //Create trigger to add units to the system.
    local trigger t = CreateTrigger()
    call TriggerRegisterVariableEvent(t, "udg_UnitIndexEvent", EQUAL, 1.00)
    call TriggerAddCondition(t, Filter(function SetupDmgEv))
 
    //Create trigger to remove units from the system.
    set t = CreateTrigger()
    call TriggerRegisterVariableEvent(t, "udg_UnitIndexEvent", EQUAL, 2.00)
    call TriggerAddCondition(t, Filter(function RemoveDmgEv))
    set t = null
 
    //Execute the configuration function to first set all GUI variables:
    call ExecuteFunc("Trig_Damage_Engine_Config_Actions")
 
    //Create trigger for storing all EVENT_UNIT_DAMAGED events.
    call CreateDmgEvTrg()
 
    //Create GUI-friendly trigger for cleaning up after UnitDamageTarget.
    set udg_ClearDamageEvent = CreateTrigger()
    call TriggerAddCondition(udg_ClearDamageEvent, Filter(function PreClearDamageEvent))
 
    //Disable SpellDamageAbility for every player.
    loop
        set i = i - 1
        call SetPlayerAbilityAvailable(Player(i), udg_SpellDamageAbility, false)
        exitwhen i == 0
    endloop
 
    //Preload ability
    call UnitAddAbility(u, udg_SpellDamageAbility)
    call RemoveUnit(u)
    set u = null
endfunction

Hopping back into the editor, testing version 4.0.

edit: getting a little error on save:
View attachment 298610

Blizzard added "Blz" as Prefix to all new natives beeing publish with 1.29, on the PTR they did not have that prefix. Bribe seems to have used the naming from the PTR, SetEventDamage -> BlzSetEventDamage.

Probably because someone reported that some old map broke since it used functions with the same name as the native. My own map would have a SetUnitName if I had made it before the Producer Update was announced.

Adding the Blz prefix makes it much less likely that an old map would have a function with the same name. I believe they will probably follow the same pattern for all new natives in the future.

 

[goldviper]

Sorry to ask but is there any possible way to detect "Amount of armor" or "Physic dmg before reduction" when using this system. Many thank

 

[Bribe]

Sorry to ask but is there any possible way to detect "Amount of armor" or "Physic dmg before reduction" when using this system. Many thank

Not natively possible, but probably the most frequently requested feature. There are buggy solutions which can sometimes estimate or get those values, but they are prone to errors.

With patch 1.29+it is possible to get a unit's armor value (not type) and it is possible to calculate the average, min and max physical damage a unit can produce (but not the raw damage value from an event - Mana Shield for example is a 0 damage event).

 

[GaLaxY_256]

Got a question sir: Is it possible to do a healing fan of knives spell with Damage Engine? Here's the trigger:

Trigger

• FoK heal
  • Events
    • Game - DamageModifierEvent becomes Equal to 1.00
  • Conditions
    • (Current Order of DamageEventSource) Equal to (Order(fanofknives))
    • IsDamageSpell Equal to True
    • (Unit-type of DamageEventSource) Equal to Dummy
  • Actions
    • Set DamageEventAmount = (0.00 - DamageEventAmount)
    • Set DamageEventType = DamageTypeHealDamageTypeHeal
    • Game - Display to (All players) the text: It works!

The problem is that it damage instead of heal, whether damage in OE is set either positive or negative. It doesn't even show the "It works" text. How can I get it to work?

 

[Bribe]

The FoK order will only be on the unit for a brief moment, and the order will be gone before any unit takes damage.

 

[GaLaxY_256]

The FoK order will only be on the unit for a brief moment, and the order will be gone before any unit takes damage.

Ahh, okay. I think adding Berserk to dummy, order it to use it and check if dummy has Berserk buff may work. Thanks for replying sir
EDIT: It worked, thank you for this system ^^

 

[FallenAngel1999]

Outstanding system! Never thought GUI can do this much

A little bit unrelated, but can you help me with the damage tag trigger? I only want the floating texts showing damage higher than 5. With damage higher than 10000, the floating texts will show 'EXECUTED' instead of the actual damage.

 

[Bribe]

Use conditions to change a string variable.

If Damage < 5.00
Skip Remaining Actions

Else If Damage > 50,000
Set Your Text = Executed

Else
Set Your Text = Damage Amount

Then once you have the text you just create the floating text accordingly.

 

[FallenAngel1999]

Thanks! It works perfectly

Another question: How to detect pure damage? I have created a DamageTypePure variable, set it to 5 (so it won't interfere with other damage types) and every ability intended to deal pure damage have had the DamageEvenType set to DamageTypePure. However, the damage type keep gets mistaken as physical damage type from attacks. How can I fix this? Did I miss out a step in the configuration stage? Could you please provide an example trigger?

*If you are unsure what pure damage is, it is basically the pre-mitigated damage before armor and magic resist. If an ability deals 300 damage, the target loses exactly 300 health, no reduction

EDIT: Fixed it. I forgot the DamageModifierEvent trigger.

 

[ssbbssc2]

I found something weird thing, or maybe its just weird for me only
I created Spell Resistance spell based off Elunes Grace, set magic damage reduction to 50%
spell breaker type of unit does not have any benefits from it at all, BUT when i gave him hero inventory and item with the same ability - it worked and stacking well
dunno is this a glitch or else
and i know, i can catch it easily in DE and modify it, but i want to do it with passive, if it possible

Updated
looks like the only working version of Elune Grace is an original, any based off copy wont work at all :\

 

[Bribe]

You have to set its resistance to a negative value or remove the resistance altogether and just use Damage Engine to check if the unit carries the item and reduce accordingly.

 

[ssbbssc2]

yeah, it can be easily done with DE (as i said)
i mean, based off copy of Elune does not work at all, if they given to unit directly in Object Editor

 

[Bribe]

Yeah that's because Damage Engine doesn't recognize an Elune's Grace item ability unless you insert it into the system manually. It only recognizes the default Elune's Grace item.

My recommendation is either base the reduction of of Spell Reduction Ability and use a negative value inverse to the positive value you want to block, or again just use your own damage modifying trigger.

 

[ssbbssc2]

looks like the least hard way is to use damage modifying trigger
meh

 

[goldviper]

@Bribe Dear Mr B. With patch 1.29 , we now has func that detect the "number of armor" unit have.
Could you some way implant the current wc3 physical damage caculation into the system.
Like: Dmg Multiplier = 1 - ( 1 - 0.06)^armor
Or maybe some option to create your own armor system like : Dmg Multiplier = 1 - (0.05 × armor ÷ (1 + 0.05 × |armor|))
we know that the current wc3 Dmg Multiplier cap at 200% and -71% so this is might change.
I just think that with this we can know the physical dmg before reduction
Like we could use to create "Cleave/Splash" skill that effect by armor amount ,
Dmg Block/Mana Shield that block dmg before any armor
Dmg "Return" skill
Ect.

 

[Bribe]

It's a useless attempt at getting the damage before reduction unless all in-game armor and damage types are inherently known. Until/if THOSE natives are added, I'm not wasting my time integrating a half-assed solution to a (universally) unsolvable problem.

If at least a native existed to determine the pre-in-game modified amount (before Mana Shield and Hardened Skin are applied), I could get rid of the remaining "spell fixer" triggers.

 

[XydenicWings]

Greetings Bribe,

Just begun to use this system and I'm totally loving it, just a question.

The code for your mana shield fix seems like intended to absorb 100% of the damage, if in the case of 50% absorb, I was thinking to set 50% of DamageEventAmount to a variable and add to back at the end. Can it work that way?

 

[Bribe]

Yes, before any math is done, set Damage Event Amount to a temporary Real variable, divide that variable by 2.00, then add that amount to Damage Event Amount at the bottom of the Man's Shield Fix trigger.

 

[FallenAngel1999]

Can this system track pre-mitigated damage (the damage before any reductions occur)? I have an ability that cause affected unit to take pre-mitigated damage for a while. I would like to know which events/variables in your system that can track this damage.

 

[Bribe]

Can this system track pre-mitigated damage (the damage before any reductions occur)? I have an ability that cause affected unit to take pre-mitigated damage for a while. I would like to know which events/variables in your system that can track this damage.

It's impossible to know what armor type a unit has, even though the latest patches allow you to know how much armor one has. So you can get part of the way there, but not enough to guarantee accuracy.

One thing you can do is not rely on in-game attack types and armor types to apply (ie. set them all to 100%), then use Damage Engine to process any further corrections. This gives you more control and allows to change effective armor and damage types at your whim.

Lastly, even if Blizzard adds GetEventDamageType and GetUnitArmorType, they'd also need to either make natives to get the Map settings for those multipliers, or the user would have to manually configure them.

 

[XydenicWings]

Yes, before any math is done, set Damage Event Amount to a temporary Real variable, divide that variable by 2.00, then add that amount to Damage Event Amount at the bottom of the Man's Shield Fix trigger.

Thanks for the clarification. I do come across another problem, IsDamageSpell = true is not working in my custom map. Perhaps some external factors affecting this, any ideas?

 

[Bribe]

Thanks for the clarification. I do come across another problem, IsDamageSpell = true is not working in my custom map. Perhaps some external factors affecting this, any ideas?

Ensure you have copied the spell damage detection to the map you're using, and configure the SpellDamageDetect ability to it.

 

[XydenicWings]

Ensure you have copied the spell damage detection to the map you're using, and configure the SpellDamageDetect ability to it.

Oh dam, I forgotten about it. Thanks a lot it works now.

 

[Bribe]

For those who are on the 1.29 patch, this version of Damage Engine (attached) is now using the SetEventDamage native.

Benefits: no longer needs Cheat Death Ability, no longer needs custom fixes for Life Drain and Finger of Death, no longer creates a trigger for each damage instance.

Also, the Damage Return Value on Locust Swarm can be switched back to its default 0.75 instead of -0.75 which was previously needed.

Disadvantages: not compatible with code pre-1.29, may have bugs which I haven't spotted (though unlikely).

For now, I will leave the actual resource unchanged, but if enough people request it I will make this 1.29 version the default Damage Engine version.

//===========================================================================
// Damage Engine lets you detect, amplify, block or nullify damage. It even
// lets you detect if the damage was physical or from a spell. Just reference
// DamageEventAmount/Source/Target or the boolean IsDamageSpell, to get the
// necessary damage event data.
//
// - Detect damage: use the event "DamageEvent Equal to 1.00"
// - To change damage before it's dealt: use the event "DamageModifierEvent Equal to 1.00"
// - Detect damage after it was applied, use the event "AfterDamageEvent Equal to 1.00"
// - Detect spell damage: use the condition "IsDamageSpell Equal to True"
// - Detect zero-damage: use the event "DamageEvent Equal to 2.00" (an AfterDamageEvent will not fire for this)
//
// You can specify the DamageEventType before dealing triggered damage, then run the trigger "ClearDamageEvent (Checking Conditions)" after dealing triggered damage from within a damage event:
// - Set NextDamageType = DamageTypeWhatever
// - Unit - Cause...
// - Trigger - Run ClearDamageEvent (Checking Conditions)
//
// You can modify the DamageEventAmount and the DamageEventType from a "DamageModifierEvent Equal to 1.00" trigger.
// - If the amount is modified to negative, it will count as a heal.
// - If the amount is set to 0, no damage will be dealt.
//
// If you need to reference the original in-game damage, use the variable "DamageEventPrevAmt".
//
//===========================================================================
// Programming note about "integer i" and "udg_DmgEvRecursionN": integer i
// ranges from -1 upwards. "udg_DmgEvRecursionN" ranges from 0 upwards.
// "integer i" is always 1 less than "udg_DmgEvRecursionN"
//
function DmgEvResetVars takes nothing returns nothing
    local integer i = udg_DmgEvRecursionN - 2
    set udg_DmgEvRecursionN = i + 1
    if i >= 0 then
        set udg_DamageEventPrevAmt  = udg_LastDmgPrevAmount[i]
        set udg_DamageEventAmount   = udg_LastDmgValue[i]
        set udg_DamageEventSource   = udg_LastDmgSource[i]
        set udg_DamageEventTarget   = udg_LastDmgTarget[i]
        set udg_IsDamageSpell       = udg_LastDmgWasSpell[i]
        set udg_DamageEventType     = udg_LastDmgPrevType[i]
    endif
endfunction
function ClearDamageEvent takes boolean clear returns nothing
    if clear then
        set udg_NextDamageOverride = false
        set udg_NextDamageType = 0
    endif
    if udg_DmgEvQueued then
        //The 0-second timer has expired, or there had been multiple sequential damage events running in parallel.   
        set udg_DmgEvQueued = false
        set udg_AfterDamageEvent = 0.00
        set udg_AfterDamageEvent = 1.00 //No longer fires with Unit State Event detection - this is
        set udg_AfterDamageEvent = 0.00 //lighter on the system but will fire slightly later than before.
                                        //It now only serves for counter-damage after the initial damage.
        call ClearDamageEvent(true) //Check for any potential failed recursive damage from the previous event.
        call DmgEvResetVars()
    endif
endfunction
function DmgEvOnAOEEnd takes nothing returns nothing
    if udg_DamageEventAOE > 1 then
        set udg_AOEDamageEvent = 0.00
        set udg_AOEDamageEvent = 1.00
        set udg_AOEDamageEvent = 0.00
        set udg_DamageEventAOE = 1
    endif
    set udg_DamageEventLevel = 1
    set udg_EnhancedDamageTarget = null
    call GroupClear(udg_DamageEventAOEGroup)
endfunction
 
function DmgEvOnExpire takes nothing returns nothing
    set udg_DmgEvStarted = false //The timer has expired. Flag off to allow it to be restarted when needed.
    call ClearDamageEvent(true) //Check for any lingering damage
    //Reset things so they don't perpetuate for AoE/Level target detection
    call DmgEvOnAOEEnd()
    set udg_DamageEventTarget = null
    set udg_DamageEventSource = null
endfunction
function PreClearDamageEvent takes nothing returns boolean
    call ClearDamageEvent(true)
    return false
endfunction
function OnUnitDamage takes nothing returns boolean
    local boolean override = udg_DamageEventOverride
    local integer i
    local integer e = udg_DamageEventLevel
    local integer a = udg_DamageEventAOE
    local string s
    local unit u
    local unit f
    call ClearDamageEvent(false) //in case the 0.00 second timer hasn't yet expired
    set i = udg_DmgEvRecursionN - 1 //Had to be moved here due to false recursion tracking
    if i < 0 then
        //Added 25 July 2017 to detect AOE damage or multiple single-target damage
        set u                       = udg_DamageEventTarget
        set f                       = udg_DamageEventSource
    elseif i < 16 then
        set udg_LastDmgPrevAmount[i]= udg_DamageEventPrevAmt
        set udg_LastDmgValue[i]     = udg_DamageEventAmount
        set udg_LastDmgSource[i]    = udg_DamageEventSource
        set udg_LastDmgTarget[i]    = udg_DamageEventTarget
        set udg_LastDmgWasSpell[i]  = udg_IsDamageSpell
        set udg_LastDmgPrevType[i]  = udg_DamageEventType
    else
        set s = "WARNING: Recursion error when dealing damage! Make sure when you deal damage from within a DamageEvent trigger, do it like this:"
        set s = s + "Trigger - Turn off (This Trigger)"
        set s = s + "Unit - Cause..."
        set s = s + "Trigger - Run ClearDamageEvent (Checking Conditions)"
        set s = s + "Trigger - Turn on (This Trigger)"
  
        //Delete the next couple of lines to disable the in-game recursion crash warnings
        call ClearTextMessages()
        call DisplayTimedTextToPlayer(GetLocalPlayer(), 0.00, 0.00, 999.00, s)
        return false
    endif
    set udg_DmgEvRecursionN     = i + 2
    set udg_DamageEventAmount   = GetEventDamage()
    set udg_DamageEventTarget   = GetTriggerUnit()
    set udg_DamageEventSource   = GetEventDamageSource()
 
    set udg_DamageEventType     = udg_NextDamageType
    set udg_NextDamageType      = 0
    set udg_DamageEventOverride = udg_NextDamageOverride
    set udg_NextDamageOverride  = false
 
    if i < 0 then
        //Added 25 July 2017 to detect AOE damage or multiple single-target damage
        if udg_DamageEventType == 0 then
            if f == udg_DamageEventSource then
                //Source has damaged more than once
                if IsUnitInGroup(udg_DamageEventTarget, udg_DamageEventAOEGroup) then
                    //Added 5 August 2017 to improve tracking of enhanced damage against, say, Pulverize
                    set udg_DamageEventLevel = udg_DamageEventLevel + 1
                    set udg_EnhancedDamageTarget = udg_DamageEventTarget
                else
                    //Multiple targets hit by this source - flag as AOE
                    set udg_DamageEventAOE = udg_DamageEventAOE + 1
                endif
            else
                //New damage source - unflag everything
                set u = udg_DamageEventSource
                set udg_DamageEventSource = f
                call DmgEvOnAOEEnd()
                set udg_DamageEventSource = u
            endif
            call GroupAddUnit(udg_DamageEventAOEGroup, udg_DamageEventTarget)
        endif
        if not udg_DmgEvStarted then
            set udg_DmgEvStarted = true
            call TimerStart(udg_DmgEvTimer, 0.00, false, function DmgEvOnExpire)
        endif
    endif
 
    if udg_DamageEventAmount == 0.00 then
        if not udg_HideDamageFrom[GetUnitUserData(udg_DamageEventSource)] then
            set udg_DamageEventPrevAmt = 0.00
            set udg_DamageEvent = 0.00
            set udg_DamageEvent = 2.00
            set udg_DamageEvent = 0.00
        endif
        call DmgEvResetVars()
    else
        set u = udg_DamageEventTarget
        set udg_IsDamageSpell = udg_DamageEventAmount < 0.00
        if udg_IsDamageSpell then
            set udg_DamageEventAmount = -udg_DamageEventAmount
            if IsUnitType(u, UNIT_TYPE_ETHEREAL) and not IsUnitType(u, UNIT_TYPE_HERO) then
                set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_ETHEREAL //1.67
            endif
            if GetUnitAbilityLevel(u, 'Aegr') > 0 then
                set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_ELUNES //0.80
            endif
            if udg_DmgEvBracers != 0 and IsUnitType(u, UNIT_TYPE_HERO) then
                //Inline of UnitHasItemOfTypeBJ without the potential handle ID leak.
                set i = bj_MAX_INVENTORY
                loop
                    set i = i - 1
                    if GetItemTypeId(UnitItemInSlot(u, i)) == udg_DmgEvBracers then
                        set udg_DamageEventAmount = udg_DamageEventAmount*udg_DAMAGE_FACTOR_BRACERS //0.67
                        exitwhen true
                    endif
                    exitwhen i == 0
                endloop
            endif
        endif
        set udg_DamageEventPrevAmt = udg_DamageEventAmount
        set udg_DamageModifierEvent = 0.00
        if not udg_DamageEventOverride then
            set udg_DamageModifierEvent = 1.00 //Primary modification - multiplication, blocking, reversing, etc.
            set udg_DamageModifierEvent = 2.00 //Secondary Modification - addition/subtraction
            set udg_DamageModifierEvent = 3.00 //Similar to 2.00 but with knowing all previous addition/subtraction have run.
        endif
        if udg_DamageEventAmount > 0.00 then
            set udg_DamageModifierEvent = 4.00 //Apply finite damage modification such as Mana Shield or Anti-Magic Shell.
        endif
        set udg_DamageEventOverride = override
        set udg_DamageModifierEvent = 0.00
        if not udg_HideDamageFrom[GetUnitUserData(udg_DamageEventSource)] then
            set udg_DamageEvent = 0.00
            set udg_DamageEvent = 1.00
            set udg_DamageEvent = 0.00
        endif
        call ClearDamageEvent(true) //in case the unit state event failed from a recursive damage event
  
        //All events have run and the damage amount is finalized.
        call BlzSetEventDamage(udg_DamageEventAmount)
        set udg_DmgEvQueued = true
        if udg_DamageEventType < 0 and GetWidgetLife(u) - udg_DamageEventAmount <= 0.405 then
            call SetUnitExploded(u, true) //In 1.29 Finger of Death works as intended.
        endif
    endif
    set u = null
    set f = null
    return false
endfunction
function CreateDmgEvTrg takes nothing returns nothing
    set udg_DamageEventTrigger = CreateTrigger()
    call TriggerAddCondition(udg_DamageEventTrigger, Filter(function OnUnitDamage))
endfunction
function SetupDmgEv takes nothing returns boolean
    local integer i = udg_UDex
    local unit u = udg_UDexUnits[i]
    if GetUnitAbilityLevel(u, 'Aloc') == 0 and TriggerEvaluate(gg_trg_Damage_Engine_Config) then
        set udg_UnitDamageRegistered[i] = true
        call TriggerRegisterUnitEvent(udg_DamageEventTrigger, u, EVENT_UNIT_DAMAGED)
        call UnitAddAbility(u, udg_SpellDamageAbility)
        call UnitMakeAbilityPermanent(u, true, udg_SpellDamageAbility)
    endif
    set u = null
    return false
endfunction
function RemoveDmgEv takes nothing returns boolean
    local integer i = udg_UDex
    set udg_HideDamageFrom[i] = false
    if udg_UnitDamageRegistered[i] then
        set udg_UnitDamageRegistered[i] = false
        set udg_DamageEventsWasted = udg_DamageEventsWasted + 1
        if udg_DamageEventsWasted == 32 then //After 32 registered units have been removed...
            set udg_DamageEventsWasted = 0
          
            //Rebuild the mass EVENT_UNIT_DAMAGED trigger:
            call DestroyTrigger(udg_DamageEventTrigger)
            call CreateDmgEvTrg()
            set i = udg_UDexNext[0]
            loop
                exitwhen i == 0
                if udg_UnitDamageRegistered[i] then
                    call TriggerRegisterUnitEvent(udg_DamageEventTrigger, udg_UDexUnits[i], EVENT_UNIT_DAMAGED)
                endif
                set i = udg_UDexNext[i]
            endloop
        endif
    endif
    return false
endfunction
 
//===========================================================================
function InitTrig_Damage_Engine takes nothing returns nothing
    local unit u = CreateUnit(Player(bj_PLAYER_NEUTRAL_EXTRA), 'uloc', 0, 0, 0)
    local integer i = bj_MAX_PLAYERS //Fixed in 3.8
 
    //Create trigger to add units to the system.
    local trigger t = CreateTrigger()
    call TriggerRegisterVariableEvent(t, "udg_UnitIndexEvent", EQUAL, 1.00)
    call TriggerAddCondition(t, Filter(function SetupDmgEv))
 
    //Create trigger to remove units from the system.
    set t = CreateTrigger()
    call TriggerRegisterVariableEvent(t, "udg_UnitIndexEvent", EQUAL, 2.00)
    call TriggerAddCondition(t, Filter(function RemoveDmgEv))
    set t = null
 
    //Execute the configuration function to first set all GUI variables:
    call ExecuteFunc("Trig_Damage_Engine_Config_Actions")
 
    //Create trigger for storing all EVENT_UNIT_DAMAGED events.
    call CreateDmgEvTrg()
 
    //Create GUI-friendly trigger for cleaning up after UnitDamageTarget.
    set udg_ClearDamageEvent = CreateTrigger()
    call TriggerAddCondition(udg_ClearDamageEvent, Filter(function PreClearDamageEvent))
 
    //Disable SpellDamageAbility for every player.
    loop
        set i = i - 1
        call SetPlayerAbilityAvailable(Player(i), udg_SpellDamageAbility, false)
        exitwhen i == 0
    endloop
 
    //Preload ability
    call UnitAddAbility(u, udg_SpellDamageAbility)
    call RemoveUnit(u)
    set u = null
endfunction

I've re-uploaded the map. The actual resource is still forwards- and backwards-compatible, but for those who want a fully 1.29+ resource, find it attached to this post.

 

[Bribe]

Can this system track pre-mitigated damage (the damage before any reductions occur)? I have an ability that cause affected unit to take pre-mitigated damage for a while. I would like to know which events/variables in your system that can track this damage.

Sorry to double-post, but I want to make sure you get a notification in case this is of interest to you or one of the others asking.

While what I replied is true, you *can* use a calculation (1.29+) to get the unit's base damage from attack index 1 or 2 (though you wouldn't know which one of the two it was damaging with):

set udg_DamageEventAmount = BlzGetUnitBaseDamage(udg_DamageEventSource, 1) + (BlzGetUnitDiceNumber(udg_DamageEventSource, 1) * BlzGetUnitDiceSides(udg_DamageEventSource, 1))

This won't work with Critical Strike or if the damage came from a spell. It also re-calculates the damage using a potentially different random number from what WC3 calculated. But it is a valid pre-armor value nevertheless.

 

[FallenAngel1999]

Sorry to double-post, but I want to make sure you get a notification in case this is of interest to you or one of the others asking.

While what I replied is true, you *can* use a calculation (1.29+) to get the unit's base damage from attack index 1 or 2 (though you wouldn't know which one of the two it was damaging with):

set udg_DamageEventAmount = BlzGetUnitBaseDamage(udg_DamageEventSource, 1) + (BlzGetUnitDiceNumber(udg_DamageEventSource, 1) * BlzGetUnitDiceSides(udg_DamageEventSource, 1))

This won't work with Critical Strike or if the damage came from a spell. It also re-calculates the damage using a potentially different random number from what WC3 calculated. But it is a valid pre-armor value nevertheless.

I see. Thanks a lot for the information. The problem with Blizzard is that they have too many damage and armor types. In my map all values are set to 1.0 ( which means damage is modified based on the value of armor rather than its type).

 

[Bribe]

I see. Thanks a lot for the information. The problem with Blizzard is that they have too many damage and armor types. In my map all values are set to 1.0 ( which means damage is modified based on the value of armor rather than its type).

Then you can use BlzGetUnitArmor (1.29+) and use the following calculation to see how the damage was scaled:

(armor * 0.06) / (1 + (armor * 0.06))

(provided that the in-game constant wasn't changed... 0.06 should match that constant).

 

[Psichrone]

I somehow came across a problem, does having multiple triggers with "DamageEvent becomes Equal to 1" cause to not stack?

 

[Bribe]

I somehow came across a problem, does having multiple triggers with "DamageEvent becomes Equal to 1" cause to not stack?

You can have as many of those events/triggers as you want. What is the problem? Can you post a map or your triggers?

 

[Psichrone]

I'll explain each trigger what it's supposed to do

• Blood Sword
  • Events
    • Game - DamageEvent becomes Equal to 1.00
  • Conditions
    • IsDamageSpell Equal to False
    • (DamageEventSource has an item of type Blood Lotus) Equal to True
  • Actions
    • Set Instant_Integer = (Instant_Integer + 1)
    • Set Instant_Caster[Instant_Integer] = DamageEventSource
    • Set Instant_Damage[Instant_Integer] = DamageEventAmount
    • Set Item_Same = 0
    • Set Item_Type = Blood Lotus
    • For each (Integer ItemCount) from 1 to 6, do (Actions)
      • Loop - Actions
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • (Item-type of (Item carried by Instant_Caster[Instant_Integer] in slot ItemCount)) Equal to Item_Type
          • Then - Actions
            • Set Item_Same = (Item_Same + 1)
          • Else - Actions
    • Unit - Set life of Instant_Caster[Instant_Integer] to ((Life of Instant_Caster[Instant_Integer]) + (Instant_Damage[Instant_Integer] x (0.25 x (Real(Item_Same)))))
    • Special Effect - Create a special effect attached to the chest of Instant_Caster[Instant_Integer] using Objects\Spawnmodels\Other\HumanBloodCinematicEffect\HumanBloodCinematicEffect.mdl
    • Special Effect - Destroy (Last created special effect)
    • Set Instant_Integer = (Instant_Integer - 1)

Dealing NON-SPELL damage grants lifesteal

• Chaos Blade
  • Events
    • Game - DamageEvent becomes Equal to 1.00
  • Conditions
    • IsDamageSpell Equal to False
    • (DamageEventSource has an item of type Chaos Blade) Equal to True
  • Actions
    • Set Instant_Integer = (Instant_Integer + 1)
    • Set Instant_Caster[Instant_Integer] = DamageEventSource
    • Set Instant_Target[Instant_Integer] = DamageEventTarget
    • Set Item_Same = 0
    • Set Item_Type = Chaos Blade
    • For each (Integer ItemCount) from 1 to 6, do (Actions)
      • Loop - Actions
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • (Item-type of (Item carried by Instant_Caster[Instant_Integer] in slot ItemCount)) Equal to Item_Type
          • Then - Actions
            • Set Item_Same = (Item_Same + 1)
          • Else - Actions
    • Set Instant_Damage[Instant_Integer] = (75.00 x (Real(Item_Same)))
    • Unit - Cause Instant_Caster[Instant_Integer] to damage Instant_Target[Instant_Integer], dealing Instant_Damage[Instant_Integer] damage of attack type Spells and damage type Normal
    • Set Instant_Integer = (Instant_Integer - 1)

Dealing NON-SPELL damage deals bonus SPELL damage

• Elven Greatsword
  • Events
    • Game - DamageEvent becomes Equal to 1.00
  • Conditions
    • IsDamageSpell Equal to True
    • (Peon_Unit[(Player number of (Owner of DamageEventSource))] has an item of type Elven Greatsword) Equal to True
    • Or - Any (Conditions) are true
      • Conditions
        • (Unit-type of DamageEventSource) Equal to Peon
        • (Unit-type of DamageEventSource) Equal to DummyUnit
  • Actions
    • Set Instant_Integer = (Instant_Integer + 1)
    • Set Instant_Caster[Instant_Integer] = DamageEventSource
    • Set Instant_Target[Instant_Integer] = DamageEventTarget
    • Set Instant_Point[Instant_Integer] = (Position of Instant_Target[Instant_Integer])
    • Set Item_Same = 0
    • Set Item_Type = Elven Greatsword
    • For each (Integer ItemCount) from 1 to 6, do (Actions)
      • Loop - Actions
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • (Item-type of (Item carried by Instant_Caster[Instant_Integer] in slot ItemCount)) Equal to Item_Type
          • Then - Actions
            • Set Item_Same = (Item_Same + 1)
          • Else - Actions
    • Unit - Create 1 DummyUnit for Instant_Owner[Instant_Integer] at Instant_Point[Instant_Integer] facing (Facing of Instant_Caster[Instant_Integer]) degrees
    • Unit - Add a 1.00 second Generic expiration timer to (Last created unit)
    • Unit - Add Faerie Fire (Item) to (Last created unit)
    • Unit - Set level of Faerie Fire (Item) for (Last created unit) to Item_Same
    • Unit - Order (Last created unit) to Night Elf Druid Of The Talon - Faerie Fire Instant_Target[Instant_Integer]
    • Custom script: call RemoveLocation (udg_Instant_Point[udg_Instant_Integer])
    • Set Instant_Integer = (Instant_Integer - 1)

Dealing SPELL damage applies Faery Fire to enemies hit

• Death Frost
  • Events
    • Game - DamageEvent becomes Equal to 1.00
  • Conditions
    • IsDamageSpell Equal to True
    • (Peon_Unit[(Player number of (Owner of DamageEventSource))] has an item of type Death Frost) Equal to True
    • (Level of Frost Nova (Custom) for DamageEventSource) Equal to 0
    • Or - Any (Conditions) are true
      • Conditions
        • (Unit-type of DamageEventSource) Equal to Peon
        • (Unit-type of DamageEventSource) Equal to DummyUnit
  • Actions
    • Set Instant_Integer = (Instant_Integer + 1)
    • Set Instant_Caster[Instant_Integer] = DamageEventSource
    • Set Instant_Owner[Instant_Integer] = (Owner of Instant_Caster[Instant_Integer])
    • Set Instant_Target[Instant_Integer] = DamageEventTarget
    • Set Instant_Point[Instant_Integer] = (Position of Instant_Target[Instant_Integer])
    • Set Item_Same = 0
    • Set Item_Type = Death Frost
    • For each (Integer ItemCount) from 1 to 6, do (Actions)
      • Loop - Actions
        • If (All Conditions are True) then do (Then Actions) else do (Else Actions)
          • If - Conditions
            • (Item-type of (Item carried by Instant_Caster[Instant_Integer] in slot ItemCount)) Equal to Item_Type
          • Then - Actions
            • Set Item_Same = (Item_Same + 1)
          • Else - Actions
    • Unit - Create 1 DummyUnit for Instant_Owner[Instant_Integer] at Instant_Point[Instant_Integer] facing (Facing of Instant_Caster[Instant_Integer]) degrees
    • Unit - Add a 1.00 second Generic expiration timer to (Last created unit)
    • Unit - Add Frost Nova (Custom) to (Last created unit)
    • Unit - Set level of Frost Nova (Custom) for (Last created unit) to Item_Same
    • Unit - Order (Last created unit) to Undead Lich - Frost Nova Instant_Target[Instant_Integer]
    • Custom script: call RemoveLocation (udg_Instant_Point[udg_Instant_Integer])
    • Set Instant_Integer = (Instant_Integer - 1)

Dealing SPELL damage apply Frost Nova to enemy hit

Now I shall describe what was happening in game
Now if I were to have all 4 Items (At any slot location)
-Lifesteal - ABSENT (No lifesteal at all)
-Frost Nova - ABSENT
-Spell Damage - Present
-Faery Fire - Present

Removed Lifesteal Item
-Frost Nova - ABSENT
-Spell Damage - Present
-Faery Fire - Present

Removed Lifesteal AND Faery Fire Item
-Frost Nova - Present
-Spell Damage - Present

Removed Faery Fire Item
-Lifesteal - ABSENT
-Frost Nova - Present
-Spell Damage - Present

I think I got a little confused with handling your system and also got tangled with my own mechanics

 

[Psichrone]

So in theory it's supposed to apply Frost Nova and Faery Fire, cause of the SPELL damage it dealt and grant lifesteal

 

[Bribe]

I'm not sure why you're using the InstantCaster stuff instead of directly referencing the DamageEventSource and target. DamageEngine already handles recursion internally so you don't have to.

Additionally, you can turn off DamageEventTrigger, deal the damage, then turn it back on, if you don't want that additional damage to be processed by anything (or turn off the (this trigger))

 

[Psichrone]

I use the InstantCaster to make it easier to copy paste things but does it cause problems?

 

[Bribe]

I use the InstantCaster to make it easier to copy paste things but does it cause problems?

It's probably the reason why the consistency in your code could be failing.

One thing you could also do is run the trigger (Clear Damage Event) after the UnitDamage function. Otherwise, turn off the DamageEventTrigger, deal damage, then turn it back on (though this will screw up the inverse spell damage detection, so you'd have to deal spell damage as negative damage).

 

[Psichrone]

I changed back "Instant_Caster" and "Instant_Target" back to "DamageEventSource" and "DamageEventTarget" it had the same results as the previous

 

[Bribe]

Can you please send over the map in its current state and let me know what I need to do to reproduce the issue? I have no idea what's wrong based on these triggers.

PM me the map if you're concerned about someone else taking it. I can assure you I would not steal your work.

 

[Psichrone]

neh it's ok, Imma just post it here I'm planning to post it unprotected anyway. So in the triggers there is a folder named "HERE IT IS" I've already placed some of the items that caused non-stacking issues, I've also placed the items near the HERO relevant to the active trigger in the "HERE IT IS" Folder I've also disabled most of the Item related triggers but there might still be a trigger that inteferes though (I figured cause disabling some of them solved the lifesteal issue), it can reproduced by example from what I've noticed triggers that require a Dummy to cast a spell

 

[Psichrone]

oh try getting all the items on the ground except the Phase Gloves, its effect will only have Faery Fire(Might be caused by the spell damage though), Lifesteal

[EDIT]: Oh and in the trigger name the ending of "InstantVar Use" means I used the Instant_Caster and Instant_Target Variable while "NoVar Use" means I used the "DamageEventSource" and "DamageEventTarget"

 

[doomhammer99]

gonna try this out

 

[Devalut]

Bribe, what is the most efficient way to detect a specific 0 damage projectile ability?
(i.e. Stormbolt/acidbomb with regular missile speed, homing, 0 damage, and to only one target)
My goal is to create a simple projectile ability that does damage based on a value like (Attribute/mana/health) while keeping it simple and mui.


Example is what I've been doing so far

Spoiler

• Frost bolt
  • Events
    • Game - DamageEvent becomes Equal to 2.00
  • Conditions
    • (DamageEventTarget has buff Frost bolt ) Equal to True
  • Actions
    • Unit - Remove Frost bolt buff from DamageEventTarget
    • Set TempInteger = 0
    • For each (Integer A) from 1 to 4, do (Actions)
      • Loop - Actions
        • Set TempInteger = (TempInteger + (Random integer number between 1 and 6))
    • Unit - Cause DamageEventSource to damage DamageEventTarget, dealing (Real((10 x TempInteger))) damage of attack type Spells and damage type Universal
• [/spoiler]

 

[Spacebuns]

You should use the "Level of Ability for Casting unit greater than 0" condition

 

[Bribe]

There's also the DamageEventLevel functionality which determines whether the unit might have any buff caused by that damage. It works with buff-adding physical damage like Bash, Dark Arrow, Frost Arrow, etc. Flame Arrow doesn't trigger it though as there's no buff on the target.

 

[Devalut]

@dtnmang
Ah, that's a good plan

@Bribe
Something akin to this? or would you do it differently?

Spoiler

• Zero Damage Copy
  • Events
    • Game - DamageEvent becomes Equal to 2.00
  • Conditions
    • DamageEventLevel Not equal to 1
    • (DamageEventTarget has buff Stunned (Pause)) Equal to True
    • (Level of Storm Bolt MOUNTAIN KING for DamageEventSource) Greater than 0
  • Actions
    • Unit - Remove Stunned (Pause) buff from DamageEventTarget
    • Unit - Cause DamageEventSource to damage DamageEventTarget, dealing 72.99 damage of attack type Spells and damage type Universal
• [/spoiler]

 

[Bribe]

First of all those are spells, not physical damage enhanced with buffs. I haven't tested if those fire more than one damage instance, nor if it were to fire more than once would I know if it is a zero damage event first or second.

So I think given that it's a spell only, unless you want to experiment you can try to just play with the buffs.

Triggering spells is already quite trivial with Spell System

 

[Jaizix]

Hi Bribe,
I'm having an issue where when I create a unit as part of a unit index event, the damage event is not registering against the unit who was indexed. That unit is receiving an index and my triggers off that index are working. When that unit deals damage the event is firing, just not when that unit is dealt damage.
Any ideas?

Everything for the unit created in the index event seems to be working.

 

[Bribe]

You're probably on an older version. The recent updates fixed that issue.