[JASS] Whats wrong with this trigger???

[adishaireen]

hey, i tried to make Hellfire with JASS trigger but whats up with this trigger??? Is this right or not???

function Hellfire_Conditions takes nothing returns boolean
    if ( not ( GetSpellAbilityId() == 'A000' ) ) then
        return false
    endif    
    return true
endfunction

function Hellfire_Actions takes nothing returns nothing
    set udg_caster = GetTriggerUnit()
    set udg_castrloc = GetUnitLoc(udg_caster)
    set udg_castrface = GetUnitFacing(udg_caster)
    set udg_targetloc = GetSpellTargetLoc()
    set bj_forLoopAIndex = 1
    set bj_forLoopAIndexEnd = 10
    loop
        exitwhen bj_forLoopAIndex > bj_forLoopAIndexEnd
        call CreateNUnitsAtLoc( 1, 'hfoo', GetOwningPlayer(udg_caster), PolarProjectionBJ(udg_castrloc, 256, udg_castrface), bj_UNIT_FACING )
        set udg_dummy = GetLastCreatedUnit ()
        set udg_dummyloc = GetUnitLoc(udg_dummy)
        call UnitAddAbilityBJ( 'A000' , udg_dummy )
        call UnitApplyTimedLifeBJ( 1.50, 'BTLF', udg_dummy )
        call IssueImmediateOrderBJ( udg_dummy, "thunderclap" )
        call AddSpecialEffectLocBJ( udg_dummyloc, "Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl" )
        call DestroyEffectBJ( GetLastCreatedEffectBJ() )
        set bj_forLoopAIndex = bj_forLoopAIndex + 1
    endloop
endfunction                     

//===========================================================================
function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

 

[Laiev]

This is gui converted...

You have no event here.

function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

You could change all the BJs (red names) to natives (purple names).
Also, you never use your condition and it can be improved.

 

[adishaireen]

This is gui converted...

You have no event here.

function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

You could change all the BJs (red names) to natives (purple names).
Also, you never use your condition and it can be improved.

how to add event???

and how i wanna use my condition??

aaaand how i wanna change BJ to natives????

 

[mckill2009]

like this...

function Hellfire_Conditions takes nothing returns boolean
   return GetSpellAbilityId() == 'A000'
endfunction

function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ(gg_trg_Hellfire, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_Hellfire, Condition(function Hellfire_Conditions))
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

 

[Laiev]

Most of BJs are stupid... Look this:

call UnitAddAbilityBJ('A000' , udg_dummy) // this is the bj that call the native below
call UnitAddAbility(udg_dummy, 'A000') // this is the native

If you're using JNGP, hold Ctrl and click on some BJ and see how it's used.

Most of them are like my example above.

Edit: Something freehanded.

function Hellfire_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real x = GetUnitX(u)
    local real y = GetUnitY(u)
    local real f = GetUnitFacing(u)
    local player p = GetTriggerPlayer()
    // ------------------------------
    local real xx = x + 256 * Cos(f * bj_DEGTORAD)
    local real yy = y + 256 * Sin(f * bj_DEGTORAD)
    local integer i = 0
    local unit d
    
    loop
        exitwhen i > 9
        set d = CreateUnit(p, 'hfoo', xx, yy, 0.)
        call UnitAddAbility(d, 'A000')
        call UnitApplyTimedLife(d, 'BTLF', 1.50)
        call IssueImmediateOrder(d, "thunderclap")
        call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y)
        set i = i + 1
    endloop
    
    set u = null
    set d = null
    set p = null
endfunction

 

[adishaireen]

Most of BJs are stupid... Look this:

call UnitAddAbilityBJ('A000' , udg_dummy) // this is the bj that call the native below
call UnitAddAbility(udg_dummy, 'A000') // this is the native

If you're using JNGP, hold Ctrl and click on some BJ and see how it's used.

Most of them are like my example above.

Edit: Something freehanded.

function Hellfire_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real x = GetUnitX(u)
    local real y = GetUnitY(u)
    local real f = GetUnitFacing(u)
    local player p = GetTriggerPlayer()
    // ------------------------------
    local real xx = x + 256 * Cos(f * bj_DEGTORAD)
    local real yy = y + 256 * Sin(f * bj_DEGTORAD)
    local integer i = 0
    local unit d
    
    loop
        exitwhen i > 9
        set d = CreateUnit(p, 'hfoo', xx, yy, 0.)
        call UnitAddAbility(d, 'A000')
        call UnitApplyTimedLife(d, 'BTLF', 1.50)
        call IssueImmediateOrder(d, "thunderclap")
        call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y)
        set i = i + 1
    endloop
    
    set u = null
    set d = null
    set p = null
endfunction

yours are very good n i like it... no need to use:

//===============================================
function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ(gg_trg_Hellfire, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_Hellfire, Condition( function Hellfire_Conditions ) )
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

Edit:Wait, when i tried your trigger, it says "script errors:line 45:expected ''

and it highlighted

[JASS=] call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y) [/code]

wtf!!! after i tried this trigger:

[JASS=]

function Hellfire_Actions takes nothing returns nothing
local unit u = GetTriggerUnit()
local real x = GetUnitX(u)
local real y = GetUnitY(u)
local real f = GetUnitFacing(u)
local player p = GetTriggerPlayer()
//-------------------------------
local real xx = x + 256 * Cos(f * bj_DEGTORAD)
local real yy = y + 256 * Sin(f * bj_DEGTORAD)
local integer i = 0
local unit d

loop
exitwhen i > 9
set d = CreateUnit( p, 'hfoo', xx , yy , 0 )
call UnitAddAbility(d, 'A000')
call UnitApplyTimedLife(d, 'BTLF', 1.50)
call IssueImmediateOrder(d, "thunderclap")
set i = i + 1
endloop

set u = null
set d = null
set p = null
endfunction

//--------------------------------------------------------
function InitTrig_Hellfire takes nothing returns nothing
set gg_trg_Hellfire = CreateTrigger()
call TriggerRegisterAnyUnitEventBJ( gg_trg_Hellfire, EVENT_PLAYER_UNIT_SPELL_EFFECT )
call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

[/code]


my pc lag like shit and crash my whole pc


and this trigger cant be used as long as the InitTrig_Hellfire not used...

 

[Mr_Bean]

Why are you creating 9 units at the same location and making them cast Thunder Clap?

 

[adishaireen]

Why are you creating 9 units at the same location and making them cast Thunder Clap?

and how to make it straight-line???

 

[Maker]

wtf!!! after i tried this trigger:
my pc lag like shit and crash my whole pc

It is because the thunderclap will trigger the hellfire ability, since there is no any kind of ability id filtering. Thus with each thunderclap, more dummies are created and they cast thunderclap creating even more dummies -> crash.

 

[adishaireen]

thunder clap create dummies???

n how to disable it???

 

[Mr_Bean]

function cond_Hellfire takes nothing returns boolean
    if (GetSpellAbilityId() == 'your_id') then
        return true
    endif
    return false
endfunction

function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Hellfire, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition(gg_trg_Hellfire, Condition(function cond_Hellfire))
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

Note: Replace your_id with the ID of your Hellfire spell.

 

[Maker]

function cond_Hellfire takes nothing returns boolean
    return GetSpellAbilityId() == 'your_id'
endfunction

There.

 

[Mr_Bean]

^ Or you could do that.

 

[Laiev]

call DestroyEffect(AddSpecialEffect("Abilities\\Spells\\Other\\Doom\\DoomDeath.mdl", x, y))

Sorry I forget one ) in the end of line lol

The actual problem is that there's no condition to detect what exactly ability is... If any ability is casted, then this trigger will run. In the trigger, dummies cast thunder clap, so the trigger run again, creating new dummies, ordering them to thunder clap again and make the trigger running again. Infinity loop .

Also, to make the spell cast thunder clap in line, you should change the value of variables 'xx' and 'yy' inside the loop based on the variable 'i'. Like:

function Hellfire_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real x = GetUnitX(u)
    local real y = GetUnitY(u)
    local real f = GetUnitFacing(u)
    local player p = GetTriggerPlayer()
    //-------------------------------
    local real xx = x + 50 * Cos(f * bj_DEGTORAD)
    local real yy = y + 50 * Sin(f * bj_DEGTORAD)
    local integer i = 1
    local unit d
  
    loop
        exitwhen i > 10
        set d = CreateUnit( p, 'hfoo', xx , yy , 0 )
        set xx = x + (50 * i) * Cos(f * bj_DEGTORAD) //this will be dynamic
        set yy = y + (50 * i) * Sin(f * bj_DEGTORAD) //the distance will be 50/100/150... util 500
        call UnitAddAbility(d, 'A000')
        call UnitApplyTimedLife(d, 'BTLF', 1.50)
        call IssueImmediateOrder(d, "thunderclap")
        set i = i + 1
    endloop

    set u = null
    set d = null
    set p = null
endfunction

 

[adishaireen]

is this okay???

function Hellfire_Condition takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction 

function Hellfire_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real x = GetUnitX(u)
    local real y = GetUnitY(u)
    local real f = GetUnitFacing(u)
    local player p = GetTriggerPlayer()
    //-------------------------------
    local real xx = x + 50 * Cos(f * bj_DEGTORAD)
    local real yy = y + 50 * Sin(f * bj_DEGTORAD)
    local integer i = 1
    local unit d
  
    loop
        exitwhen i > 10
        set d = CreateUnit( p, 'hfoo', xx , yy , 0 )
        set xx = x + (50 * i) * Cos(f * bj_DEGTORAD) //this will be dynamic
        set yy = y + (50 * i) * Sin(f * bj_DEGTORAD) //the distance will be 50/100/150... util 500
        call UnitAddAbility(d, 'A000')
        call UnitApplyTimedLife(d, 'BTLF', 1.50)
        call IssueImmediateOrder(d, "thunderclap")
        set i = i + 1
    endloop

    set u = null
    set d = null
    set p = null
endfunction

//--------------------------------------------------------
function InitTrig_Hellfire takes nothing returns nothing
    set gg_trg_Hellfire = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ( gg_trg_Hellfire, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_Hellfire, Condition( function Hellfire_Condition ) )
    call TriggerAddAction( gg_trg_Hellfire, function Hellfire_Actions )
endfunction

 

[Mr_Bean]

Not yet. What is the code of the spell that the hero casts? This is because you add the spell with code A000 to the dummy and the condition for triggering the spell is that the spell must be A000, which means it will crash again.

 

[adishaireen]

i....dunno..but its Breath Of Fire(custom spell)

 

[Mr_Bean]

In the object editor select this ability and press CTRL + d. This displays the raw codes for the spells (look on the left-hand side of the screen). What does it say for your spell?

 

[Maker]

If you aren't going to use the f in angles anywhere, do the * bj_DEGTORAD when you get the facing. You don't have to calculate it four times.

 

[adishaireen]

wait, what is the mean of bj_DEGTORAD???
(i've been wondering it 1/2 night)

Edit:if the code is A000:ANbf, how i wanna attached it to JASS???

Edit 1nce more: n what is Cos and Sin ????

 

[Maker]

bj_DEGTORAD converts degrees (0...360) into radians (0...2*Pi). It is a preset value, Pi/180.

 

[adishaireen]

and what is Cos and Sin ??????

 

[PurgeandFire]

They are trigonometric functions.

http://www.mathsisfun.com/sine-cosine-tangent.html

 

[adishaireen]

b4 i post this into spells, i wanna make sure if this SpawnCreeps trigger is right:

[JASS=]function SpawnCreeps_Actions takes nothing returns nothing

call FogEnableOff( )
call FogMaskEnableOff( )
call CreateNUnitsAtLoc( 10, 'nmrl', Player(PLAYER_NEUTRAL_AGGRESSIVE), GetRectCenter(gg_rct_Region_000), bj_UNIT_FACING )


endfunction

//===========================================================================
function InitTrig_SpawnCreeps takes nothing returns nothing
set gg_trg_SpawnCreeps = CreateTrigger( )
call TriggerRegisterTimerEventPeriodic( gg_trg_SpawnCreeps, 5.00 )
call TriggerAddAction( gg_trg_SpawnCreeps, function SpawnCreeps_Actions )
endfunction

[/code]

 

[mckill2009]

replace the CreateNUnitsAtLoc to CreateUnit then loop it 10x...use coordinates instead of
locations...you location leak btw...

TriggerRegisterTimerEventPeriodic >>> TriggerRegisterTimerEvent