[vJASS] Angle Between Co-ords?

[Mr_Bean]

I am trying to make a spell which involves the hero charging towards the targeted unit. However, I cannot seem to get the angle of charging correct. I have used the function:

set D.angle = Atan2(GetUnitX(D.caster) - GetUnitX(D.target), GetUnitY(D.caster) - GetUnitY(D.target))

However, this is not very accurate. Any other more efficient way of determining the angle between the co-ords?

Thanks!

EDIT: Also, how would I pause the unit, but still constantly play its "walk" animation while charging?

 

[Troll-Brain]

It is supposed to be :
y2 - y1 , x2 - 1 and not x2 - x1 , y2 - y1

SetUnitAnimation... doesn't work when the unit is paused ?

 

[Mr_Bean]

Hmmm, I changed the xs and ys around, but it still does the same thing.

EDIT: You can play animations while a unit is paused. I just tested with the unit's "attack" animation. However, the "walk" animation only plays for a fraction of a second.

 

[Troll-Brain]

You got it that the result is in radian, not degre ?

 

[Mr_Bean]

Yes. Would you mind taking a look at my code?

Code

scope Forward

    private struct ForwardData
        unit caster
        unit target
        real TotalDist
        real DistLeft
        real angle
    
        static method Timer_Actions takes nothing returns nothing
            local timer t = GetExpiredTimer()
            local thistype D = GetTimerData(t)
            local real x
            local real y
            local real x2
            local real y2
            if D.DistLeft > 0 then
                set x = GetUnitX(D.caster)
                set y = GetUnitY(D.caster)
                set x2 = x + 5 * Cos(D.angle * bj_DEGTORAD)
                set y2 = y + 5 * Cos(D.angle * bj_DEGTORAD)
                call SetUnitX(D.caster, x2)
                call SetUnitY(D.caster, y2)
                set D.DistLeft = D.DistLeft - 5
            else
                call ReleaseTimer(t)
                call SetUnitPathing(D.caster, true)
                call PauseUnit(D.caster, false)
                call SetUnitAnimation(D.caster, "stand")
                call D.deallocate()
            endif
            set t = null
        endmethod
    
        static method create takes nothing returns thistype
            local thistype D = thistype.allocate()
            local real xdist
            local real ydist
            local timer t = NewTimer()
            set D.caster = GetTriggerUnit()
            set D.target = GetSpellTargetUnit()
            set xdist = GetUnitX(D.caster) - GetUnitX(D.target)
            set ydist = GetUnitY(D.caster) - GetUnitY(D.target)
            set D.TotalDist = SquareRoot((xdist * xdist) + (ydist * ydist))
            set D.DistLeft = D.TotalDist
            call SetUnitPathing(D.caster, false)
            call PauseUnit(D.caster, true)
            call SetUnitAnimation(D.caster, "walk")
            set D.angle = bj_RADTODEG * (Atan2(GetUnitY(D.target) - GetUnitY(D.caster), GetUnitX(D.target) - GetUnitX(D.caster)))
            call SetTimerData(t, D)
            call TimerStart(t, 0.03, true, function thistype.Timer_Actions)
            set t = null
            return D
        endmethod
        
        static method Conditions takes nothing returns boolean
            if GetSpellAbilityId() == 'A001' then
                call thistype.create()
            endif
            return false
        endmethod
        
        static method onInit takes nothing returns nothing
            local trigger t = CreateTrigger()
            call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
            call TriggerAddCondition(t, Condition(function thistype.Conditions))
            set t = null
        endmethod
    
    endstruct

endscope

 

[WaterKnight]

You use Cos on y, should be Sin.

http://rml3.com/a20p/images/trig_sin_cos_tan.gif

And for walk animation, take SetUnitAnimationByIndex.

 

[Mr_Bean]

OMG, such a stupid mistake (don't worry, I know basic trig, I just copied that line and forgot to change cos to sin).

What integer corresponds to "walk"?

 

[WaterKnight]

That's different for each model because it depends in which order animations are declared. Starting from 0, it counts upwards. If you are not adept with modeling, just trial&error. Can only be between 0 and number of animations - 1.

 

[Magtheridon96]

Here's a tip:
Instead of caching the angle, you can cache the sin of the angle in radians and the cosine.

 

[Mr_Bean]

Thanks Waterknight, I will use trial and error.

The reason I use degrees is I have just finished highschool and I have never worked with radians.

 

[Mr_Bean]

Update:
I found the integer for the "attack" animation, but it only plays once with SetUnitAnimationByIndex. Any ideas on how I can make the unit constantly play the "walk" animation?

 

[Troll-Brain]

I would say periodic timer.

 

[Maker]

One option is to use a hidden (visible set to false) ability based on Channel. Order the unit to cast that and give it long follow through time. Set animation to walk for the ability.

 

[Mr_Bean]

Awesome, I finally found the integer for "walk" and you don't need a periodic timer to make it constant - you set the animation once and it works. Thanks for your help!

 

[WaterKnight]

That's because walk animations are usually looping, option of model animations.