[JASS] LightningEX Destroy Help

[watermelon_1234]

function Trig_Thunder_Test_Actions takes nothing returns nothing
    local lightning thunder1
    local lightning thunder2
    local real x
    local real y
    set x = GetUnitX(udg_Test)
    set y = GetUnitX(udg_Test)
    call AddLightningEx( "CLPB", true, x, y, 2000.00, x, y, 0.00 )
    set thunder1 = GetLastCreatedLightningBJ()
    call AddLightningEx( "CLSB", true, x, y, 2000.00, x, y, 0.00 )
    set thunder2 = GetLastCreatedLightningBJ()
    call AddSpecialEffectTargetUnitBJ( "origin", udg_Test, "Abilities\\Weapons\\Bolt\\BoltImpact.mdl" )
    call DestroyEffectBJ( GetLastCreatedEffectBJ() )
    call PolledWait( 1.00 )
    call DestroyLightningBJ(thunder1)
    call DestroyLightningBJ(thunder2)
endfunction

//===========================================================================
function InitTrig_Thunder_Test takes nothing returns nothing
    set gg_trg_Thunder_Test = CreateTrigger(  )
    call TriggerRegisterPlayerChatEvent( gg_trg_Thunder_Test, Player(0), "-thunder", true )
    call TriggerAddAction( gg_trg_Thunder_Test, function Trig_Thunder_Test_Actions )
endfunction

Okay, something's wrong with this, and I'm not sure what it is since I'm new to Jass. The lightning never gets destroyed, but it does get created. Does anyone what's wrong?

 

[wd40bomber7]

function DestroyLightningBJ takes lightning whichBolt returns boolean
    return DestroyLightning(whichBolt)
endfunction

Kill the middle man. Remove the BJ infront of the DestroyLightning function.


The problem is that GetLastCreatedUnitBJ()/GetLastCreatedEffectBJ()/GetLastCreatedLightningBJ() doesn't work so will [in jass] so do this:

function Trig_Thunder_Test_Actions takes nothing returns nothing
    local lightning thunder1
    local lightning thunder2
    local real x
    local real y
    set x = GetUnitX(udg_Test)
    set y = GetUnitY(udg_Test) //Fixed a bug that had both of these say GetUnitX
    set thunder1 = AddLightningEx( "CLPB", true, x, y, 2000.00, x, y, 0.00 ) //Killed another middle man(bj)
    set thunder2 = AddLightningEx( "CLSB", true, x, y, 2000.00, x, y, 0.00 )
    call DestroyEffect( AddSpecialEffectTarget( "origin", udg_Test, "Abilities\\Weapons\\Bolt\\BoltImpact.mdl" ) ) //Killed several more middle men
    call PolledWait( 1.00 )
    call DestroyLightning(thunder1)
    call DestroyLightning(thunder2)
    set thunder1 = null
    set thunder2 = null //Just a small leak fix
endfunction

//===========================================================================
function InitTrig_Thunder_Test takes nothing returns nothing
    set gg_trg_Thunder_Test = CreateTrigger(  )
    call TriggerRegisterPlayerChatEvent( gg_trg_Thunder_Test, Player(0), "-thunder", true )
    call TriggerAddAction( gg_trg_Thunder_Test, function Trig_Thunder_Test_Actions )
endfunction

 

[GhostWolf]

You could just do

   local real x = GetUnitX(udg_Test)
   local real y = GetUnitY(udg_Test)

(and yet again the JASS tags are making me nuts ! ARGGGGG)


I also read in one of the tut's you gave me that its better (didn't explain why) to declare the value of variables like that and not declare the variables and later on the value.

 

[wd40bomber7]

True it saves a few (or less) miliseconds to do it that way.

function Trig_Thunder_Test_Actions takes nothing returns nothing
    local real x = GetUnitX(udg_Test) //Fixed a bug that had both of these say GetUnitX
    local real y = GetUnitY(udg_Test) //Some more very small optimization  
    local lightning thunder1 = AddLightningEx( "CLPB", true, x, y, 2000.00, x, y, 0.00 ) //Killed another middle man(bj)
    local lightning thunder2 = AddLightningEx( "CLSB", true, x, y, 2000.00, x, y, 0.00 )
    call DestroyEffect( AddSpecialEffectTarget( "origin", udg_Test, "Abilities\\Weapons\\Bolt\\BoltImpact.mdl" ) ) //Killed several more middle men
    call PolledWait( 1.00 )
    call DestroyLightning(thunder1)
    call DestroyLightning(thunder2)
    set thunder1 = null
    set thunder2 = null //Just a small leak fix
endfunction

//===========================================================================
function InitTrig_Thunder_Test takes nothing returns nothing
    set gg_trg_Thunder_Test = CreateTrigger(  )
    call TriggerRegisterPlayerChatEvent( gg_trg_Thunder_Test, Player(0), "-thunder", true )
    call TriggerAddAction( gg_trg_Thunder_Test, function Trig_Thunder_Test_Actions )
endfunction

 

[watermelon_1234]

Thank you wd40bomber7 and GhostWolf!