Order Tracking - Submission

MyPad · May 25, 2017

~~Although this has already been done, I would like to present the code with the character conversion.~~

Mission Performed: Order Tracking

Code

Description

Credits

Order Tracking Trigger (done in JASS)

JASS:

    // Prints to a certain player
    function PrintTo takes player p, string s, real dur returns nothing
        call DisplayTimedTextToPlayer(p, 0, 0, dur, s)
    endfunction
 
    // Prints to all players
    function Print takes string s returns nothing
        call PrintTo(GetLocalPlayer(), s, (StringLength(s) * 0.3 + 1.5))
    endfunction
 
    // Main Order tracking ConditionFunc
    function Order_Tracker_Actions takes nothing returns nothing
        local unit u = GetTriggerUnit()
        local eventid eventId = GetTriggerEventId()
        local integer order = GetIssuedOrderId()
        local string orderStr = OrderId2String(order)
        local player u_p = GetTriggerPlayer()
 
        local unit u_targ
        local destructable d_targ
        local item i_targ
 
        call PrintTo(u_p, "Ordered Unit: " + GetUnitName(u), 2.5)
        // legacy part...
        //call PrintTo(u_p, "unit type of Ordered Unit: " + Int2Char(GetUnitTypeId(u)), 3.)
        call PrintTo(u_p, "Owner of Ordered Unit: " + GetPlayerName(u_p), 2.5)
        call PrintTo(u_p, "Issued Order: " + orderStr, 3.5)
        call PrintTo(u_p, "Id of issued Order: " + I2S(order), 4.5)
 
        if eventId == EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER then
            call PrintTo(u_p, "Input coordinates: X(" + R2SW(GetOrderPointX(), 1, 1) + "), Y(" + R2SW(GetOrderPointY(), 1, 1) + ")", 5.5)
        elseif eventId == EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER then
            call PrintTo(u_p, "Event target is ambiguous", 4.5)
 
            set u_targ = GetOrderTargetUnit()
            set i_targ = GetOrderTargetItem()
            set d_targ = GetOrderTargetDestructable()
 
            if u_targ != null then
                call PrintTo(u_p, "Target(Unit) of Issued Order: " + GetUnitName(u_targ), 5.5)
            elseif i_targ != null then
                call PrintTo(u_p, "Target(Item) of Issued Order: " + GetItemName(i_targ), 5.5)
            elseif d_targ != null then
                call PrintTo(u_p, "Target(Destructable) of Issued Order: " + GetDestructableName(d_targ), 5.5)
            endif
 
            set u_targ = null
            set i_targ = null
            set d_targ = null
        elseif eventId == EVENT_PLAYER_UNIT_ISSUED_UNIT_ORDER then
            call PrintTo(u_p, "Event target is specific to unit only", 3.5)
            call PrintTo(u_p, "Target Unit of Issued Order: " + GetUnitName(GetOrderTargetUnit()), 3.5)
        endif
        set u_p = null
        set eventId = null
        set u = null
    endfunction

    // Activates and Deactivates the trigger.
    function Order_Tracker_Chat takes nothing returns nothing
        if GetEventPlayerChatString() == "-toggle" then
            if IsTriggerEnabled(gg_trg_Order_Tracker) then
                call DisableTrigger(gg_trg_Order_Tracker)
                call PrintTo(Player(0), "Order Id tracking is turned off", 2.)
            else
                call EnableTrigger(gg_trg_Order_Tracker)
                call PrintTo(Player(0), "Order Id tracking is turned back on!", 2.)
            endif
        else
            call ClearTextMessages()
        endif
    endfunction
 
    //===========================================================================
    function InitTrig_Order_Tracker takes nothing returns nothing
        local trigger t = CreateTrigger()
        local integer i = 0
        set gg_trg_Order_Tracker = CreateTrigger()
        loop
            exitwhen i > bj_MAX_PLAYER_SLOTS
            call TriggerRegisterPlayerUnitEvent(gg_trg_Order_Tracker, Player(i), EVENT_PLAYER_UNIT_ISSUED_ORDER, null)
            call TriggerRegisterPlayerUnitEvent(gg_trg_Order_Tracker, Player(i), EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER, null)
            call TriggerRegisterPlayerUnitEvent(gg_trg_Order_Tracker, Player(i), EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER, null)
            call TriggerRegisterPlayerUnitEvent(gg_trg_Order_Tracker, Player(i), EVENT_PLAYER_UNIT_ISSUED_UNIT_ORDER, null)
            set i = i + 1
        endloop
        // Why I use Filter instead of Condition is due to Bribe using it... (it is 3 bytes shorter)
        call TriggerAddCondition(gg_trg_Order_Tracker, Filter(function Order_Tracker_Actions))
 
        call TriggerRegisterPlayerChatEvent(t, Player(0), "-toggle", true)
        call TriggerRegisterPlayerChatEvent(t, Player(0), "-clear", true)
        call TriggerAddCondition(t, Filter(function Order_Tracker_Chat))
 
        call Print("Order tracking is enabled by default.")
        call Print("To disable it, type \"-toggle\" as your message and press enter")
        call Print("To enable it, type \"-toggle\" as done above\n")
        call Print("To clear messages, type \"-clear\".")
        set t = null
    endfunction

Order tracking is the act of tracking orders through a trigger. It has a lot of uses, from debugging, to making Phantom Rush (Phantom Lancer, DotA) possible, even to making a Nydus Canal in Warcraft 3 (to be done).

Q: Why is the Character library present?
A: Legacy Answer: {It is to show you the (Usually 7) 8-bit ASCII that represents the units, destructables, items, abilities and even orders. On another note, this one is really not necessary for the tracking of orders but it could help typecast integers into characters.}
It has been moved to the Auxiliary Tab

Q: Why did you write the Character library?
A; ..., that part is just optional... (was mandatory to me, though)

Q: Where is the order tracker?
A: It is found below the label "Order Tracking Trigger"

Thanks to Aniki for the string mapping function.

Aniki · May 26, 2017

You don't really need a library to convert integers to object ids, a simple function is just fine:

JASS:

function to_base_256 takes integer i returns string
    local string map = "................................ !\"#$%&'()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\\]^_`abcdefghijklmnopqrstuvwxyz{|}~................................................................................................................................."
    local string result = ""
    local integer t
    local integer d
    loop
        exitwhen i == 0
        set t = i / 256
        set d = i - t*256
        set result = SubString(map, d, d + 1) + result
        set i = t
    endloop
    return result
endfunction

MyPad · May 26, 2017

Woah! Thanks for the string. Is it okay if I incorporate it into the trigger set?

On another note, I was thinking how to make it more efficient.

~~Very well, I'll add a credits list and include you in it.~~

Added!

IcemanBo · May 26, 2017

MyPad said:
For the typecasting of an integer to an ASCII character:

Hm? Why you use it, it's not needed. : )

MyPad said:
Order Tracking Trigger (done in JASS)

Please attach the demo map.

MyPad · May 26, 2017

I thought that the ascii equivalent should be included.
I learned that it was really not needed.

Still keeping the library. I added a hidden tag though. ~~I will update the description too.~~

Demo Map attached!

IcemanBo · Jun 1, 2017

Don't keep the library, you don't need it, and re-read the misson; name "Barracks" should be printed for example when 'hbar' is ordered for being builded.

MyPad · Jun 2, 2017

Okay, but is it okay if I move the library to an auxiliary spot? The base code already has everything in it.

IcemanBo · Jun 2, 2017

You won't need this code at all, so I don't see sense in having it here.

MyPad · Jun 2, 2017

Placed it within notes tag...

IcemanBo · Jun 2, 2017

Read my previous critique again.

MyPad · Jun 2, 2017

I think I might and would've spammed this thread with repetitive replies, but now, I've moved the library out of the mission.

I'm going to update the map without the Character library.

IcemanBo · Jun 2, 2017

Read again. Mission - Order Tracking - Submission

Order Tracking - Submission

Code

Description

Credits

Attachments

Similar threads