[JASS] Problem with my function

[JustNrik]

I created this function to revive a hero on player's start location after certain time, the function is working fine, the only problem is that it doesn't show the time, only the timer window with the message but not the time that left to revive.

This is the code

function HeroRevive takes unit u, integer i, real r, location p returns nothing
local string s = "Respawn in:"
local timer array t
local timerdialog array td
set u = GetDyingUnit()
set i = GetConvertedPlayerId(GetOwningPlayer(u))
set r = ( 2.00 * I2R(GetHeroLevel(u)) )
set p = GetPlayerStartLocationLoc(Player(i))
call StartTimerBJ( t[i], false, r)
call CreateTimerDialogBJ( t[i], s )
set td[i] = GetLastCreatedTimerDialogBJ()
call TimerDialogDisplayForPlayerBJ( false, td[i], Player(i) )
call TriggerSleepAction(r)
call ReviveHeroLoc( u, p, true )
call PanCameraToTimedLocForPlayer( Player(i), p, 0 )
call SelectUnitForPlayerSingle( u, Player(i) )
call DestroyTimerDialog( td[i] )
call RemoveLocation(p)
set u = null
set t[i] = null
set td[i] = null
endfunction

 

[deathismyfriend]

If you are coding in Jass you should inline your function calls. All those BJs are horrible for speed and efficiency.

The timer does not start because you never create the timer.

You need to do this.

local timer t = CreateTimer()

Also remove the timerdialog array and use a local timerdialog to show the timer to the player.
You also destroy the timer dialog which means that it will never show to the player.

Here is how this function should be written.

function HeroRevive takes unit u, real r, location loc, boolean b returns nothing
        local string s = "Respawn in:"
        local timer t = CreateTimer()
        local timerdialog td = CreateTimerDialog(t)
        local integer p = GetPlayerId(GetOwningPlayer(u))
        local real x = GetLocationX(loc)
        local real y = GetLocationY(loc)
        call TimerStart( t, r, false, null)
        if (GetLocalPlayer() == Player(p)) then
            call TimerDialogDisplay( td, true)
        endif
        call TriggerSleepAction(r)
        call ReviveHero( u, x, y, true )
        if (GetLocalPlayer() == Player(p)) then
            call PanCameraToTimed(x, y, 0)
            call ClearSelection()
            call SelectUnit(u, true)
        endif
        call DestroyTimerDialog( td )
        if (b) then
            call RemoveLocation(loc)
        endif
        set u = null
        set t = null
        set td = null
    endfunction

Call it from GUI using this custom script.

• Set tempUnit = (Triggering unit)
• Set tempReal = (time till reviving)
• Set tempPoint = (location to revive the unit at.)
• Custom script: call HeroRevive( udg_tempUnit, udg_tempReal, udg_tempPoint, true)

Note: the above function is MUI but it uses waits so the time will vary.

 

[JustNrik]

It's not working good, The hero is reviving instantly and he's not selected when revived and the camera is not pan in the location..

 

[deathismyfriend]

What r value are you using ? How are you calling the function ? Can you post this please.

 

[JustNrik]

• Dead
  • Events
    • Unit - A unit Dies
  • Conditions
    • ((Dying unit) is A Hero) Equal to True
  • Actions
    • Set TempUnit = (Dying unit)
    • Set TeamReal = (2.00 x (Real((Hero level of TempUnit))))
    • Set TempPoint = ((Owner of TempUnit) start location)
    • Custom script: call HeroRevive( udg_TempUnit, udg_TempReal, udg_TempPoint, true)

 

[deathismyfriend]

• Dead
  • Events
    • Unit - A unit Dies
  • Conditions
    • ((Dying unit) is A Hero) Equal to True
  • Actions
    • Set TempUnit = (Dying unit)
    • Set TeamReal = (2.00 x (Real((Hero level of TempUnit))))
    • Set TempPoint = ((Owner of TempUnit) start location)
    • Custom script: call HeroRevive( udg_TempUnit, udg_TempReal, udg_TempPoint, true)

It should work fine then. What time is getting displayed on the timer dialog window in game ?

 

[JustNrik]

It's not even displayed, the hero just insta-revive and that's all :/

Don't worry anyway, I'd prefer to use GUI. I see Jass to complex X_X'

 

[IcemanBo]

I guess because TriggerSleepAction only works in TriggerActions, and not in generic functions. Using a timer would be better anyway.
But you of course can stay in GUI. Before you just start using JASS, you anyway should read some tutorials first.

 

[deathismyfriend]

I guess because TriggerSleepAction only works in TriggerActions, and not in generic functions. Using a timer would be better anyway.
But you of course can stay in GUI. Before you just start using JASS, you anyway should read some tutorials first.

I thought it was something stupid. I couldn't remember though. Thanks Iceman.

 

[mckill2009]

your function doesnt have 'trigger', so the sleep trigger will not work properly, timers in jass suppose to work if there's a function above it coz it will fire that function when timer stops, your best bet if you really want to use timers is to use TimerUtils...

 

[JustNrik]

I guess because TriggerSleepAction only works in TriggerActions, and not in generic functions. Using a timer would be better anyway.
But you of course can stay in GUI. Before you just start using JASS, you anyway should read some tutorials first.

Well, my first function was working fine with the TriggerSleepAction, the problem was only that it didn't show the time, only the window with the string...

 

[edo494]

local timer array t
local timerdialog array td
set u = GetDyingUnit()
set i = GetConvertedPlayerId(GetOwningPlayer(u))
set r = ( 2.00 * I2R(GetHeroLevel(u)) )
set p = GetPlayerStartLocationLoc(Player(i))
call StartTimerBJ( t[i], false, r)

this is just wrong. You dont need to make them arrays, since they are locals, so they are always unique to the running scope and dont share state between JVM instances.

Basically what you dont do is actually create the timer, you just try to start it, but there is no created timer to begin with

 

[deathismyfriend]

@Edo

Check out the code I posted above. I believe that is what he is trying to use. I already showed him how to fix it but for some reason there is still a bug and I am unable to test for a solution at this time.

 

[edo494]

local integer p = GetPlayerId(GetOwningPlayer(u)) + 1 the +1 is actually not needed and will cause different players to show the effect(Local block), because all your functions are natives, and they expect 0 based indexing for players

Also wait kind of sucks, but for the sake of making it easy to understand, I think its fine

 

[deathismyfriend]

local integer p = GetPlayerId(GetOwningPlayer(u)) + 1 the +1 is actually not needed and will cause different players to show the effect(Local block), because all your functions are natives, and they expect 0 based indexing for players

Also wait kind of sucks, but for the sake of making it easy to understand, I think its fine

Ya I know wait sucks and I knew I was missing something stupid. He was using it to call from GUI and for some reason I added the + 1 in there lol thanks.

 

[JustNrik]

Thanks very much, it's working perfect now!

 

[deathismyfriend]

Thanks very much, it's working perfect now!

No problem. Edo494 pointed out the problem though. I knew it was something stupid.