1. Are you planning to upload your awesome spell or system to Hive? Please review the rules here.
    Dismiss Notice
  2. The Melee Mapping Contest #4: 2v2 - Results are out! Step by to congratulate the winners!
    Dismiss Notice
  3. We're hosting the 15th Mini-Mapping Contest with YouTuber Abelhawk! The contestants are to create a custom map that uses the hidden content within Warcraft 3 or is inspired by any of the many secrets within the game.
    Dismiss Notice
  4. The 20th iteration of the Terraining Contest is upon us! Join and create exquisite Water Structures for it.
    Dismiss Notice
  5. Check out the Staff job openings thread.
    Dismiss Notice

GUI-Friendly Damage Detection v1.2.1

Submitted by Weep
This bundle is marked as approved. It works and satisfies the submission rules.
GUI-Friendly Damage Detection
by Weep
Version 1.2.1

-- General Information --
This system provides a leak-free, GUI-friendly implementation of an "any unit takes damage" event. It requires no JASS knowledge to use, nor any other systems, nor any software other than the World Editor. It will not interfere with other systems, either.

It uses the Game - Value Of Real Variable event as its method of activating other triggers, and passes the event responses through a few globals.

Before you copy triggers that use GDD into a new map, you need to copy over GDD with its GDD Variable Creator trigger, or the variables won't be automatically created correctly.
If you need to fix things:
If you pasted GDD-using triggers before pasting GDD, to fix it, change the type of the variable GDD_Event to be a Real in the Trigger Editor's Variables window, and then find the triggers that became disabled and change their event to use the variable GDD_Event.


-- How To Implement --
  1. Be sure "Automatically create unknown variables while pasting trigger data" is enabled in the World Editor general preferences.
  2. Copy the trigger category "GDD" from the demo map and paste it into your map. (Alternately: create the variables listed in the globals block below, create a trigger named GUI Friendly Damage Detection", and paste in this entire text.)
  3. Create your damage triggers using Game - Value Of Real Variable, select GDD_Event as the variable, and leave the rest of the settings to the default "becomes Equal to 0.00".
The event responses are the following variables:
  • GDD_Damage is the amount of damage, replacing Event Response - Damage Taken.
  • GDD_DamagedUnit is the damaged unit, replacing Event Response - Triggering Unit.
    • However, Triggering Unit can still be used, if you need to use waits. Read the Notes section below for more info.
  • GDD_DamageSource is the damaging unit, replacing Event Response - Damage Source.

-- Example Usage --
Displaying damage:
  • Display Damage
    • Events
      • Game - GDD_Event becomes Equal to 0.00
    • Conditions
    • Actions
      • Game - Display to (All players) for 1.00 seconds the text: ((((Name of GDD_DamageSource) + damaged ) + (Name of GDD_DamagedUnit)) + ( for + ((String(GDD_Damage)) + damage.)))


-- System Code --
Expand to read:
Code (vJASS):
// GUI-Friendly Damage Detection -- v1.2.1 -- by Weep
//    http://www.thehelper.net/forums/showthread.php?t=137957
//
//    Requires: only this trigger and its variables.
//
// -- What? --
//    This system provides a leak-free, GUI-friendly implementation of an "any unit takes
//    damage" event.  It requires no JASS knowledge to use.
//
//    It uses the Game - Value Of Real Variable event as its method of activating other
//    triggers, and passes the event responses through a few globals.
//
// -- Why? --
//    The traditional GUI method of setting up a trigger than runs when any unit is damaged
//    leaks trigger events.  This system is easy to implement and removes the need to do
//    you own GUI damage detection setup.
//
// -- How To Implement --
//    0. Before you copy triggers that use GDD into a new map, you need to copy over GDD
//       with its GDD Variable Creator trigger, or there will be a problem: the variables
//       won't be automatically created correctly.
//
//    1. Be sure "Automatically create unknown variables while pasting trigger data" is
//       enabled in the World Editor general preferences.
//    2. Copy this trigger category ("GDD") and paste it into your map.
//       (Alternately: create the variables listed in the globals block below, create a
//       trigger named "GUI Friendly Damage Detection", and paste in this entire text.)
//    3. Create your damage triggers using Game - Value Of Real Variable as the event,
//       select GDD_Event as the variable, and leave the rest of the settings to the default
//       "becomes Equal to 0.00".
//       The event responses are the following variables:
//          GDD_Damage is the amount of damage, replacing Event Response - Damage Taken.
//          GDD_DamagedUnit is the damaged unit, replacing Event Response - Triggering Unit.
//              Triggering Unit may still be used, if you need to use waits.
//              Read the -- Notes -- section below for more info.
//          GDD_DamageSource is the damaging unit, replacing Event Response - Damage Source.
//
// -- Notes --
//    GDD's event response variables are not wait-safe; you can't use them after a wait in
//    a trigger.  If you need to use waits, Triggering Unit (a.k.a. GetTriggerUnit()) can
//    be used in place of GDD_DamageSource.  There is no usable wait-safe equivalent to
//    Event Damage or Damage Source; you'll need to save the values yourself.
//
//    Don't write any values to the variables used as the event responses, or it will mess
//    up any other triggers using this system for their triggering.  Only use their values.
//
//    This uses arrays, so can detect damage for a maximum of 8190 units at a time, and
//    cleans up data at a rate of 33.33 per second, by default.  This should be enough for
//    most maps, but if you want to change the rate, change the value returned in the
//    GDD_RecycleRate function at the top of the code, below.
//
//    By default, GDD will not register units that have Locust at the moment of their
//    entering the game, and will not recognize when they take damage (which can only
//    happen if the Locust ability is later removed from the unit.)  To allow a unit to have
//    Locust yet still cause GDD damage events if Locust is removed, you can either design
//    the unit to not have Locust by default and add it via triggers after creation, or
//    edit the GDD_Filter function at the top of the code, below.
//
// -- Credits --
//    Captain Griffin on triggerc.net for the research and concept of GroupRefresh.
//
//    Credit in your map not needed, but please include this README.
//
// -- Version History --
//    1.2.1: Minor code cleaning.  Added configuration functions.  Updated documentation.
//    1.2.0: Made this system work properly with recursive damage.
//    1.1.1: Added a check in order to not index units with the Locust ability (dummy units).
//           If you wish to check for damage taken by a unit that is unselectable, do not
//           give the unit-type Locust in the object editor; instead, add the Locust ability
//           'Aloc' via a trigger after its creation, then remove it.
//    1.1.0: Added a check in case a unit gets moved out of the map and back.
//    1.0.0: First release.


//===================================================================
// Configurables.
function GDD_RecycleRate takes nothing returns real //The rate at which the system checks units to see if they've been removed from the game
    return 0.03
endfunction

function GDD_Filter takes unit u returns boolean //The condition a unit has to pass to have it registered for damage detection
    return GetUnitAbilityLevel(u, 'Aloc') == 0 //By default, the system ignores Locust units, because they normally can't take damage anyway
endfunction

//===================================================================
// This is just for reference.
// If you use JassHelper, you could uncomment this section instead of creating the variables in the trigger editor.

// globals
//  real udg_GDD_Event = 0.
//  real udg_GDD_Damage = 0.
//  unit udg_GDD_DamagedUnit
//  unit udg_GDD_DamageSource
//  trigger array udg_GDD__TriggerArray
//  integer array udg_GDD__Integers
//  unit array udg_GDD__UnitArray
//  group udg_GDD__LeftMapGroup = CreateGroup()
// endglobals

//===================================================================
// System code follows.  Don't touch!
function GDD_Event takes nothing returns boolean
    local unit damagedcache = udg_GDD_DamagedUnit
    local unit damagingcache = udg_GDD_DamageSource
    local real damagecache = udg_GDD_Damage
    set udg_GDD_DamagedUnit = GetTriggerUnit()
    set udg_GDD_DamageSource = GetEventDamageSource()
    set udg_GDD_Damage = GetEventDamage()
    set udg_GDD_Event = 1.
    set udg_GDD_Event = 0.
    set udg_GDD_DamagedUnit = damagedcache
    set udg_GDD_DamageSource = damagingcache
    set udg_GDD_Damage = damagecache
    set damagedcache = null
    set damagingcache = null
    return false
endfunction

function GDD_AddDetection takes nothing returns boolean
//  if(udg_GDD__Integers[0] > 8190) then
//      call BJDebugMsg("GDD: Too many damage events!  Decrease number of units present in the map or increase recycle rate.")
//      ***Recycle rate is specified in the GDD_RecycleRate function at the top of the code.  Smaller is faster.***
//      return
//  endif
    if(IsUnitInGroup(GetFilterUnit(), udg_GDD__LeftMapGroup)) then
        call GroupRemoveUnit(udg_GDD__LeftMapGroup, GetFilterUnit())
    elseif(GDD_Filter(GetFilterUnit())) then
        set udg_GDD__Integers[0] = udg_GDD__Integers[0]+1
        set udg_GDD__UnitArray[udg_GDD__Integers[0]] = GetFilterUnit()
        set udg_GDD__TriggerArray[udg_GDD__Integers[0]] = CreateTrigger()
        call TriggerRegisterUnitEvent(udg_GDD__TriggerArray[udg_GDD__Integers[0]], udg_GDD__UnitArray[udg_GDD__Integers[0]], EVENT_UNIT_DAMAGED)
        call TriggerAddCondition(udg_GDD__TriggerArray[udg_GDD__Integers[0]], Condition(function GDD_Event))
    endif
    return false
endfunction

function GDD_PreplacedDetection takes nothing returns nothing
    local group g = CreateGroup()
    local integer i = 0
    loop
        call GroupEnumUnitsOfPlayer(g, Player(i), Condition(function GDD_AddDetection))
        set i = i+1
        exitwhen i == bj_MAX_PLAYER_SLOTS
    endloop
    call DestroyGroup(g)
    set g = null
endfunction

function GDD_GroupRefresh takes nothing returns nothing
// Based on GroupRefresh by Captain Griffen on triggerc.net
    if (bj_slotControlUsed[5063] == true) then
        call GroupClear(udg_GDD__LeftMapGroup)
        set bj_slotControlUsed[5063] = false
    endif
    call GroupAddUnit(udg_GDD__LeftMapGroup, GetEnumUnit())
endfunction

function GDD_Recycle takes nothing returns nothing
    if(udg_GDD__Integers[0] <= 0) then
        return
    elseif(udg_GDD__Integers[1] <= 0) then
        set udg_GDD__Integers[1] = udg_GDD__Integers[0]
    endif
    if(GetUnitTypeId(udg_GDD__UnitArray[udg_GDD__Integers[1]]) == 0) then
        call DestroyTrigger(udg_GDD__TriggerArray[udg_GDD__Integers[1]])
        set udg_GDD__TriggerArray[udg_GDD__Integers[1]] = null
        set udg_GDD__TriggerArray[udg_GDD__Integers[1]] = udg_GDD__TriggerArray[udg_GDD__Integers[0]]
        set udg_GDD__UnitArray[udg_GDD__Integers[1]] = udg_GDD__UnitArray[udg_GDD__Integers[0]]
        set udg_GDD__UnitArray[udg_GDD__Integers[0]] = null
        set udg_GDD__Integers[0] = udg_GDD__Integers[0]-1
    endif
    set udg_GDD__Integers[1] = udg_GDD__Integers[1]-1
endfunction

function GDD_LeaveMap takes nothing returns boolean
    local boolean cached = bj_slotControlUsed[5063]
    if(udg_GDD__Integers[2] < 64) then
        set udg_GDD__Integers[2] = udg_GDD__Integers[2]+1
    else
        set bj_slotControlUsed[5063] = true
        call ForGroup(udg_GDD__LeftMapGroup, function GDD_GroupRefresh)
        set udg_GDD__Integers[2] = 0
    endif
    call GroupAddUnit(udg_GDD__LeftMapGroup, GetFilterUnit())
    set bj_slotControlUsed[5063] = cached
    return false
endfunction

// ===========================================================================
function InitTrig_GUI_Friendly_Damage_Detection takes nothing returns nothing
    local region r = CreateRegion()
    call RegionAddRect(r, GetWorldBounds())
    call TriggerRegisterEnterRegion(CreateTrigger(), r, Condition(function GDD_AddDetection))
    call TriggerRegisterLeaveRegion(CreateTrigger(), r, Condition(function GDD_LeaveMap))
    call GDD_PreplacedDetection()
    call TimerStart(CreateTimer(), GDD_RecycleRate(), true, function GDD_Recycle)
    set r = null
endfunction


-- Notes --
GDD's event response variables are not wait-safe; you can't use them after a wait in a trigger. If you need to use waits, Triggering Unit (a.k.a. GetTriggerUnit()) can be used in place of GDD_DamageSource. There is no usable wait-safe equivalent to GDD_Damage or GDD_DamageSource; you'll need to save the values yourself.

A common problem when using any damage detection system occurs when you try to cause the damage source to damage the damaged unit from a damage event - for example, if triggering bonus damage. This causes the unit to repeatedly damage the target, because dealing damage in the trigger causes that trigger to run again, and again in turn, infinitely. One solution is to add the action Turn off (This trigger) before dealing damage and add the action Turn on (This trigger) afterward.

Don't write any values to the variables used as the event responses, or it will mess up any other triggers using this system for their triggering. Only use their values.

This uses arrays, so can detect damage for a maximum of 8190 units at a time, and cleans up data at a rate of 33.33 per second, by default. This should be enough for most maps, but if you want to change the rate, change the value returned in the GDD_RecycleRate function at the top of the code.

By default, GDD will not register units that have Locust at the moment of their entering the game, and will not recognize when they take damage (which can only happen if the Locust ability is later removed from the unit.) To allow a unit to have Locust yet still cause GDD damage events if Locust is removed, you can either design the unit to not have Locust by default and add it via triggers after creation, or edit the GDD_Filter function at the top of the code.

-- Credits --
Captain Griffin on triggerc.net for the research and concept of GroupRefresh.

Credit in your map not needed, but please include the README.

-- Version History --
Expand to read:
1.2.1: Minor code cleaning. Added configuration functions. Updated documentation.
1.2.0: Made this system work properly with recursive damage.
1.1.1: Added a check in order to not index units with the Locust ability (dummy units). If you wish to check for damage taken by a unit that is unselectable, do not give the unit-type Locust in the object editor; instead, add the Locust ability 'Aloc' via a trigger after its creation, then remove it.
1.1.0: Added a check in case a unit gets moved out of the map and back.
1.0.0: First release.


Keywords:
gui, friendly, damage, detection, detect
Contents

GUI-Friendly Damage Detection (Map)

Reviews
Moderator
17:29, 16th Jan 2010 TriggerHappy: Very easy to use for GUI users and a fairly unique implementation.
  1. 17:29, 16th Jan 2010
    TriggerHappy:

    Very easy to use for GUI users and a fairly unique implementation.
     
  2. Anachron

    Anachron

    Joined:
    Sep 9, 2007
    Messages:
    6,167
    Resources:
    66
    Icons:
    49
    Packs:
    2
    Tools:
    1
    Maps:
    3
    Spells:
    9
    Tutorials:
    1
    JASS:
    1
    Resources:
    66
    So this creates a trigger for ever unit entering the map?
    You could use hashtables and such to make it full MUI (endless indexing).

    Anway, pretty cool I must say. There are a plenty of other DD systems around but yours is so far I can see one of the most GUI friendly ones. But that also decreases functionality.

    So for easy stuff, this is good enough.
     
  3. baassee

    baassee

    Joined:
    Nov 14, 2008
    Messages:
    3,220
    Resources:
    17
    Spells:
    14
    Tutorials:
    3
    Resources:
    17
    I guess you used reals and the golems dont damage 21k damage. Get rid of the 000 by converting to integer
     
  4. Weep

    Weep

    Joined:
    Jul 12, 2009
    Messages:
    316
    Resources:
    3
    Models:
    2
    Spells:
    1
    Resources:
    3
    Yes. This allows the triggers' subsequent removal, in contrast to the traditional GUI technique of setting up damage detection, where you simply keep adding on damage events to one trigger which cannot be cleared in a practical fashion, causing an (admittedly minor) leak.

    I could, but I wanted this to be as compatible as possible. It'll work pre-1.24, and more importantly, because it doesn't require any 1.24 features nor any compiler other than the WE default, it can be used in any platform's World Editor.

    Yes, and it'll also co-exist happily with any other system. Flexibility and compatibility were among my main goals. Also, it takes care of double-registration protection (if a unit exits and re-enters the map) for you, and handles recursive damage.

    That's not part of the system, just part of the quick demonstration of how to use it. It's unimportant.
     
  5. Slaydon

    Slaydon

    Joined:
    Jan 6, 2008
    Messages:
    2,432
    Resources:
    2
    Tutorials:
    2
    Resources:
    2
    I lmao'd at the pic, then i saw everything else, looks very interesting, could be very usefull for a feature in my map
     
  6. reason 3

    reason 3

    Joined:
    Aug 11, 2009
    Messages:
    1,549
    Resources:
    2
    Maps:
    1
    Spells:
    1
    Resources:
    2
    Nice sys,for the majority of users which use GUI.
     
  7. hell gate

    hell gate

    Joined:
    Nov 23, 2008
    Messages:
    477
    Resources:
    10
    Models:
    1
    Spells:
    9
    Resources:
    10
    you really should use vJass
     
  8. Teldrassil

    Teldrassil

    Joined:
    Feb 7, 2005
    Messages:
    402
    Resources:
    6
    Maps:
    6
    Resources:
    6
    Why?

    JNGP has a lot of problems with patch 1.24, for example if you use it you won't be able to use GUI Hashtables. Which means if you only want one of these VJass systems you'll need to make anything requiring a hashtable VJass as well.

    Also, the name of this system specifically states "GUI-Friendly" and if it used VJass it'd destroy some GUI functions, like I just stated, and that's not very friendly.

    -Teld
     
  9. Arnadath

    Arnadath

    Joined:
    Oct 31, 2008
    Messages:
    227
    Resources:
    0
    Resources:
    0
    Very good system (despite there are 8 like this)
    GUI friendly yes. But i suspect it is converted in JASS. Youd better learn normal jass
     
  10. Element of Water

    Element of Water

    Joined:
    Aug 3, 2008
    Messages:
    2,298
    Resources:
    5
    Spells:
    3
    Tutorials:
    1
    JASS:
    1
    Resources:
    5
    You're trying to say this is converted GUI? For your information, no, it most certainly is not converted GUI in any way.
     
  11. StaberFire

    StaberFire

    Joined:
    Jun 28, 2008
    Messages:
    683
    Resources:
    8
    Icons:
    4
    Skins:
    1
    Spells:
    3
    Resources:
    8
    Fan-freaking-tastic. If I ever attain the motivation to make a whole map, this will be the first place I go. I could never find a good, user-friendly DDS as a GUI-user before. That's some well-deserved rep my friend.
     
  12. cHeRoL

    cHeRoL

    Joined:
    Mar 30, 2008
    Messages:
    655
    Resources:
    2
    Spells:
    2
    Resources:
    2
    You should use Floating Texts instead of Game - Display to all.
    And the texts to be shown above damage delear's head.
     
  13. Arnadath

    Arnadath

    Joined:
    Oct 31, 2008
    Messages:
    227
    Resources:
    0
    Resources:
    0
    as i see, you might be right, it uses locals
    yes
     
  14. Weep

    Weep

    Joined:
    Jul 12, 2009
    Messages:
    316
    Resources:
    3
    Models:
    2
    Spells:
    1
    Resources:
    3
    I hadn't found any that are intended for easy use with GUI. Have any links?

    Again it seems I'm betrayed by my screenshot, because you've completely missed the purpose of this...

    The text is not part of this system! It is only there as a demonstration of its use. The underlying code is meant to be a system used for other purposes, whether it is displaying damage in-game or building triggered spells. I suppose the first sentence of the resource description wasn't clear enough, either. :facepalm:
     
  15. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    I have a question, how bad is the RegisterEvent leak? btw, can this be used to make a custom damage system?
     
  16. Weep

    Weep

    Joined:
    Jul 12, 2009
    Messages:
    316
    Resources:
    3
    Models:
    2
    Spells:
    1
    Resources:
    3
    Are you talking about the event leak incurred via the traditional way of setting up damage detection in the GUI? Unsure - estimates seem to vary between negligible, and ~400 bytes... Still, it's the principle of it - avoiding leaks when possible - plus this centralizes damage detection rather than registering events repeatedly for every spell that uses damage detection.

    I suppose so.
     
  17. Adiktuz

    Adiktuz

    Joined:
    Oct 16, 2008
    Messages:
    9,674
    Resources:
    23
    Models:
    2
    Packs:
    1
    Maps:
    1
    Spells:
    16
    Tutorials:
    1
    JASS:
    2
    Resources:
    23
    oh.. okay, thanks!

    look at this, If I add a Unit- Take Damage event for every unit in a map and then you can transfer to other maps(it is a campaign) and then it registers again the event for each unit every time you enter a map will it still be negligible?
     
  18. Weep

    Weep

    Joined:
    Jul 12, 2009
    Messages:
    316
    Resources:
    3
    Models:
    2
    Spells:
    1
    Resources:
    3
    I'm not familiar with how campaigns are set up, but I'd be surprised if it was any different than for a single map.
     
  19. Anachron

    Anachron

    Joined:
    Sep 9, 2007
    Messages:
    6,167
    Resources:
    66
    Icons:
    49
    Packs:
    2
    Tools:
    1
    Maps:
    3
    Spells:
    9
    Tutorials:
    1
    JASS:
    1
    Resources:
    66
    A small map has at least 1000 units in a game, that would make 390kb leaks.
    An bigger one, such as an TD, can easily reach up to 10.000 Units, which would be 3,9mb leaks. And that for every library that uses the RegisterDamageEvent method.