Prevent Item From Being Dropped

[Zeatherann]

What JASS code is needed to prevent a specific item from being dropped?

function Item_Lose takes nothing returns nothing
    local unit Hero=GetTriggerUnit()
    local item Item=GetManipulatedItem()
    if(GetItemTypeId(I)=='item')then
        call Prevent_Item_From_Being_Dropped(Hero,Item)
    endif
    set Hero=null
    set Item=null
endfunction

The above function is [basically] what my event handling for dropping items is. This function is registered as a condition. There is a similar trigger for getting an item and another trigger for using an item. They are called Item_Get and Item_Use respectively. My problem is that I don't know what code to write to implement the function Prevent_Item_From_Being_Dropped. This function has to retain the original item's handle id and other data, as well as remaining in the same slot of Hero. Any ideas?

 

[deathismyfriend]

Since you get the Manipulated item (I'm guessing it is the dropped item) You can give it back to the player.
To place it back in the correct slot you would need a trigger that loops and stores what items are in what slot on the hero.

Hopefully that was what you were asking ? If not please explain a little more.

 

[Ceday]

It seems like I am saying this at least once a day.

Use 0.0 second TSA or 0.0 second timer or TriggerSyncReady().

• Untitled Trigger 002
  • Events
    • Unit - A unit Loses an item
  • Conditions
  • Actions
    • ----------- Use one of options here ---------------
    • Hero - Give (Item being manipulated) to (Hero manipulating item)

 

[DD_legionTN]

Hmm, why don't you just change the Stats - Can be dropped = false in OE?

 

[Ceday]

^^Lol ownage.

 

[Zeatherann]

I don't set that flag in the object editor because I want items to be dropped on this item. I can live with a zero second delay. Thanks Ceday. Deathismyfriend: Doing what you suggest simply creates a ghost item that has a good chance of crashing Warcraft 3. I realize that I'll have to loop over the slots (maybe).

 

[LordDz]

Is it only for this specific item, or do you want it for several items?
Because if it's just one item, then you can do what DD_Legion suggests, and have another copy of the item that is droppable.

So if your item is "Death Mask"
Then you create two copies, one droppable and one not. Then use triggers to give the heroes that is supposed to be able to drop it the one version, while giving the others the other item.

 

[Zeatherann]

I've fixed my issue. Here is the solution.

function PreventDrop_Callback takes nothing returns nothing
    local timer Callback=GetExpiredTimer()
    local integer CallbackId=GetHandleId(Callback)
    local unit Hero=LoadUnitHandle(Hash,CallbackId,0)
    local item Item=LoadItemHandle(Hash,CallbackId,1)
    local integer Slot=LoadInteger(Hash,CallbackId,0)
    call DisableTrigger(Event_ItemLose)
    call DisableTrigger(Event_ItemGet)
    call UnitAddItem(Hero,Item)
    call UnitDropItemSlot(Hero,Item,Slot)
    call EnableTrigger(Event_ItemLose)
    call EnableTrigger(Event_ItemGet)
    call DestroyTimer(Callback)
    set Callback=null
    set Hero=null
    set Item=null
    call FlushChildHashtable(Hash,CallbackId)
endfunction
function PreventDrop takes unit Hero,item Item,integer Slot returns nothing
    local timer Callback=CreateTimer()
    local integer CallbackId=GetHandleId(Callback)
    call SaveUnitHandle(Hash,CallbackId,0,Hero)
    call SaveItemHandle(Hash,CallbackId,1,Item)
    call SaveInteger(Hash,CallbackId,0,Slot)
    call TimerStart(Callback,0,false,function PreventDrop_Callback)
    set Callback=null
endfunction
function ItemLose takes nothing returns nothing
    local unit Hero=GetTriggerUnit()
    local item Item=GetManipulatedItem()
    local item TestItem=null
    local integer Slot=0
    call DisplayTextToPlayer(udg_Local,0,0,GetUnitName(Hero)+" dropped a "+GetItemName(Item)+".")
    if GetItemTypeId(Item)=='I007'then
        loop
            set TestItem=UnitItemInSlot(Hero,Slot)
            if TestItem==Item then
                call PreventDrop(Hero,Item,Slot)
                set Slot=5
            endif
            set TestItem=null
            exitwhen Slot==5
            set Slot=Slot+1
        endloop
    endif
    set Hero=null
    set Item=null
    set TestItem=null
endfunction