[vJASS] ExecuteFunc

[Starquizer]

What is the ExecuteFunc command, can't understand what it does.

And also what is the difference between 'ExecuteFunc' and 'call' ?

I was unable to understand JassHelper manual.

TIA

 

[Magtheridon96]

function HelloMyNameIsEd takes nothing returns nothing
    call DestroyTrigger(CreateTrigger())
endfunction

private struct Inits extends array
    private static method onInit takes nothing returns nothing
        call ExecuteFunc("HelloMyNameIsEd")
    endmethod
endstruct

That's how it works :3

The difference between this and call is that this is more dynamic and it opens up a new thread. (Well, not exactly opening up a new thread, but it simulates it. Warcraft III is single-threaded)

Dynamism:

globals
    private string func = ""
endglobals

// ....

call ExecuteFunc(func)

// ...

set func = "..."

That way, you could change the function that gets executed.

 

[Starquizer]

???!!!!!

Easy please; I am just a newbie.

 

[overcold_ice]

here:

// instead of doing this:
call TriggerEvaluate(trigger) // this isn't dynamic, let's see the process

local trigger t = CreateTrigger()
call TriggerRegisterCondition(t, Condition(function toCall)) // or
call TriggerRegisterAction(t, Condition(function toCall))
// execute it
call TriggerEvaluate(trigger)

// do this instead
call ExecuteFunc("toCallName") // this is more flexible, due the use of string,
                               // and take a look at the process

local string f = "MyFunction" // optional
call ExecuteFunc(f) // static use

// dynamic use
local integer i = 5
loop
    exitwhen i == 0
    call ExecuteFunc("MyFunction" + I2S(i))
    set i = i - 1
endloop

 

[Starquizer]

@ overcold_ice
Thanks for the explanation, first.

Will ExecuteFunc works if the function has arguments ?

 

[overcold_ice]

you don't get it ~.~ . . . . .
the main function is to run the function, ignoring the arguments . . .
same goes to that TriggerEvaluation method i listed above . .

here another one:

// you will get sucked up using these things
if FunctionName == "ABC" then
    call ABC(arg1, arg2, arg3)
elseif FunctionName == "CDE" then
    call CDE(arg1, arg2, arg3)
// . . . . so on

// this is a short alternative, easy to use, but missing arguments
// arguments aren't that necessary, except for APIs and natives
call TriggerEvaluate(trigger) // common ways
call ExecuteFunc("string") // rare ways, due to the ineffectiveness of .name thing
// i'm not quite experienced with these things
call function.evaluate()
call function.execute()

edit:
sorry, i misunderstood D:
it will work just fine ~
now i don't know ~
maybe not . . .

 

[WaterKnight]

No you cannot run functions with ExecuteFunc that take arguments.

 

[overcold_ice]

i didn't know that ~.~
good to know it

 

[Starquizer]

i didn't know that ~.~
good to know it

Its OK no problem I am just trying to remember some old vJASS.

 

[Geries]

ExecuteFunc is not vJass, it is only used to call "onInit" and initializer functions. The called function don't have to exist, so you can set anything there just nothing will happen and thread( function/trigger ) will continue. ExecuteFunc also ignores function priority order:

function A takes nothing returns nothing
     call ExecuteFunc( "B" )
endfunction

function B takes nothing returns nothing
     // If function A is called then this will run
endfunction

Also it runs a new thread, so function "B" will start operation count at 0.

function A takes nothing returns nothing
     call ExecuteFunc( "A" )
     // Infinite loop, never ends cause op limit never be reached also crashes warcraft
endfunction

And if you try to execute a function that takes arguments warcraft will crash at load. Thats why onInit functions must be static.

 

[Magtheridon96]

And if you try to execute a function that takes arguments warcraft will crash at load. Thats why onInit functions must be static.

And because a method onInit would be the create method :I

 

[mckill2009]

you can also do like this (just for fun)...

function A takes nothing returns nothing
   call ExecuteFunc("C")
endfunction

function B takes arg1, arg2.... returns unit
   return unit
endfunction

function C takes nothing returns nothing
   local unit u = B(arg1, arg2......)
endfunction

 

[Magtheridon96]

@geries, that infinite loop doesn't crash warcraft, it exits it

This would crash warcraft:

function CrashGame takes nothing returns nothing
    call Player(-1337)
endfunction

 

[Bribe]

There are several main ways to run code:

//JASS:

call Function() //#1

call ExecuteFunc("Function") //#2

set trig = CreateTrigger()
call TriggerAddCondition(trig, Filter(function Function))
call TriggerEvaluate(trig) //#3

set trig = CreateTrigger()
call TriggerAddAction(trig, function Function)
call TriggerExecute(trig) //#4

call ForForce(bj_FORCE_PLAYER[0], function Function) //#5, unorthodox but it has its perks

call TimerStart(CreateTimer(), 60.00, true, function Function) //#6, very important

//vJass "additions":

call Function.evaluate() //When compiled, works the same as #3

call Function.execute() //When compiled, works the same as #4

Obviously, triggers are necessary for registering events, but this is to show you that you have lots of options for running code.

Keep in mind, only ExecuteFunc or TriggerAddAction lets you use TriggerSleepAction within the function. Other than that, besides calling a function, the behaviors will work the same whenever you use "ExecuteFunc" or pass the "code" type as an argument:

1) Function will open up its own thread, so if that thread crashes or reaches the op-limit the thread which existed before it will not crash.

2) The op-limit of the new thread will be reset, so you can distribute heavy actions across multiple threads when necessary.

 

[Cokemonkey11]

call ForForce(bj_FORCE_PLAYER[0], function Function) //#5, unorthodox but it has its perks

can you tell me about this one? can't say I've ever seen someone do it before.

 

[Bribe]

It's unorthodox, and only (ab)used fairly recently, which is probably why you haven't seen it before.

Mostly you'll see its use in the JASS Resources section from Magtheridon96 and myself.

Without it, there is no way to pass a function as an argument and be able to simply "call" it. Sure with vJass you can use function interfaces and ".evaluate()" them or ".execute()" them, but interfaces double the code length which sucks.

 

[Cokemonkey11]

what about passing a string as an argument and then using ExecuteFunc()?

 

[Bribe]

You could do that, too, but then you have to use strings which is really inconvenient when you use things like structs/private functions because with structs you have to type "s__StructName_StaticMethod" and private functions you don't know if it's 2 or 3 underscores because JH randomizes it.

 

[Starquizer]

In the previous posts the word "Thread" is mentioned, what is that ? (I have lots of catching-up to do, it seems)

 

[Bribe]

Thread in the sense we are talking about is a shell containing the code you're running WHILE it's running.

That also means that if you use a TriggerSleepAction (from a Trigger action or from ExecuteFunc) that the first thread doesn't sleep during that time, so you can use it to delegate actions appropriately:

function InitTrig_MyTrigger takes nothing returns nothing
    call ExecuteFunc("Hello")
    call BJDebugMsg("Hello")
endfunction

function Hello takes nothing returns nothing
    call TriggerSleepAction(0)
    call BJDebugMsg("World")
endfunction

//This will display to you:

"Hello"
...
"World"

 

[Geries]

Thread in the sense we are talking about is a shell containing the code you're running WHILE it's running.

That also means that if you use a TriggerSleepAction (from a Trigger action or from ExecuteFunc) that the first thread doesn't sleep during that time, so you can use it to delegate actions appropriately:

function InitTrig_MyTrigger takes nothing returns nothing
    call ExecuteFunc("Hello")
    call BJDebugMsg("Hello")
endfunction

function Hello takes nothing returns nothing
    call TriggerSleepAction(0)
    call BJDebugMsg("World")
endfunction

//This will display to you:

"Hello"
...
"World"

Wait won't work

 

[WaterKnight]

Wait won't work

It does. But I think it did not in some previous version. Well, actually it's called >Trigger<SleepAction.

 

[Starquizer]

Is

TriggerSleepAction

equivalent to the

• Wait X sec

???

 

[WaterKnight]

Yes, the 0 was just arbitrarily chosen. Everyone should know that TriggerSleepAction(0) is not actually immediate.

 

[Bribe]

Well we don't know how ExecuteFunc actually works. Maybe behind the scenes Blizzard uses an internal pseudo-trigger to run that script, which could be why TriggerSleepAction works in that case. However it doesn't affect the value of GetTriggeringTrigger(), so maybe the function "TriggerSleepAction" just has an irrelevant name.

 

[Starquizer]

I am still confused, when do I use ExecuteFunc over call.
There is also .evaluate is it similar to ExecuteFunc and call ?

I am really confused and don't know what I am missing to understand those things ???!!!!

 

[Bribe]

Your best situation is to use "call" 100% of the time, and then as you have need of other things use them.

I get people asking me "what does this thing do?" but honestly it might as well do nothing unless you already have a need of it.

 

[Starquizer]

I am reading the Jass Helper manual but there are lots of vague things, how do I understand them since you seems to have a good experience in Jass.

Other than that thanks for your help (+rep)

 

[WaterKnight]

Imagine that you want to run a function out of one hundred depending on the content of a variable.

So you could write:

if (var == 1) then
    call Func1()
elseif (var == 2) then
    call Func2()
elseif (var == 3) then
    call Func3()
elseif (var == 4) then
    call Func4()
...
elseif (var == 100) then
    call Func100()
endif

You see this is inconvenient, produces lots of code, is kind of slow if var is high and these functions might originate from some completely other position that has nothing to do with it.

Instead you could write:

call ExecuteFunc("Func" + I2S(var))

or you do not even know how the function is named, it's just passed as a code parameter or in another container.

So you can do this for example:

local trigger t = CreateTrigger()

call TriggerAddCondition(t, Condition(code))

call TriggerEvaluate(t)

 

[Bribe]

Well if something is vague make a post about it, like you have done here. I recommend if the thing is too vague, skip over it for now and read the things that make sense, and then tomorrow when your brain has settled from the new material you can try again to grasp it.

The best ways to learn: write out the code yourself, and see how it compiles (by checking the outputwar3map.j file in the logs folder of the JNGP folder).

 

[Cokemonkey11]

vJass can do a lot of things, but not all of them are really THAT helpful.

Your best bet is to understand the important, useful stuff, and use it.

Here are some good keywords to understand from the top of my head:

scope
library
struct
method
globals
private
constant
public

Other things like text macros are quite unnecessary for now.

Good luck and happy coding!

 

[Bribe]

Well "constant" is not a vJass exclusive feature

Structs wouldn't have been so popular without TimerUtils doing the data transfer, though better systems have evolved since then like Timer32 and the more complicated but more lightweight CTL.

 

[WaterKnight]

I only use structs (+my structs follower extension).

 

[Cokemonkey11]

I use structs in all MUI spells, without any timer library.

1 global timer per scope is the way to go, IMO!

 

[Bribe]

Definitely - if you know how to write out your own linear stack or linked list, everything should be fine!

 

[Troll-Brain]

If the period is really low it's ok, but it doesn't really work with "high" periods such as one second.
Now ofc it all depends what you want/need.