Simple buged Jass trigger

[NFWar]

I am messing around with Jass scripts. What is wrong with this one? It says:
"Invalid number of arguments" in this line

    call TriggerAddCondition( gg_trg_StaticBlink, Condition( function Trig_StaticBlink_Conditions ) )

function Trig_StaticBlink_Conditions takes nothing returns boolean
    return true
endfunction

function Trig_StaticBlink_Func004002003001 takes nothing returns boolean
    return ( IsUnitType(GetFilterUnit(), UNIT_TYPE_STRUCTURE) == false )
endfunction

function Trig_StaticBlink_Func004002003002001 takes nothing returns boolean
    return ( IsUnitType(GetFilterUnit(), UNIT_TYPE_FLYING) == false )
endfunction

function Trig_StaticBlink_Func004002003002002001 takes nothing returns boolean
    return ( IsUnitAlly(GetFilterUnit(), GetOwningPlayer(GetTriggerUnit())) == false )
endfunction

function Trig_StaticBlink_Func004002003002002002001 takes nothing returns boolean
    return ( IsUnitAliveBJ(GetFilterUnit()) == false )
endfunction

function Trig_StaticBlink_Func004002003002002002002001 takes nothing returns boolean
    return ( IsUnitType(GetFilterUnit(), UNIT_TYPE_MECHANICAL) == false )
endfunction

function Trig_StaticBlink_Func004002003002002002002002 takes nothing returns boolean
    return ( IsUnitType(GetFilterUnit(), UNIT_TYPE_MAGIC_IMMUNE) == false )
endfunction

function Trig_StaticBlink_Func004002003002002002002 takes nothing returns boolean
    return GetBooleanAnd( Trig_StaticBlink_Func004002003002002002002001(), Trig_StaticBlink_Func004002003002002002002002() )
endfunction

function Trig_StaticBlink_Func004002003002002002 takes nothing returns boolean
    return GetBooleanAnd( Trig_StaticBlink_Func004002003002002002001(), Trig_StaticBlink_Func004002003002002002002() )
endfunction

function Trig_StaticBlink_Func004002003002002 takes nothing returns boolean
    return GetBooleanAnd( Trig_StaticBlink_Func004002003002002001(), Trig_StaticBlink_Func004002003002002002() )
endfunction

function Trig_StaticBlink_Func004002003002 takes nothing returns boolean
    return GetBooleanAnd( Trig_StaticBlink_Func004002003002001(), Trig_StaticBlink_Func004002003002002() )
endfunction

function Trig_StaticBlink_Func004002003 takes nothing returns boolean
    return GetBooleanAnd( Trig_StaticBlink_Func004002003001(), Trig_StaticBlink_Func004002003002() )
endfunction

function Trig_StaticBlink_Func005A takes nothing returns nothing
    call UnitDamageTargetBJ( GetTriggerUnit(), GetEnumUnit(), ( 50.00 + ( 10.00 * I2R(GetUnitAbilityLevelSwapped('A00B', GetTriggerUnit())) ) ), ATTACK_TYPE_NORMAL, DAMAGE_TYPE_LIGHTNING )
endfunction

function Trig_StaticBlink_Actions takes nothing returns nothing
    local group Group
    local location Point
    set Point = GetUnitLoc(GetTriggerUnit())
    set Group = GetUnitsInRangeOfLocMatching(150.00, Point, Condition(function Trig_StaticBlink_Func004002003))
    call ForGroup( Group, function Trig_StaticBlink_Func005A )
    call DestroyGroup(Group)
endfunction

//===========================================================================
function InitTrig_StaticBlink takes nothing returns nothing
    set gg_trg_StaticBlink = CreateTrigger(  )
    call TriggerRegisterUnitEvent( gg_trg_StaticBlink, EVENT_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( gg_trg_StaticBlink, Condition( function Trig_StaticBlink_Conditions ) )
    call TriggerAddAction( gg_trg_StaticBlink, function Trig_StaticBlink_Actions )
endfunction

 

[watermelon_1234]

Actually, the problem is with the line before that, TriggerRegisterUnitEvent. Change that to TriggerRegisterAnyUnitEventBJ and the event to EVENT_PLAYER_UNIT_SPELL_EFFECT and it should work.

If you want, I could optimize that code for you.

BTW, post trigger/jass-related problems in the Triggers & Scripts forum.

 

[Bribe]

1) What is the point in having a condition that just returns true? That's a waste of time unless you're tracking Trigger Evaluations.

2. Mostly Optimized

function Blink_Evaluation takes nothing returns boolean
    local unit u = GetFilterUnit()
 
    if IsUnitType(u, UNIT_TYPE_STRUCTURE) or IsUnitType(u, UNIT_TYPE_FLYING) or IsUnitAlly(u, GetOwningPlayer(GetTriggerUnit())) or GetUnitState(u, UNIT_STATE_LIFE) > 0 or IsUnitType(u, UNIT_TYPE_MECHANICAL) or IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE) then
        set u = null
        return false
    endif
 
    set u = null
    return true
endfunction
 
function Blink_Damage takes nothing returns nothing
    call UnitDamageTarget(GetTriggerUnit(), GetEnumUnit(), ( 50.00 + ( 10.00 * I2R(GetUnitAbilityLevel(GetTriggerUnit(), 'A00B')) ) ), true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_LIGHTNING, WEAPON_TYPE_WHOKNOWS)
endfunction
 
function Blink_Actions takes nothing returns nothing
    local group g = CreateGroup()
    call GroupEnumUnitsInRange(g, GetUnitX(GetTriggerUnit()), GetUnitY(GetTriggerUnit()), 150.00, Condition(function Blink_Evaluation))
    call ForGroup( g, function Blink_Damage )
    call DestroyGroup(g)
    set g = null
endfunction
 
//Initialize Trigger
function InitTrig_StaticBlink takes nothing returns nothing
    set gg_trg_StaticBlink = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_StaticBlink, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( gg_trg_StaticBlink, function Blink_Actions )
endfunction

 

[watermelon_1234]

The code can be optimized a bit more (From Bribe's post):

function Blink_Evaluation takes nothing returns boolean
    local unit u = GetFilterUnit()
    local boolean b = IsUnitType(u, UNIT_TYPE_STRUCTURE) or IsUnitType(u, UNIT_TYPE_FLYING) or  IsUnitAlly(u, GetOwningPlayer(GetTriggerUnit())) or GetUnitState(u,  UNIT_STATE_LIFE) > 0 or IsUnitType(u, UNIT_TYPE_MECHANICAL) or  IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE) //I think you should also check if the unit is alive.
    set u = null
    return b
endfunction
 
function Blink_Damage takes nothing returns nothing
    call UnitDamageTarget(GetTriggerUnit(), GetEnumUnit(), ( 50.00 + ( 10.00 * GetUnitAbilityLevel(GetTriggerUnit(), 'A00B')) ), true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_LIGHTNING, WEAPON_TYPE_WHOKNOWS)
endfunction

 

[Bribe]

Your function returns b if any of those or conditions are true. That's not what it's supposed to do. It needs to return false if any of those or conditions are true.

Also, if the GetUnitState > 0 returns false, that means the unit is dead anyway (I replaced IsUnitDeadBJ).

Edit: I'm almost positive that the I2R which you deleted from UnitDamageTarget needs to be there. I've had syntax errors from trying to calculate Integers with Reals.

@NFWar, use the code I gave you and you won't run into any problems.

 

[PurgeandFire]

    return not b

Perhaps? =P

I tested it with I2R and without, it parses just fine. They are weird in what they consider integers and reals. If you directly input a value of like 2.5 and declare it as an integer, it will show an error. But if you do something like 5/2, it will be declarable as an integer without problems:

function Whee takes nothing returns nothing
    local integer i = 5/2 //no syntax error
    local integer i2 = 7/4 //no syntax error
    local integer i3 = 2.5  //syntax error
    local integer x = i*i2 //you can declare it as an integer or a real without error
    //local real x = i*i2
endfunction

Basically, since it is multiplied by "10.00" and not "10" it is considered a real. =D

 

[Bribe]

Nice, I always wondered about dividing integers. Thanks for that. Does return not b work? I thought not only worked in if/then parameters.

 

[watermelon_1234]

Your function returns b if any of those or conditions are true. That's not what it's supposed to do. It needs to return false if any of those or conditions are true.

Also, if the GetUnitState > 0 returns false, that means the unit is dead anyway (I replaced IsUnitDeadBJ).

This is what happens when I don't look at the code closely.
There is a very simple fix for this though if you don't want to use not b:

local boolean b = IsUnitType(u, UNIT_TYPE_STRUCTURE) == false and IsUnitType(u, UNIT_TYPE_FLYING) == false and IsUnitAlly(u, GetOwningPlayer(GetTriggerUnit())) == false and GetWidgetLife(u) > 0.405 and IsUnitType(u, UNIT_TYPE_MECHANICAL) == false and IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE) == false //This is basically the equivalent of not b

 

[NFWar]

Thx for help... still dont understand what is aproblem...
By cnp Bribe's trigger it show 3 errors

I am rly suck in Jass and cant understand it at all. Return what? takes what? why take? why return? Wtf is this? :S
Also all tutorials are mess, HUGE mess. It explain and I cant understand. Also Jass changing and some tutorials are useless.

 

[watermelon_1234]

By cnp Bribe's trigger it show 3 errors.

I'm pretty sure his trigger can parse correctly. (As long as the trigger you CnPed it to is named StaticBlink.)

Sorry, I can't really help with explaining Jass.

 

[Bribe]

What error messages does it give you? Tell me any "Expected: blah blah blah" - those are the errors I want to know. And tell me which line each one points to.

 

[NFWar]

What error messages does it give you? Tell me any "Expected: blah blah blah" - those are the errors I want to know. And tell me which line each one points to.

Ok, no errors now, but no damage when unit blink
Leave it people. I will never learn Jass...

 

[Bribe]

Nah I know what the problem is. For some reason you wanted it to only target dead units. I don't know why you added that in there, but here it is without that:

function Blink_Evaluation takes nothing returns boolean
    local unit u = GetFilterUnit()
    local boolean b = IsUnitType(u, UNIT_TYPE_STRUCTURE) or IsUnitType(u, UNIT_TYPE_FLYING) or  IsUnitAlly(u, GetOwningPlayer(GetTriggerUnit())) or GetUnitState(u,  UNIT_STATE_LIFE) <= 0 or IsUnitType(u, UNIT_TYPE_MECHANICAL) or  IsUnitType(u, UNIT_TYPE_MAGIC_IMMUNE)
    set u = null
    return not b
endfunction
 
function Blink_Damage takes nothing returns nothing
    call UnitDamageTarget(GetTriggerUnit(), GetEnumUnit(), ( 50.00 + ( 10.00 * GetUnitAbilityLevel(GetTriggerUnit(), 'A00B')) ), true, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_LIGHTNING, WEAPON_TYPE_WHOKNOWS)
endfunction
 
function Blink_Actions takes nothing returns nothing
    local group g = CreateGroup()
    call GroupEnumUnitsInRange(g, GetUnitX(GetTriggerUnit()), GetUnitY(GetTriggerUnit()), 150.00, Condition(function Blink_Evaluation))
    call ForGroup( g, function Blink_Damage )
    call DestroyGroup(g)
    set g = null
endfunction
 
//Initialize Trigger
function InitTrig_StaticBlink takes nothing returns nothing
    set gg_trg_StaticBlink = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( gg_trg_StaticBlink, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddAction( gg_trg_StaticBlink, function Blink_Actions )
endfunction

 

[Bribe]

I am rly suck in Jass and cant understand it at all. Return what? takes what? why take? why return?

Try deleting them and you get errors.

It's a game from 2001. Not many people were familiar with programming back then, so they weren't sure how to code their game. If something looks weird as hell, it's because it is. There's no point in writing "takes nothing returns nothing" - you shouldn't have to write that.

Return what? Return always marks the end of a function. Same as on a Mac, Return marks the end of a paragraph or the sending of data. Sometimes a function is a boolean. Like "if unit is a flyer then do actions". Well, if it's a boolean function, it needs to declare that. So it "returns boolean".

Takes what? That's only if another function is using it. Just keep on with "Takes nothing" for now.

Why take? Greedy bastards...

Why return? It's a give/take relationship.

 

[NFWar]

Ok, trigger works, damage units, everyone is happy. +rep for all of ya. Not much people help to n00bs like me. I will take this trigger as STARTING example of Jass (for me).