Unit Fading Effect

[Lord_Sauron]

Hi. In my map I have units that can cloak. I've used a dummy spell to cause a trigger to add permanent invisibilty to them, and can be cast again to remove it. That all works fine. What I was wondering was if someone could write a custom script so that when the invisibility is removed, their transparency is set to 95%, then to 0% over about 1.5 seconds. Is this possible? I'm trying to make an inverse effect to when the invisibility is added and they appear to fade to the enemy: I'd like them to fade back in. I tried doing this with unit groups but had no luck.
Basically, the cloaked unit casts the spell, the permament invis is removed, * , it is removed from the unit group. I would like a script to put where the * is. The unit is set to the variable "Casting_Unit" if thats any help. Thanks.

 

[-JonNny]

i do not exactly get what you want.. just fading a unit in over time?
then this would help

function FadeIn takes real time , unit u returns nothing
local integer i = 1
local integer ii = 8
    loop
        exitwhen i>ii
        call SetUnitVertexColor(u,255,255,255,(255-(32*q)))  
        call TriggerSleepAction(time/8)
        set i = i + 1
    endloop
endfunction

the function to call

call FadeIn.execute(1.50,CasterUnit)

(btw , uses vJass , youll need JassNewGenPack)

 

[Eleandor]

You mean

call FadeIn(1.5, CasterUnit)

?

 

[-JonNny]

nope , i meant what i wrote

call FadeIn.execute(1.50,CasterUnit)

shouldnt that work? Its vJass but im kinda new to it

call FadeIn(1.5, CasterUnit)

wouldnt that pause even the function which calls it that all actions afterward have 1.5 seconds delay?

 

[PurplePoot]

-JonNny, TSA should be avoided at all costs.

Here we go, vJass required. Haven't tested but it should work, I'll test after dinner --

library FadeIn
    private struct Data
        unit fade
        real alpha = 0
        real alphaPerInterval
    endstruct
    globals
        private constant real interval = .03
        private timer T = CreateTimer()
        private integer max = 0
        private Data array darr
    endglobals
    private function Loop takes nothing returns nothing
        local integer i = 0
        local Data dat
        loop
            exitwhen i >= max
            set dat = darr[i]
            set dat.alpha = dat.alpha + dat.alphaPerInterval
            if dat.alpha > 255. then
                set dat.alpha = 255.
            endif
            call SetUnitVertexColor(dat.fade,255,255,255,R2I(dat.alpha))
            if dat.alpha == 255. then
                set max = max - 1
                set darr[i] = darr[max]
                if max == 0 then
                    call PauseTimer(T)
                endif
                call dat.destroy()
            else
                set i = i + 1
            endif
        endloop
    endfunction
    function FadeInUnit takes unit u, real time returns nothing
        local Data dat = Data.create()
        set dat.fade = u
        set dat.alphaPerInterval = 255.*interval/time
        if max == 0 then
            call TimerStart(T,interval,true,function Loop)
        endif
        set darr[max] = dat
        set max = max + 1
    endfunction
endlibrary

 

[-JonNny]

good job

sry for being offtopic , What do you exactly mean with "TSA" and why should it be avoided?

 

[Lord_Sauron]

Hmm ok thanks, but how do I add it into my map. Do I need JassNewGenPack, and where can I find it?

 

[PurplePoot]

JassNewGenPack

Note that it only works on the 1.21b worldedit.exe, which is available for download in a number of places.

To use this, just put it in a trigger of whatever name you like (overwrite the entire contents). Then write (replacing words in <>):

• Some Trigger
  • Actions
    • Custom script: call FadeInUnit(<unit variable>,<time>)

-JonNny, TSA = Trigger Sleep Action, and among other things it's rather horribly inaccurate, hence timers.

EDIT: Minor changes to my code to make the timing a little more accurate.

 

[neavea]

If you don't jass, the GUI version would be this:

• Fade Away
  • Actions
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 95.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 85.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 75.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 65.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 55.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 45.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 35.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 25.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 15.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 5.00% transparency
    • Wait 0.15 seconds
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 0.00% transparency

GUI FTW!!!

Although its probably not as slick as PurplePoot, its GUI...

 

[Eleandor]

Neavea you should at least use a For loop instead of copy/paste every action 10 times.

And TriggerSleepAction is pretty accurate when used above 0.3 seconds. In this case, you'd still prefer timers ofcourse.

 

[neavea]

Neavea you should at least use a For loop instead of copy/paste every action 10 times.

Using loop would repeat actions. Those actions above I do not want to repeat as the transparency must be set differently every single time it is set.

 

[Eleandor]

You can make the transparency in function of the loop index. Like:

• Trigger
• For Each Integer A from 0 to 9 do:
  • Loop - actions
    • Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with (95.00 - (10*Integer A)%) transparency
    • Wait 0.15 seconds
• Animation - Change (Triggering unit)'s vertex coloring to (100.00%, 100.00%, 100.00%) with 0% transparency

 

[neavea]

Ah... I see....

I like it! Ive never used the loop -actions... That can come in handy! =)

 

[PurplePoot]

Eleandor, yes, TSA is fine for longer intervals (well, you should actually use PW, but that's a side note). However, the majority of uses are in fast loops either way, which just emphasizes how annoying it has to have no good sleep...

 

[Lord_Sauron]

Ok, thanks guys.