String to Integer question

[shadowvzs]

i want make a function what colorize the text depend its contain number/lower or uppercase letters

lets say udg_String = *random 100 character*

and i want check with loop each character, lower/uppercase character i think ok with if s==StringCase(s,true) then do action but i got problem with numbers coz S2I give 0 to every non number letter, but i got no clue how to make difference between this:

S2I("k") and S2I("0") coz result is same 0 in both case :/

 

[-Kobas-]

you can compare strings as well ?

you pick string from line of text and then compare it inside loop with some string array where you stored all low case (a,b,c...) etc...

Dunno really

 

[Arhowk]

Isnt there a snippet for that?

e/

library ColorCodeString
    function ColorCodeString takes string s, string numColor, string lowerColor, string upperColor, string specColor, integer start returns string
        local string ns = ""
        local string c
        local integer m = StringLength(s)
        local integer i = start
        local boolean l
        loop
            exitwhen m == i
            
            set c = SubString(s,i,i+1)
            
            if (c!=" ") then
                set l=StringCase(c,false)==c
                
                //special or number
                if (c==StringCase(c,true) and l) then
                    //number
                    if ("0"==c or 0!=S2I(c)) then
                        set ns=ns+"|cff"+numColor+c
                    //special
                    else
                        set ns=ns+"|cff"+specColor+c
                    endif
                //lowercase
                elseif (l) then
                    set ns=ns+"|cff"+lowerColor+c
                //uppercase
                else
                    set ns=ns+"|cff"+upperColor+c
                endif
            else
                set ns=ns+" "
            endif
            
            set i = i + 1
        endloop
        return ns
    endfunction
endlibrary

 

[shadowvzs]

ok i got that ideea about string comparasion like if same then upper and lowercased string then its number or syntax but i ty to both of u the help

 

[Magtheridon96]

function IsCharNumber takes string s returns boolean
    return I2S(S2I(s)) == s
endfunction

function IsCharLetter takes string s returns boolean
    return StringCase(s,true) != StringCase(s,false)
endfunction

function IsCharSymbol takes string s returns boolean
    return not IsCharLetter(s) and not IsCharNumber(s)
endfunction

 

[Dr Super Good]

The hash of "0" is different from the hash of "k". so use that.

The hash of "k" is the same as the hash of "K" so be aware that this can not detect case.