[General] bypassing triggers re-script replacing units

[LordPerenolde II]

By replacing units through in-game triggers, will other triggers regarding them stop working? Like, you have tons of units you have to replace but don't want because you'll have to rewrite triggers otherwise. Will this help to bypass that? Or the triggers will get an "empty" string instead?

 

[DracoL1ch]

you wanna delete and re-create unit? all triggers will be lost

 

[IcemanBo]

It's maybe obviously, but you are talking about triggers which are still using "footman_001" in the execution for example? So hardcoded stuff?

 

[Chaosy]

@Iceman
You can actually change that, I think.
I am almost certain you can do set gg_something_footman001 = some unit

 

[DracoL1ch]

@Iceman
You can actually change that, I think.
I am almost certain you can do set gg_something_footman001 = some unit

wont affects related triggers anyhow

 

[LordPerenolde II]

i'm not talking about deleting, i'm talking about replacing, that is>
Unit - replace (units of type blablabla) with a xunit using the new mana and hp

Will this still blank the triggers connected to the replaced units? or they will be swapped bypassing this?

 

[DracoL1ch]

i'm not talking about deleting, i'm talking about replacing, that is>
Unit - replace (units of type blablabla) with a xunit using the new mana and hp

Will this still blank the triggers connected to the replaced units? or they will be swapped bypassing this?

there's nothing like "replacing" in JASS
don't let GUI to fool you, read that and see what hides behind "replacing"

function ReplaceUnitBJ takes unit whichUnit, integer newUnitId, integer unitStateMethod returns unit
    local unit    oldUnit = whichUnit
    local unit    newUnit
    local boolean wasHidden
    local integer index
    local item    indexItem
    local real    oldRatio

    // If we have bogus data, don't attempt the replace.
    if (oldUnit == null) then
        set bj_lastReplacedUnit = oldUnit
        return oldUnit
    endif

    // Hide the original unit.
    set wasHidden = IsUnitHidden(oldUnit)
    call ShowUnit(oldUnit, false)

    // Create the replacement unit.
    if (newUnitId == 'ugol') then
        set newUnit = CreateBlightedGoldmine(GetOwningPlayer(oldUnit), GetUnitX(oldUnit), GetUnitY(oldUnit), GetUnitFacing(oldUnit))
    else
        set newUnit = CreateUnit(GetOwningPlayer(oldUnit), newUnitId, GetUnitX(oldUnit), GetUnitY(oldUnit), GetUnitFacing(oldUnit))
    endif

    // Set the unit's life and mana according to the requested method.
    if (unitStateMethod == bj_UNIT_STATE_METHOD_RELATIVE) then
        // Set the replacement's current/max life ratio to that of the old unit.
        // If both units have mana, do the same for mana.
        if (GetUnitState(oldUnit, UNIT_STATE_MAX_LIFE) > 0) then
            set oldRatio = GetUnitState(oldUnit, UNIT_STATE_LIFE) / GetUnitState(oldUnit, UNIT_STATE_MAX_LIFE)
            call SetUnitState(newUnit, UNIT_STATE_LIFE, oldRatio * GetUnitState(newUnit, UNIT_STATE_MAX_LIFE))
        endif

        if (GetUnitState(oldUnit, UNIT_STATE_MAX_MANA) > 0) and (GetUnitState(newUnit, UNIT_STATE_MAX_MANA) > 0) then
            set oldRatio = GetUnitState(oldUnit, UNIT_STATE_MANA) / GetUnitState(oldUnit, UNIT_STATE_MAX_MANA)
            call SetUnitState(newUnit, UNIT_STATE_MANA, oldRatio * GetUnitState(newUnit, UNIT_STATE_MAX_MANA))
        endif
    elseif (unitStateMethod == bj_UNIT_STATE_METHOD_ABSOLUTE) then
        // Set the replacement's current life to that of the old unit.
        // If the new unit has mana, do the same for mana.
        call SetUnitState(newUnit, UNIT_STATE_LIFE, GetUnitState(oldUnit, UNIT_STATE_LIFE))
        if (GetUnitState(newUnit, UNIT_STATE_MAX_MANA) > 0) then
            call SetUnitState(newUnit, UNIT_STATE_MANA, GetUnitState(oldUnit, UNIT_STATE_MANA))
        endif
    elseif (unitStateMethod == bj_UNIT_STATE_METHOD_DEFAULTS) then
        // The newly created unit should already have default life and mana.
    elseif (unitStateMethod == bj_UNIT_STATE_METHOD_MAXIMUM) then
        // Use max life and mana.
        call SetUnitState(newUnit, UNIT_STATE_LIFE, GetUnitState(newUnit, UNIT_STATE_MAX_LIFE))
        call SetUnitState(newUnit, UNIT_STATE_MANA, GetUnitState(newUnit, UNIT_STATE_MAX_MANA))
    else
        // Unrecognized unit state method - ignore the request.
    endif

    // Mirror properties of the old unit onto the new unit.
    //call PauseUnit(newUnit, IsUnitPaused(oldUnit))
    call SetResourceAmount(newUnit, GetResourceAmount(oldUnit))

    // If both the old and new units are heroes, handle their hero info.
    if (IsUnitType(oldUnit, UNIT_TYPE_HERO) and IsUnitType(newUnit, UNIT_TYPE_HERO)) then
        call SetHeroXP(newUnit, GetHeroXP(oldUnit), false)

        set index = 0
        loop
            set indexItem = UnitItemInSlot(oldUnit, index)
            if (indexItem != null) then
                call UnitRemoveItem(oldUnit, indexItem)
                call UnitAddItem(newUnit, indexItem)
            endif

            set index = index + 1
            exitwhen index >= bj_MAX_INVENTORY
        endloop
    endif

    // Remove or kill the original unit.  It is sometimes unsafe to remove
    // hidden units, so kill the original unit if it was previously hidden.
    if wasHidden then
        call KillUnit(oldUnit)
        call RemoveUnit(oldUnit)
    else
        call RemoveUnit(oldUnit)
    endif

    set bj_lastReplacedUnit = newUnit
    return newUnit
endfunction

so it's an operation with removing unit and creating totally different one, who has no connections whatsoever with ANY thing on your map

 

[LordPerenolde II]

Fine. I'll sort it out somehow. Thank you.

 

[Tal'Rarity]

You could try using a morph ability instead like chaos or bear-form like abilities.

 

[Dr Super Good]

Replacing a unit deletes the existing unit and makes a new one. This means it always has a different or unused handle. As such all references to it need to be updated.

One could trivialize this at the cost of some performance by only referring to the unit using a hashtable. You assign the unit a unique key and update its reference when you replace it. Instead of storing a reference to the unit in unit variables you instead store the key in an integer and use that key to look it up as required. The extra level of references and the use of hashtables will slow execution down, however the amount should be trivial for most use cases.

 

[LordPerenolde II]

Replacing a unit deletes the existing unit and makes a new one. This means it always has a different or unused handle. As such all references to it need to be updated.

One could trivialize this at the cost of some performance by only referring to the unit using a hashtable. You assign the unit a unique key and update its reference when you replace it. Instead of storing a reference to the unit in unit variables you instead store the key in an integer and use that key to look it up as required. The extra level of references and the use of hashtables will slow execution down, however the amount should be trivial for most use cases.

Thank you, almighty, but i've already sorted out my own simplest way: through campaign editor. For some reason the object editor in that mission was kinda faulty and didn't allow me to change some units stats or, even worst, unit models, so i had to go on campaign editor and use object editor on other fewer maps, which "accepted" the changes made.
I a few words, all good now.