[Snippet] Order Event

[Bribe]

Like SpellEffectEvent, but this one is for catching orders. Also like SpellEffectEvent, this is pretty much as lightweight as it gets.

Update to version 3.0.0.0 - now requires Table due to some orders having very high indices. Thanks to Spellbound for pointing this out. Also, I improved the initialization by not auto-registering all three events unless the user specifically calls RegisterOrderEvent.

//============================================================================
// OrderEvent by Bribe, special thanks to Nestharus and Azlier, version 3.0.1.1
//
// API
// ---
//     RegisterOrderEvent(integer orderId, code eventFunc)
//     RegisterAnyOrderEvent(code eventFunc) //Runs for point/target/instant for any order
//
// Requires
// --------
//     RegisterPlayerUnitEvent: http://www.hiveworkshop.com/threads/snippet-registerevent-pack.250266/
//     Table: http://www.hiveworkshop.com/forums/showthread.php?t=188084
//
library OrderEvent requires RegisterPlayerUnitEvent, Table

globals
    private Table t = 0
endglobals

//============================================================================
function RegisterAnyOrderEvent takes code c returns nothing
    static if RPUE_VERSION_NEW then
        call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, c)
        call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, c)
        call RegisterAnyPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, c)
    else
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, c)
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, c)
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, c)
    endif
endfunction

//============================================================================
private function OnOrder takes nothing returns nothing
    call TriggerEvaluate(t.trigger[GetIssuedOrderId()])
endfunction

//============================================================================
function RegisterOrderEvent takes integer orderId, code c returns nothing
    local trigger trig
    if integer(t) == 0 then
        set t = Table.create()
        call RegisterAnyOrderEvent(function OnOrder)
    endif
    set trig = t.trigger[orderId]
    if trig == null then
        set trig = CreateTrigger()
        set t.trigger[orderId] = trig
    endif
    call TriggerAddCondition(trig, Filter(c))
    set trig = null
endfunction

endlibrary

 

[Bribe]

Made this thing really tight and added in Nestharus' wise input that I can just subtract 0xD0000 instead of hashing the values in a hashtable.

Shortened the API significantly and this should be very easy to pick up on.

 

[Nestharus]

Add thanks to azlier for finding that number as well (I got it from him).

Otherwise looks a lot better =)

 

[Magtheridon96]

0XD00000?
I was trying to find that number for days
This snippet is very useful ^^

 

[Bribe]

Updated to use RegisterPlayerUnitEvent.

 

[Magtheridon96]

*Votes for approval*

 

[Dirac]

It would be great if this library provided with something such as GetUnitCurrentOrderX() and Y() to know where the unit is heading.

 

[Bribe]

That has nothing to do with this library. That has more to do with the LastOrder library on wc3c.net.

 

[Magtheridon96]

LastOrder?
I have been inspired ^^

 

[azlier]

Like RegisterPlayerUnitEvent, I think this can benefit from this post.

 

[Bribe]

Updated, code is much shorter now.

 

[Bribe]

Re-Added RegisterAnyOrderEvent. Is this fit for approval?

 

[watermelon_1234]

I can't think of a situation when I want to have an event detecting a specific order for all three cases of being immediate, point, or target and making me have to manually differentiate between them.
Because of this, I'm not sure when I would want to use this over RegisterPlayerUnitEvent and just filter out specific order ids.

Of course, I would be open to suggestions.

 

[Bribe]

What if you only wanted to detect Undefend, or only detect a "stop" or "attack" order?

 

[Troll-Brain]

I don't get why you talked about the stop and undefend order, i mean they obviously are a not target order.
Now, it quite makes sense for the attack order, since it can be a target or point order.

Or am i missing something ?

 

[Bribe]

Well the "RegisterOrderEvent" fires whenever that order ID is matched for any of the three events. I don't see a point in making a "RegisterTarget/Point/ImmediateOrderEvent".

 

[Troll-Brain]

I had just read what watermelon_1234 had said and what you answered to him.
But now, i've reading your code and it makes sense.
Most of times we only need to check about a specific order, and if we have the need to check all point or all target, or no target orders, then you just don't need this resource.

 

[Switch33]

Small typo. . .

function RegisterAnyOrderEvent takes code order returns nothing
->function RegisterAnyOrderEvent takes code c returns nothing

 

[Bribe]

Bah, thanks for spotting that. That's the problem when I make small edits. Maybe I just shouldn't edit it at all even if it's just a little thing like that, until I have time to compile it.

 

[Magtheridon96]

This is pretty nifty, and people will find uses for it. (Spell Development)

I vote for approval.

edit

One problem: A trigger evaluation per order + 12 Spam clicking players + 50 attacking units = Dead

 

[Bribe]

Well no one ever had a GG from having the LastOrder library in their map, which uses even moar

 

[Magtheridon96]

Hey, Event does pretty much the same thing; I guess this library shouldn't have performance issues then ^-^
Voting for approval (again)

 

[Bribe]

OK, and since I have been recommending this resource to others as well, I think I will go ahead and approve it.

 

[watermelon_1234]

I still don't see how this resource is useful, at least from a spell maker's point of view.

Let's say I have a spell based on Berserk and I want to do spell actions only when the order is issued.
How is your system's way

    private function SpellActions takes nothing returns nothing
        local unit c = GetTriggerUnit()
        if GetUnitAbilityLevel(c, SPELL_ID) > 0 then
            // Do spell stuff here
        endif
        set c = null
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterOrderEvent(ORDER_ID, function SpellActions)
    endfunction

better than

    private function SpellActions takes nothing returns nothing
        local unit c = GetTriggerUnit()
        if GetIssuedOrderId() == ORDER_ID and GetUnitAbilityLevel(c, SPELL_ID) > 0 then
            // Do spell stuff here
        endif
        set c = null
    endfunction
    
    private function Init takes nothing returns nothing
        call RegisterPlayerUnitEvent(EVENT_PLAYER_UNIT_ISSUED_ORDER, function SpellActions)
    endfunction

not to mention that the latter only registers immediate orders since the spell can't be cast differently?

 

[Bribe]

The reason the first way is better is because the trigger will only evaluate if the correct order has landed. The system efficiently handles orders no matter if it was a point, target or immediate order.

It is the same concept of using SpellEffectEvent or GTrigger to handle a specific cast (GTrigger also handles specific orders like this does).

Take for example a unit is ordered "stop". The system will evaluate all triggers that was registered with the "stop" order ID. With your method, your thing will evaluate no matter which order was issued.

 

[IcemanBo]

Submission: [Snippet] OrderEvent v2.1.0.0 Date: 18 October 16 Status: Graveyard Note: The resource was previously approved and therefore should work fine. If you use this script already in your codes, it's okay to keep it there. But now we have this approved [Snippet] RegisterEvent pack, and so it's time to graveyard these specializations.

 

[Bribe]

Updated to require Table as Spellbound pointed out to me that some orders go much higher than the array allows with that single offset.

 

[AGD]

Would be better if you add compatibility for Bannar's RegisterPlayerUnitEvent by having
static if RPUE_VERSION_NEW then

globals
    private Table t = 0
endglobals

Wise choice

 

[Bribe]

Would be better if you add compatibility for Bannar's RegisterPlayerUnitEvent by having
static if RPUE_VERSION_NEW then

That static if looks pretty ugly, but OK, it's added for completeness. Version 3.0.1.0.

What do you mean with the "wise choice"?

 

[AGD]

What do you mean with the "wise choice"?

Oh, I'm mistaken. I thought you didn't do set t = Table.create() thinking that it's safe enough to just set t to 0 since no one would be using that zero Table instance aside from you anyway hehe

 

[Bribe]

Well, you wouldn't want to use "0" for a Table ... ever. You can safely use vJass "key" types, though.

Updated to v3.0.1.1 - fixed a syntax error as I forgot to change the syntax from the vanilla t[] to Table's t.trigger[]. Thanks to SpellBound for catching this.

 

[AGD]

You can safely use vJass "key" types, though.

Haven't thought of that, thanks for the tip.

Well, you wouldn't want to use "0" for a Table ... ever.

I'm curious though, is it because it's against the standards not a good practice? or is it because it's unsafe like using the index 8191 in an array?

 

[Bribe]

If you use an unassigned integer as a Table index, you'd run the risk of another system doing the same. However, in the case of Table 0, that is considered "null" and if there are any mishaps in someone's code which leads to the referencing of uninitialized Tables, they would default to 0 and you get a lot of overwrites. So, even if you could be sure that the index of 0 is being used nowhere else, it's not good practice.

 

[AGD]

Reapproved for a reason parallel to what's stated here.

Approved

 

[Bribe]

Updated to require Table as Spellbound pointed out to me that some orders go much higher than the array allows with that single offset.

Wow considering if I hadn't done this, I think one of the recent patches may have messed up the order ID offset which I had been using anyway.