[Jass]Why doesnt this work?

[Butters]

function Mensaje takes nothing  returns nothing
    if GetUnitTypeId(GetLastCreatedUnit())=='Harf' then
        call BJDebugMsg("Arthas")
    endif    
endfunction    

function Spawn_Unidad takes nothing returns nothing
    call CreateUnit(Player(0),'Harf',GetLocationX(GetRectCenter(GetPlayableMapRect())),GetLocationY(GetRectCenter(GetPlayableMapRect())),270)
    call Mensaje()
endfunction

function InitTrig_Trigger takes nothing returns nothing
    local trigger Trigger2 = CreateTrigger()
    call TriggerRegisterTimerEventPeriodic(Trigger2, 2.00)
    call TriggerAddAction(Trigger2, function Spawn_Unidad)
endfunction

its pretty simple though i cant make the message appear, and i couldnt make it work with GetUnitName

 

[Soga-]

BJDebugMsg doesn't work, I don't think. You use DisplayTextToForce or DisplayTextToPlayer.

 

[Butters]

i dont think thats the problem, because if i modify it this way

function Mensaje takes nothing  returns nothing
    if GetUnitTypeId(GetLastCreatedUnit())=='Harf' then
        call BJDebugMsg("Arthas")
    else
        call BJDebugMsg("Something")
    endif    
endfunction

it shows the msj "Something"

 

[Ciebron]

BJDebug message works.

to the problem

i dont think call CreateUnit sets a GetLastCreatedUnit() (which is bj_lastCreatedUnit)

can't try it now, im at a friend's place

Edit:

ok installed wc3 on hes comp. and yes it was as i tought u can how ever fix this

function Mensaje takes unit u returns nothing
    if GetUnitTypeId(u)=='Harf' then
        call BJDebugMsg("Arthas")
    endif    
endfunction    

function Spawn_Unidad takes nothing returns nothing
    local unit u = CreateUnit(Player(0),'Harf',GetLocationX(GetRectCenter(GetPlayableMapRect())),GetLocationY(GetRectCenter(GetPlayableMapRect())),270)
    call Mensaje(u)
    set u = null
endfunction

this will do it for you

 

[Eleandor]

Ciebron is right: GetLastCreatedUnit() basically returns a global variable: bj_lastCreatedUnit.

bj_lastCreatedUnit is only set when using CreateUnit BJ's. The CreateUnit function you're using is a native and does not set bj_lastCreatedUnit to the actual last created unit.

 

[Butters]

thanks a lot, i still have a lot to learn

 

[Butters]

ok another problem

function FootmanMuere takes nothing returns boolean
    return IsUnitDeadBJ(bj_lastCreatedUnit)
endfunction

function Footman takes nothing returns nothing
    local integer FootmanInteger = 1
    call DisableTrigger(gg_trg_Comienzo)
    loop
    exitwhen FootmanInteger==10
        call CreateUnitAtLoc(Player(1),'hfoo',Location(-1799.4,755.4),270)
        loop 
        exitwhen FootmanMuere()==true
        call TriggerSleepAction(1)
        endloop
        set FootmanInteger = FootmanInteger+1
    endloop
    
endfunction

function InitTrig_Comienzo takes nothing returns nothing
    set gg_trg_Comienzo = CreateTrigger()
    call TriggerRegisterPlayerChatEvent(gg_trg_Comienzo,Player(0),"Empezar",true)
    call TriggerAddAction(gg_trg_Comienzo,function Footman)
endfunction

when i type "Empezar" 10 footmans spawn, while i want only 1 footman to spawn, and when that footman dies, another one should be created

 

[Eleandor]

If you're so fond on using bj_lastCreatedUnit, then you can still avoid using CreateUnitAtLoc...

replace

        call CreateUnitAtLoc(Player(1),'hfoo',Location(-1799.4,755.4),270)

by

        set bj_lastCreatedUnit = CreateUnit(Player(0),'hfoo',-1799.4,755.4,270) // not sure if this is correct, but something like that anyway

Besides, the FootmanMuere function is utterly useless.

You can simply replace

        exitwhen FootmanMuere()==true

with

        exitwhen (GetUnitState(bj_lastCreatedUnit, UNIT_STATE_LIFE) <= 0.0)
        // basically check if life of last created unit is ... well... 0...

I also think CreateUnitAtLoc doesn't use bj_lastCreatedUnit either. It probably has to be CreateUnitAtLocBJ. But as I said, just use "CreateUnit" and set a unit variable as the result of that function call.

An example script would look like this:

function Footman takes nothing returns nothing
    local integer FootmanInteger = 1
    local unit footman
    call DisableTrigger(gg_trg_Comienzo)
    loop
    exitwhen FootmanInteger==10
        set footman = CreateUnit(Player(0),'hfoo',-1799.4,755.4,270)
        loop
            exitwhen (GetUnitState(footman, UNIT_STATE_LIFE) <= 0.0)
            call TriggerSleepAction(1.0)
        endloop
        set FootmanInteger = FootmanInteger+1
    endloop
    set footman = null
endfunction

function InitTrig_Comienzo takes nothing returns nothing
    set gg_trg_Comienzo = CreateTrigger()
    call TriggerRegisterPlayerChatEvent(gg_trg_Comienzo,Player(0),"Empezar",true)
    call TriggerAddAction(gg_trg_Comienzo,function Footman)
endfunction

 

[GhostWolf]

What exactly is a problem here? You made a loop that will loop from 1 to 10 and create footmans.
I'm not sure why the nested loop doesn't stop the spawning, probably because of the wait, but anyhow - when a unit dies you tell the main loop to continue and create footmans.

Please, at least look at your freaking code and think how to write whatever you want... writing a mish-mesh and coming here with every stupid question won't make you smarter.