[Snippet] Order Types

Berb · Jun 10, 2010

Order Types

In Warcraft III the possibilities for types of orders are limited to 3. They are:

Point
Target
Immediate/None

Also worth mentioning is the three different types of targets, which are:

Unit
Destructable
Item

It is often necessary to distinguish between these, for example you want your spell to perform a different set of actions if the target is a unit or a destructable (or if the order-type is a point target as opposed to a unit target) this library efficiently produces a result that can be used as a simple integer.

JASS:

library OrderTypes
/*******************************
 * Order Types Library
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 * by: Berb
 * Version: 1.0
 * 
 * Description:
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 *	The purpose of this library is to provide the user with an API function that allows
 *	them to easily (and efficiently) check which type of order the current event response
 *	is dealing with. It uses event responses such as "GetOrderPointLoc" so using this 
 *	outside of an event response action will not work.
 *
 * API:
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 *      • GetOrderType                  ~ Returns an integer constant representing the type
 *                                      of order that is in-process. 
 *      • GetAbilityOrderType           ~ Just like "GetOrderType" except for ability
 *                                      events rather than order events.
 *
 *      • GetOrderTargetType            ~ Returns an integer constant representing the type
 *                                      of target that the order was issued on.
 *      • GetAbilityOrderTargetType     ~ Just like "GetOrderTargetType" except for ability
 *                                      events rather than order events.
 *
 * Constants -------------------------------------------------------------------------------*/
    globals

        constant	integer     ORDER_TYPE_NONE     = 0
        constant	integer     ORDER_TYPE_POINT    = 1
        constant	integer     ORDER_TYPE_TARGET   = 2
        
        constant    integer     TARGET_TYPE_UNIT    = 0
        constant    integer     TARGET_TYPE_DEST    = 1
        constant    integer     TARGET_TYPE_ITEM    = 2
        constant    integer     TARGET_TYPE_NONE    = 3
        
    endglobals
/* -----------------------------------------------------------------------------------------
 * 
 */
    globals
        private     location	data__targetLoc		= null
    endglobals
				
    function GetAbilityOrderTargetType takes nothing returns integer
        if GetSpellTargetUnit() != null then
            return TARGET_TYPE_UNIT
        elseif GetSpellTargetItem() != null then
            return TARGET_TYPE_ITEM
        elseif GetSpellTargetDestructable() != null then
            return TARGET_TYPE_DEST
        endif
        return TARGET_TYPE_NONE
    endfunction
                
    function GetAbilityOrderType takes nothing returns integer   
        if GetSpellTargetUnit() != null     or /*
            */ GetSpellTargetItem() != null or /*
            */ GetSpellTargetDestructable() != null then
            return ORDER_TYPE_TARGET
        endif
        
        set data__targetLoc = GetSpellTargetLoc()    
        if data__targetLoc != null then
            call RemoveLocation(data__targetLoc)
            return ORDER_TYPE_POINT
        endif
        return ORDER_TYPE_NONE
    endfunction
        
    function GetOrderTargetType takes nothing returns integer
        if GetOrderTargetUnit() != null then
            return TARGET_TYPE_UNIT
        elseif GetOrderTargetItem() != null then
            return TARGET_TYPE_ITEM
        elseif GetOrderTargetDestructable() != null then
            return TARGET_TYPE_DEST
        endif
        return TARGET_TYPE_NONE
    endfunction
        
    function GetOrderType takes nothing returns integer
        if GetOrderTarget() != null then
            return ORDER_TYPE_TARGET
        endif
        
        set data__targetLoc = GetOrderPointLoc()
        if data__targetLoc != null then
            call RemoveLocation(data__targetLoc)
            return ORDER_TYPE_POINT
        endif
        return ORDER_TYPE_NONE
    endfunction
 /*
  *
  ******************************************************************************************/
 endlibrary

Initially this was written in zinc, but since I really don't find the zinc language attractive in an environment designed for vJass I converted it to plain ol' vJass.

I think this should be a little more appropriate for the JASS section than my previous two submissions, I thought many would find this useful and I couldn't find anything of the sort already submitted.

Pharaoh_ · Jun 10, 2010

You can use GetSpellTargetX/Y() and check if they are 0, instead of using location.
Very simple, I have seen one somewhere else (that one was concerning widget only, not every type of order target), but it definitely is useful.

Berb · Jun 11, 2010

Well I used GetOrderPointLoc and GetSpellTargetLoc because they explicitly return (null) when there is an instant order, where as the (x, y) natives can return 0.00 in two possible scenarios. It also eliminates having to declare/compare two variables, instead I can just use the one. Since the location only needs to be removed if the location is not null, then I figure it saves a few steps.

azlier · Jun 11, 2010

Looks good.

Berb · Jun 11, 2010

I don't know where that mysterious debug function came from though. I'm going to remove it.

JASS:

    private function Error takes string msg returns nothing
        debug call BJDebugMsg(SCOPE_PREFIX+":|cffff0000Error: "+msg)
    endfunction

I don't remember what I was using this for, but it isn't used in the code at all. It's being removed from the script.

azlier · Jun 11, 2010

Missed that.

Bribe · Jun 18, 2010

To the point, as always.

Axarion · Jun 18, 2010

Nice and easy library. Saves some work =)

Bribe · Feb 6, 2011

JASS:

    function GetOrderType takes nothing returns integer
        if GetOrderTarget() != null then
            return ORDER_TYPE_TARGET
        endif
        
        set data__targetLoc = GetOrderPointLoc()
        if data__targetLoc != null then
            call RemoveLocation(data__targetLoc)
            return ORDER_TYPE_POINT
        endif
        return ORDER_TYPE_NONE
    endfunction

The native GetTriggerEventId can be used instead of the location, in conjunction with EVENT_PLAYER_UNIT_ISSUED_ORDER and EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER and EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER

Berb · Feb 8, 2011

I suppose you could that would probably save some processing time.

Bribe · Jun 21, 2011

Yeah, here would be the updated library with the slight optimization if you're interested:

JASS:

library OrderTypes
/*******************************
 * Order Types Library
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 * by: Berb
 * Version: 1.0
 * 
 * Description:
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 *    The purpose of this library is to provide the user with an API function that allows
 *    them to easily (and efficiently) check which type of order the current event response
 *    is dealing with. It uses event responses such as "GetOrderPointLoc" so using this 
 *    outside of an event response action will not work.
 *
 * API:
 * ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
 *      • GetOrderType                  ~ Returns an integer constant representing the type
 *                                      of order that is in-process. 
 *      • GetAbilityOrderType           ~ Just like "GetOrderType" except for ability
 *                                      events rather than order events.
 *
 *      • GetOrderTargetType            ~ Returns an integer constant representing the type
 *                                      of target that the order was issued on.
 *      • GetAbilityOrderTargetType     ~ Just like "GetOrderTargetType" except for ability
 *                                      events rather than order events.
 *
 * Constants -------------------------------------------------------------------------------*/
    globals

        constant    integer     ORDER_TYPE_NONE     = 0
        constant    integer     ORDER_TYPE_POINT    = 1
        constant    integer     ORDER_TYPE_TARGET   = 2
        
        constant    integer     TARGET_TYPE_UNIT    = 0
        constant    integer     TARGET_TYPE_DEST    = 1
        constant    integer     TARGET_TYPE_ITEM    = 2
        constant    integer     TARGET_TYPE_NONE    = 3
        
    endglobals
/* -----------------------------------------------------------------------------------------
 * 
 */
    globals
        private     location    data__targetLoc        = null
    endglobals
                
    function GetAbilityOrderTargetType takes nothing returns integer
        if GetSpellTargetUnit() != null then
            return TARGET_TYPE_UNIT
        elseif GetSpellTargetItem() != null then
            return TARGET_TYPE_ITEM
        elseif GetSpellTargetDestructable() != null then
            return TARGET_TYPE_DEST
        endif
        return TARGET_TYPE_NONE
    endfunction
                
    function GetAbilityOrderType takes nothing returns integer   
        if GetSpellTargetUnit() != null     or /*
            */ GetSpellTargetItem() != null or /*
            */ GetSpellTargetDestructable() != null then
            return ORDER_TYPE_TARGET
        endif
        
        set data__targetLoc = GetSpellTargetLoc()    
        if data__targetLoc != null then
            call RemoveLocation(data__targetLoc)
            return ORDER_TYPE_POINT
        endif
        return ORDER_TYPE_NONE
    endfunction
        
    function GetOrderTargetType takes nothing returns integer
        if GetOrderTargetUnit() != null then
            return TARGET_TYPE_UNIT
        elseif GetOrderTargetItem() != null then
            return TARGET_TYPE_ITEM
        elseif GetOrderTargetDestructable() != null then
            return TARGET_TYPE_DEST
        endif
        return TARGET_TYPE_NONE
    endfunction
        
    function GetOrderType takes nothing returns integer
        if GetOrderTarget() != null then
            return ORDER_TYPE_TARGET
        elseif GetTriggerEventId() == EVENT_PLAYER_UNIT_ISSUED_ORDER then
            return ORDER_TYPE_NONE
        endif
        return ORDER_TYPE_POINT
    endfunction
/*
 *
 ******************************************************************************************/
endlibrary

The downside is it doesn't recognize "EVENT_UNIT_ISSUED_ORDER" but using that event would be a total waste for obvious reasons (no one should be using it)

Magtheridon96 · Jun 21, 2011

Actually the downside is that ugly variable name =P
data__targetLoc

Troll-Brain · Jun 21, 2011

Magtheridon96 said:
Actually the downside is that ugly variable name =P
data__targetLoc

From a guy which uses short variables names for everything. :thumbs_up:

But i'm agree we shoudn't use double underscores, ever, because of vJass.

Magtheridon96 · Jun 21, 2011

From a guy which uses short variables names for everything.

But i'm agree we shoudn't use double underscores, ever, because of vJass

lol You have a point there

Berb · Jun 27, 2011

I'll try to remember to update the script when I get back. I haven't tested it though so I'll do that before jumping to the conclusion, unless you can tell me that it works - your word is good enough for me.

Zwiebelchen · Apr 2, 2016

This snippet will fail if someone uses an immediate ability based on channel. Channel has the nasty property to return the caster for GetSpellTargetUnit() when setting the target type to self-cast, so your condition will break there.

[Snippet] Order Types

Similar threads