i'm stumped

[sunshinex3]

so i am using melee rules for my map, they say when a player leaves his units and building leave with him

thats what i want/need except theirs this one small problem:

one of the races old gods, chanes ownership of gold mines to player controlled all the triggers for this check and its great!! except when the player leaves, the gold mines go with him...

how would i fix that?

Replace the gold mine? how its removed and there is no location point to store...

possible switch it back to neutral as he leaves? would be great don't know how to do it though.

 

[Wrda]

When he leaves, before removing all his units, change the owner of "his" goldmine with pick every unit owned by player matching condition unit type is goldmine then change owner, then pick again with no condition and remove them.

 

[sunshinex3]

• player leaves
  • Events
    • Player - Player 1 (Red) leaves the game
    • Player - Player 2 (Blue) leaves the game
  • Conditions
  • Actions
    • Unit Group - Pick every unit in (Units owned by (Triggering player) of type Gold Mine) and do (Actions)
      • Loop - Actions
        • Unit - Change ownership of (Picked unit) to Neutral Passive and Change color
        • Animation - Reset (Attacked unit)'s animation
        • Unit - Remove Commune (old gods) from (Attacked unit)

we tried this already, it didn't work even when it was at the very top of the trigger list. But the trigger i think is the problem takes priority.

• Melee Initialization
  • Events
    • Time - Elapsed game time is 500.00 seconds
  • Conditions
  • Actions
    • Melee Game - Use melee time of day (for all players)
    • Melee Game - Limit Heroes to 1 per Hero-type (for all players)
    • Melee Game - Give trained Heroes a Scroll of Town Portal (for all players)
    • Melee Game - Run melee AI scripts (for computer players)
    • Melee Game - Enforce victory/defeat conditions (for all players)

its the Enforce victory/defeat conditions (for all players) trigger i think that's the problem i am not sure what to do i really like this trigger i need in my game its just this small problem

should disable it and then make it run when players leave, like make it apart of the first trigger

 

[Rigborn]

I am assuming you based off your gold mine building on either undead, or night elf entangled, haunted gold mine. If so, shouldn't you be changing the owner of that building rather than that gold mine itself ?

 

[sunshinex3]

nope off the actual gold mine i remove neutral hostile from it and give it back once its attacked

 

[BloodSoul]

Your previously mentioned "player leaves" trigger is using the "Attacked Unit" function in two actions, and it will always return null because it's not meant to work with that event.

Is there any other trigger making use of the same event, and is removing all units from the leaver? If so, the trigger that's going to be executed first is the one that was created first; putting it on top of all the others wont change the trigger priority.

The "Enforce victory/defeat conditions" doesn't properly work with custom races/town halls. There are posts/threads out there which will help you fix that problem.

 

[Dr Super Good]

The melee leave is implemented as follows...

//===========================================================================
function MeleeTriggerActionPlayerLeft takes nothing returns nothing
    local player thePlayer = GetTriggerPlayer()

    // Just show game over for observers when they leave
    if (IsPlayerObserver(thePlayer)) then
        call RemovePlayerPreserveUnitsBJ(thePlayer, PLAYER_GAME_RESULT_NEUTRAL, false)
        return
    endif

    call CachePlayerHeroData(thePlayer)

    // This is the same as defeat except the player generates the message
    // "player left the game" as opposed to "player was defeated".

    if (MeleeGetAllyCount(thePlayer) > 0) then
        // If at least one ally is still alive and kicking, share units with
        // them and proceed with death.
        call ShareEverythingWithTeam(thePlayer)
        call MeleeDoLeave(thePlayer)
    else
        // If no living allies remain, swap all units and buildings over to
        // neutral_passive and proceed with death.
        call MakeUnitsPassiveForTeam(thePlayer)
        call MeleeDoLeave(thePlayer)
    endif
    call MeleeCheckForLosersAndVictors()
endfunction

//===========================================================================
function MeleeInitVictoryDefeat takes nothing returns nothing
    local trigger    trig
    local integer    index
    local player     indexPlayer

    // Create a timer window for the "finish soon" timeout period, it has no timer
    // because it is driven by real time (outside of the game state to avoid desyncs)
    set bj_finishSoonTimerDialog = CreateTimerDialog(null)

    // Set a trigger to fire when we receive a "finish soon" game event
    set trig = CreateTrigger()
    call TriggerRegisterGameEvent(trig, EVENT_GAME_TOURNAMENT_FINISH_SOON)
    call TriggerAddAction(trig, function MeleeTriggerTournamentFinishSoon)

    // Set a trigger to fire when we receive a "finish now" game event
    set trig = CreateTrigger()
    call TriggerRegisterGameEvent(trig, EVENT_GAME_TOURNAMENT_FINISH_NOW)
    call TriggerAddAction(trig, function MeleeTriggerTournamentFinishNow)

    // Set up each player's mortality code.
    set index = 0
    loop
        set indexPlayer = Player(index)

        // Make sure this player slot is playing.
        if (GetPlayerSlotState(indexPlayer) == PLAYER_SLOT_STATE_PLAYING) then
            set bj_meleeDefeated[index] = false
            set bj_meleeVictoried[index] = false

            // Create a timer and timer window in case the player is crippled.
            set bj_playerIsCrippled[index] = false
            set bj_playerIsExposed[index] = false
            set bj_crippledTimer[index] = CreateTimer()
            set bj_crippledTimerWindows[index] = CreateTimerDialog(bj_crippledTimer[index])
            call TimerDialogSetTitle(bj_crippledTimerWindows[index], MeleeGetCrippledTimerMessage(indexPlayer))

            // Set a trigger to fire whenever a building is cancelled for this player.
            set trig = CreateTrigger()
            call TriggerRegisterPlayerUnitEvent(trig, indexPlayer, EVENT_PLAYER_UNIT_CONSTRUCT_CANCEL, null)
            call TriggerAddAction(trig, function MeleeTriggerActionConstructCancel)

            // Set a trigger to fire whenever a unit dies for this player.
            set trig = CreateTrigger()
            call TriggerRegisterPlayerUnitEvent(trig, indexPlayer, EVENT_PLAYER_UNIT_DEATH, null)
            call TriggerAddAction(trig, function MeleeTriggerActionUnitDeath)

            // Set a trigger to fire whenever a unit begins construction for this player
            set trig = CreateTrigger()
            call TriggerRegisterPlayerUnitEvent(trig, indexPlayer, EVENT_PLAYER_UNIT_CONSTRUCT_START, null)
            call TriggerAddAction(trig, function MeleeTriggerActionUnitConstructionStart)

            // Set a trigger to fire whenever this player defeats-out
            set trig = CreateTrigger()
            call TriggerRegisterPlayerEvent(trig, indexPlayer, EVENT_PLAYER_DEFEAT)
            call TriggerAddAction(trig, function MeleeTriggerActionPlayerDefeated)

            // Set a trigger to fire whenever this player leaves
            set trig = CreateTrigger()
            call TriggerRegisterPlayerEvent(trig, indexPlayer, EVENT_PLAYER_LEAVE)
            call TriggerAddAction(trig, function MeleeTriggerActionPlayerLeft)

            // Set a trigger to fire whenever this player changes his/her alliances.
            set trig = CreateTrigger()
            call TriggerRegisterPlayerAllianceChange(trig, indexPlayer, ALLIANCE_PASSIVE)
            call TriggerRegisterPlayerStateEvent(trig, indexPlayer, PLAYER_STATE_ALLIED_VICTORY, EQUAL, 1)
            call TriggerAddAction(trig, function MeleeTriggerActionAllianceChange)
        else
            set bj_meleeDefeated[index] = true
            set bj_meleeVictoried[index] = false

            // Handle leave events for observers
            if (IsPlayerObserver(indexPlayer)) then
                // Set a trigger to fire whenever this player leaves
                set trig = CreateTrigger()
                call TriggerRegisterPlayerEvent(trig, indexPlayer, EVENT_PLAYER_LEAVE)
                call TriggerAddAction(trig, function MeleeTriggerActionPlayerLeft)
            endif
        endif

        set index = index + 1
        exitwhen index == bj_MAX_PLAYERS
    endloop

    // Test for victory / defeat at startup, in case the user has already won / lost.
    // Allow for a short time to pass first, so that the map can finish loading.
    call TimerStart(CreateTimer(), 2.0, false, function MeleeTriggerActionAllianceChange)
endfunction

My suggestion is to copy the melee leave code and use your copied version of it over the standard one. You can then modify the code with special cases to deal with your Old Gods race correctly.