[JASS] Need help getting a player

[usfmohy]

I am making a trigger that is called hero revive ...
I create a Timer Dialog for my Timer ...
I want to show the timer dialog only for the owner of the hero ..
I used this but its not working it shows the dialog to all players .. any help ?

local timerdialog td = CreateTimerDialogBJ( t,"Your hero revive in" )
call TimerDialogDisplayForPlayerBJ(true , td , GetOwningPlayer(GetTriggerUnit()))

-----------------------------------------------------
Never mind i found the answer :

local timerdialog td = CreateTimerDialogBJ( t,"Your hero revive in" )
    call TimerDialogDisplay(td , false)
    call TimerDialogDisplayForPlayerBJ(true , td , GetOwningPlayer(GetTriggerUnit()))

 

[Berb]

Don't use "BJ" functions they simply call natives. The natives that you want to concern yourself with here are:

native CreateTimerDialog takes timer t returns timerdialog
native TimerDialogDisplay takes timerdialog whichDialog, boolean display returns nothing

This is the native; the BJ that you were using does the following:

function CreateTimerDialogBJ takes timer t, string title returns timerdialog
    set bj_lastCreatedTimerDialog = CreateTimerDialog(t)
    call TimerDialogSetTitle(bj_lastCreatedTimerDialog, title)
    call TimerDialogDisplay(bj_lastCreatedTimerDialog, true)
    return bj_lastCreatedTimerDialog
endfunction

As you can see, this native already calls TimerDialogDisplay. This means that you call many functions unnecessarily, there is no reason to call TimerDialogDisplay(dialog, true) only to do TimerDialogDisplay(dialog, false) after.

I re-wrote your trigger:

local timerdialog td=CreateTimerDialog(t)
    call TimerDialogSetTitle(td, "Your Hero Revives In...")
    call TimerDialogDisplay(td, GetLocalPlayer( )==GetOwningPlayer(GetTriggerUnit()))

By the way, this is what the TimerDialogDisplayForPlayerBJ looks like:

function TimerDialogDisplayForPlayerBJ takes boolean show, timerdialog td, player whichPlayer returns nothing
    if (GetLocalPlayer() == whichPlayer) then
        // Use only local code (no net traffic) within this block to avoid desyncs.
        call TimerDialogDisplay(td, show)
    endif
endfunction

As you can see, I've simply substituted the if-statement directly into the boolean parameter.

 

[usfmohy]

As you can see, I've simply substituted the if-statement directly into the boolean parameter.

Thanks man for this precious help +infinite rep if i can