GetUnitLoc

[defskull]

Does using GetUnitLoc leaks ?

Example:

set x = GetLocationX(GetUnitLoc(GetTriggerUnit()))
set y = GetLocationY(GetUnitLoc(GetTriggerUnit()))

 

[mckill2009]

GetUnitLoc returns a location handle, so yeah it leaks...
same as call CreateNUnitsAtLoc( 1, 'hfoo', Player(0), GetUnitLoc(GetTriggerUnit()), bj_UNIT_FACING )

 

[ap0calypse]

Perhaps you could use

set x = GetUnitX( GetTriggerUnit() )

instead?
Then you don't need to deal with a location at all.

 

[defskull]

I'm dealing with GetLocationZ to acknowledge terrain's current height
Unfortunately there is no such thing as GetUnitZ.

So I have to GetLocationZ(whichLocation)

 

[mckill2009]

function GetZ takes location loc, real x, real y returns real
    call MoveLocation(loc,x,y)
    return GetLocationZ(loc)
endfunction

EDIT:

OR

function GetUnitZ takes location loc, unit u returns real
    call MoveLocation(loc, GetUnitX(u), GetUnitY(u)) 
    return GetLocationZ(loc)
endfunction

 

[PurgeandFire]

You can alternatively use this:
http://wc3jass.com/4981/snippet-getz/msg38689/topicseen/#new

library GetZ /* v1.0.0.0
*******************************************************************
*
*   This script will provide an interface to retrieve Z-values
*   of points and units without requiring you to deal with
*   locations.
*
*******************************************************************
*
*   function GetPointZ takes real x, real y returns real
*
*      -  Returns the Z-value of a particular point on the terrain.
*
*   function GetUnitZ takes unit u returns real
*
*      -  Returns the Z-value of a unit.
*      -  This will take both terrain height and fly height into
*         account.
*
*******************************************************************/

    globals
        private location loc = Location(0, 0)
    endglobals

    function GetPointZ takes real x, real y returns real
	    call MoveLocation(loc, x, y)
	    return GetLocationZ(loc)
    endfunction

    function GetUnitZ takes unit u returns real
	    call MoveLocation(loc, GetUnitX(u), GetUnitY(u))
	    return GetLocationZ(loc) + GetUnitFlyHeight(u)
    endfunction

endlibrary

@mckill: You have to account for the unit's flying height as well as the location z.