[JASS] Improving/Fixing Code

[Rui]

[JASS=Hi. I have been playing around with JASSNewGen and I would like to get some feedback on this code]
function Trig_BoardIn_Actions takes nothing returns nothing
local unit tempunt = GetEnteringUnit()
local rect temprect = gg_rct_TempArea
local location temploc = GetRandomLocInRect(temprect)
call SetUnitPositionLoc(tempunt, temploc)
call RemoveLocation(temploc)
call SetUnitOwner(tempunt, PLAYER_NEUTRAL_PASSIVE, false)
if tempunt == gg_unit_Othr_0213 then
call ThrallIsBoarding()
call DisableTrigger(GetTriggeringTrigger())
endif
set tempunt = null
set temprect = null
set temploc = null
endfunction

function ThrallIsBoarding takes nothing returns nothing
local group TempingRedGroup
call ForGroup(GetUnitsOfPlayerAll(Player(0)), RemoveUnit(GetEnumUnit()))
set TempingRedGroup = GetLastCreatedGroup()
call DestroyGroup(TempingRedGroup)
call BJDebugMSG("This function is working.")
set TempingRedGroup = null
endfunction
//===========================================================================
function InitTrig_BoardIn takes nothing returns nothing
set gg_trg_BoardIn = CreateTrigger()
call TriggerRegisterEnterRectSimple(gg_trg_BoardIn, gg_rct_TutorialSetSail)
call TriggerAddAction(gg_trg_BoardIn, function Trig_BoardIn_Actions)
endfunction[/code]

The syntax Checker yelled at me because of undeclared variables (such as gg_rct_TempArea, which DOES exist, gg_unit_Othr_0213, etc).
It also says "Can't convert Nothing to Code" on the ForGroup part. Perhaps I misunderstood the function.

What I'm basically trying to do is removing all the units owned by player once gg_unit_Othr_0213 enters the rect.

 

[aznricepuff]

native ForGroup takes group whichGroup, code callback returns nothing

The callback is a function where you put all of your actions concerning the ForGroup loop.

About the undeclared variables, the syntax checker will do that to you sometimes. Just make another GUI trigger that does nothing but uses the variable gg_rct_TempArea in some way. Then the syntax checker should recognize the variable.

function Trig_BoardIn_Actions takes nothing returns nothing
    local unit tempunt = GetTriggerUnit()
    local rect temprect = gg_rct_TempArea
    local location temploc = GetRandomLocInRect( temprect )

    call SetUnitPositionLoc( tempunt, temploc )
    call RemoveLocation( temploc )
    call SetUnitOwner( tempunt, PLAYER_NEUTRAL_PASSIVE, false )
    if ( tempunt == gg_unit_Othr_0213 ) then
        call ThrallIsBoarding()
        call DisableTrigger( GetTriggeringTrigger() )
    endif

    set tempunt = null
    set temprect = null
    set temploc = null
endfunction

function Remove_Units takes nothing returns nothing
    call RemoveUnit( GetEnumUnit() )
endfunction

function ThrallIsBoarding takes nothing returns nothing
    local group g = CreateGroup()

    call GroupEnumUnitsOfPlayer( g, Player(0), null )
    call ForGroup( g, function Remove_Units )
    call BJDebugMSG( "This function is working." )

    call DestroyGroup( g )
    set g = null
endfunction
//===========================================================================
function InitTrig_BoardIn takes nothing returns nothing
    set gg_trg_BoardIn = CreateTrigger()
    call TriggerRegisterEnterRectSimple(gg_trg_BoardIn, gg_rct_TutorialSetSail)
    call TriggerAddAction(gg_trg_BoardIn, function Trig_BoardIn_Actions)
endfunction

 

[Jetherit]

Rui, your ForGroup should look something like...

function RemoveFunc takes nothing returns nothing
call RemoveUnit(GetEnumUnit())
endfunction

function blah takes nothing returns nothing
call ForGroup(some group, function RemoveFunc)
endfunction

 

[Rui]

Thanks, I understand how ForGroup works now! =)

Another question, is Neutral Passive player 15? Syntax Checker also yells at that part.

 

[wd40bomber7]

Are you sure you have NewGen's syntax checker on and not WE's ? Make sure disable WE syntax check is checked and Enable Jass helper is checked?
As far as I know Player(15) is neutral passive.

 

[Eleandor]

Try
Player(PLAYER_NEUTRAL_PASSIVE)

 

[wd40bomber7]

I think it compiles constants by replacing them with their value. So it really comes down to which is faster to type.

    constant integer            PLAYER_NEUTRAL_PASSIVE          = 15

 

[Rui]

Ok, thanks.

Yet another question =P can I set a local point using coordinates? If yes, do I need to destroy the point after using it?

EDIT: I have Enabled JASS Helper and disabled WE Syntax Checker, and the editor still yells about undeclared variables.

 

[wd40bomber7]

Anything that involves Location(x,y) makes a point and must be removed. Instead look for a native that allows you to input the x and y without inputing a location.

 

[GhostWolf]

Is there such a native ? I looked for one in JassCraft for like 10 minutes, couldn't find anything.

 

[Dr Super Good]

You call a function below the calling function (impossiable).

Make sure all functions you call are above the calling one in the map script.

 

[wd40bomber7]

(Because the post between my two posts got deleted this is what was in my previous post)

native Location                 takes real x, real y returns location

Thats the native


Just to exemplify what Dr. Super Good said:

function Remove_Units takes nothing returns nothing
    call RemoveUnit( GetEnumUnit() )
endfunction

function ThrallIsBoarding takes nothing returns nothing
    local group g = CreateGroup()

    call GroupEnumUnitsOfPlayer( g, Player(0), null )
    call ForGroup( g, function Remove_Units )
    call BJDebugMSG( "This function is working." )

    call DestroyGroup( g )
    set g = null
endfunction
function Trig_BoardIn_Actions takes nothing returns nothing
    local unit tempunt = GetTriggerUnit()
    local rect temprect = gg_rct_TempArea
    local location temploc = GetRandomLocInRect( temprect )

    call SetUnitPositionLoc( tempunt, temploc )
    call RemoveLocation( temploc )
    call SetUnitOwner( tempunt, PLAYER_NEUTRAL_PASSIVE, false )
    if ( tempunt == gg_unit_Othr_0213 ) then
        call ThrallIsBoarding()
        call DisableTrigger( GetTriggeringTrigger() )
    endif

    set tempunt = null
    set temprect = null
    set temploc = null
endfunction
//===========================================================================
function InitTrig_BoardIn takes nothing returns nothing
    set gg_trg_BoardIn = CreateTrigger()
    call TriggerRegisterEnterRectSimple(gg_trg_BoardIn, gg_rct_TutorialSetSail)
    call TriggerAddAction(gg_trg_BoardIn, function Trig_BoardIn_Actions)
endfunction

In JASS you can only call a function that is above your current function.

 

[GhostWolf]

Oh didn't know this, thought it was just some sort of tradition.

And that native is just a normal loc, it doesn't really help.
What I meant is for example distance beetwin points.
Can we somehow (I know this won't work, its just an example for the question) make it check like this

local real distance = DistanceBetweenPoints(x1,y1,x2,y2)

 

[wd40bomber7]

function DistanceBetweenPoints takes location locA, location locB returns real
    local real dx = GetLocationX(locB) - GetLocationX(locA)
    local real dy = GetLocationY(locB) - GetLocationY(locA)
    return SquareRoot(dx * dx + dy * dy)
endfunction

Thats the BJ that needs a location. So you take it and you modify it to:

function DistanceBetweenPointsXY takes real x1, real y1, real x2, real y2 returns real
    local real dx = x2 - x1
    local real dy = y2 - y1
    return SquareRoot(dx * dx + dy * dy)
endfunction

Then you add that to your code and *poof* there ya go.

 

[Eleandor]

native Location                 takes real x, real y returns location

Thats the native

Are you sure? I thought there was a function like GetLocZ...

 

[wd40bomber7]

GetLocationZ returns the height of ground level at the X and Y coords of the location. Its not actually part of the internal location struct.

 

[Rui]

I actually realized it myself DSG =P PJASS was yelling at me that it didn't know the function. That's when I remembered the function being called had to be above

I used the CreateUnit function, and I obviously used coordinates to define where it would be located. Are you totally sure it doesn't leak?

Btw Eleandor I had a few problems with 'Z' lol I was defining coordinates for the unit being created and it appeared at a different place. It happened that I was reading the last two numbers of the coordinates (which are Y and Z respectively) instead of the first pair xD

 

[GhostWolf]

Ah right didn't think about that ! thanks

Err... lol a few new comments before me...

Rui, locations using reals and not loc's won't leak because reals don't leak.

 

[Rui]

Ok... a coordinate is a real... I guess that makes sense, hehe

Thanks again.