Explosions

Moderator · Dec 30, 2011

12th Dec 2015
IcemanBo: Too long as NeedsFix. Rejected.

06:59, 23rd Jul 2012
Magtheridon96:

Use static ifs to evaluate the constant booleans on compile time.
You need some documentation for the spell.
Using a tree destruction system is totally not worth it.
Check out my spell code.
I'm using a static rect. What I do first is set the rect's bounds, then store the distance
squared into a variable (because I want to pick destructables in a circle, not a square),
then I enumerate over the destructables in the rect. The isTree function I wrote is the most
efficient and compact method ever to detect a tree. (Using a hashtable along with type registry
is the fastest yet least compact methods). I'm taking advantage of how JASS "shortcircuits" boolean
expressions with this function. If the first part returns false, the next won't even run, and the
function would immediately return false. I'm checking if the distance between the destructable and
the center is less than or equal to the radius and if the destructable is tree before I kill it.
It's simple tree detection.
You can totally copy the code if you want.
The global group "TempGroup" should be camelCased. (tempGroup)
Constant functions are the same as normal functions. Remove the 'constant' keyword and you'll save 9 bytes of file size.
(Including the space that you have to include in between constant and one of the words next to it)
Your GetTargetType function can simply return the boolean expression you have in the if block.
(return not IsUnitType(target, UNIT_TYPE_DEAD) and not ...)
Since the caster isn't going to be moving anywhere while your function is executing, it would be better to
cache his coordinates OUTSIDE the loop so you don't have to repeat the call over and over again.
You should probably do the same for the Sin and Cos of his facing.
Cos(GetRandomReal(0, 360) * bj_DEGTORAD) is exactly the same as GetRandomReal(-1,1)
It would be recommended to store the random generated reals so you can use the same ones
when setting the variables x and y inside the loop. (Store GetRandomReal(-1,1) and use that variable,
and do the same for GetRandomReal(0, aoe)).
It wouldn't make a very huge difference, but it just seems better.
You should probably also cache the triggering player outside the loop since he will be constant
for every iteration you make.
You have one useless local unit variable in your Actions function. (local unit du)
It would be better if you add comments and line breaks inside your code to make things a bit
more readable.

xIceShotx · Dec 30, 2011

This doesn't even work properly ;o, If each person castes it, it orders all the units the casted the ability to recast it again ._.
-Translated to Spanish:-
Esto ni siquiera funciona bien ;o, si cada persona que las castas, que ordena todas las unidades del fundido la posibilidad de que la refundición de nuevo ._.

mateuspv · Dec 30, 2011

1 - You need an image of the game, I did this if you want to use:

2 - Bjs you have many, try to transform them into native

simple examples given here

JASS:

function C takes nothing returns boolean
    return GetSpellAbilityId() == 'A000'
endfunction

JASS:

local integer l     = GetUnitAbilityLevelSwapped('A000', c)
// >>>
local integer l     = GetUnitAbilityLevel(c, 'A000')

JASS:

function InitTrig_Explosions takes nothing returns nothing
    local trigger E = CreateTrigger(  )
    call TriggerRegisterAnyUnitEventBJ( E, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( E, Condition( function C ) )
    call TriggerAddAction( E, function A )
    set E = null
endfunction

instead of calling and destroy an effect you can call like this:
call DestroyEffect(AddSpecialEffectLoc(modelName, where))

GetRandomDirectionDeg
>>>
GetRandomReal(0, 360)

you need to improve their filters, BJ's in native,take a look at the forum, is not very dificel.

Jay the Editor · Dec 31, 2011

To mateuspv: You're such a kind fellow lol .. creating an image out of no one ask for it >< Btw, do you use photoshop to create those words? It's very nice!

Ruke · Dec 31, 2011

JASS:

function DamageSfx takes nothing returns string
    return "Abilities\\Weapons\\BoatMissile\\BoatMissile.mdl"
endfunction

function ExplosionsSfx takes nothing returns string
    return "abilities\\weapons\\catapult\\catapultmissile.mdl"
endfunction

function ExplosionsRawcode takes nothing returns integer
    return 'A000'
endfunction

function Run takes nothing returns boolean
    local unit caster
    local integer level
    local integer i = 0
    local integer explosions
    local real damage
    local real aoe
    local real x
    local real y
    local unit j

    if GetSpellAbilityId() == ExplosionsRawcode() then
        set caster = GetTriggerUnit()
        set level = GetUnitAbilityLevel(caster, ExplosionsRawcode())
        set explosions = 2 * level
        set damage = 10.00 + 10.00 * level
        set aoe = 225.
        
        loop
            exitwhen i > explosions
            
            set x = (GetUnitX(caster) + aoe / 1.25 * Cos(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Cos(GetRandomReal(0, 360) * bj_DEGTORAD)
            set y = (GetUnitY(caster) + aoe / 1.25 * Sin(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Sin(GetRandomReal(0, 360) * bj_DEGTORAD)
            
            call DestroyEffect(AddSpecialEffect(ExplosionsSfx(), x, y))
            
            call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, aoe, null)
            
            loop
                set j = FirstOfGroup(bj_lastCreatedGroup)
                exitwhen j == null
                call GroupRemoveUnit(bj_lastCreatedGroup, j)
                
                if IsUnitEnemy(j, GetTriggerPlayer()) then
                    call UnitDamageTarget(caster, j, damage, false, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, null)
                    call DestroyEffect(AddSpecialEffect(DamageSfx(), GetUnitX(j), GetUnitY(j)))
                endif
            endloop
            
            set i = i + 1
        endloop
        
        set caster = null
    endif
    
    return false
endfunction

function InitTrig_Explosions1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t, Condition(function Run))
endfunction

Español:

No uses BJs (la mayoría son innecesarias).
No uses location, usa coordenadas.
Cuando creas variables, ponele nombres más descriptivos (así se hace mas fácil leerlos inclusive para vos).
Fijate como trabajo con los grupos (por ahora es la manera mas eficiente/rápida de trabajar con ellos).

bj_lastCreatedGroup: Usa este grupo cuando vallas a hacer únicamente enumeraciones de unidades (como en este caso, que lo único que tenes que hacer es agarrar las unidades y hacerles daño, nada mas).

Ponele nombres más descriptivos a tus funciones.

¿Viste las funciones ExplosionsRawcode, ExplosionsSfx y DamageSfx?, las hice para que el usuario pueda configurar fácilmente la habilidad (en este caso podemos modificar sin ningún problema los efectos y el RAWCODE del spell).

English:

Don't use BJs (mostly are unnecessary).
Don't use location, use cordinates instead.
When you create variables, put descriptive names to them (makes easy read the code).
Look how I work with groups (for now, this is the best way).

bj_lastCreatedGroup: Use this group when you only need a group for enumerate units.

Put descriptive names to your functions.

Do you see the ExplosionsRawcode, ExplosionsSfx and DamageSfx functions?, I make them to make easy the job to the user (for configurate things).

Greetings/Saludos.

EDIT: Solamente trabajo en el bloque de condiciones porque éste se ejecuta primero que las acciones, por ende es más rápido. / I only work in the condition block because it executes first than the actions, so this way is more faster.

KhaosMachine · Dec 31, 2011

Ruke said:
JASS:

function DamageSfx takes nothing returns string return "Abilities\\Weapons\\BoatMissile\\BoatMissile.mdl" endfunction function ExplosionsSfx takes nothing returns string return "abilities\\weapons\\catapult\\catapultmissile.mdl" endfunction function ExplosionsRawcode takes nothing returns integer return 'A000' endfunction function Run takes nothing returns boolean local unit caster local integer level local integer i = 0 local integer explosions local real damage local real aoe local real x local real y local unit j if GetSpellAbilityId() == ExplosionsRawcode() then set caster = GetTriggerUnit() set level = GetUnitAbilityLevel(caster, ExplosionsRawcode()) set explosions = 2 * level set damage = 10.00 + 10.00 * level set aoe = 225. loop exitwhen i > explosions set x = (GetUnitX(caster) + aoe / 1.25 * Cos(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Cos(GetRandomReal(0, 360) * bj_DEGTORAD) set y = (GetUnitY(caster) + aoe / 1.25 * Sin(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Sin(GetRandomReal(0, 360) * bj_DEGTORAD) call DestroyEffect(AddSpecialEffect(ExplosionsSfx(), x, y)) call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, aoe, null) loop set j = FirstOfGroup(bj_lastCreatedGroup) exitwhen j == null call GroupRemoveUnit(bj_lastCreatedGroup, j) if IsUnitEnemy(j, GetTriggerPlayer()) then call UnitDamageTarget(caster, j, damage, false, false, ATTACK_TYPE_NORMAL, DAMAGE_TYPE_NORMAL, null) call DestroyEffect(AddSpecialEffect(DamageSfx(), GetUnitX(j), GetUnitY(j))) endif endloop set i = i + 1 endloop set caster = null endif return false endfunction function InitTrig_Explosions1 takes nothing returns nothing local trigger t = CreateTrigger() call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT) call TriggerAddCondition(t, Condition(function Run)) endfunction

Español:

No uses BJs (la mayoría son innecesarias).
No uses location, usa coordenadas.
Cuando creas variables, ponele nombres más descriptivos (así se hace mas fácil leerlos inclusive para vos).
Fijate como trabajo con los grupos (por ahora es la manera mas eficiente/rápida de trabajar con ellos).

bj_lastCreatedGroup: Usa este grupo cuando vallas a hacer únicamente enumeraciones de unidades (como en este caso, que lo único que tenes que hacer es agarrar las unidades y hacerles daño, nada mas).

Ponele nombres más descriptivos a tus funciones.

¿Viste las funciones ExplosionsRawcode, ExplosionsSfx y DamageSfx?, las hice para que el usuario pueda configurar fácilmente la habilidad (en este caso podemos modificar sin ningún problema los efectos y el RAWCODE del spell).

English:

Don't use BJs (mostly are unnecessary).
Don't use location, use cordinates instead.
When you create variables, put descriptive names to them (makes easy read the code).
Look how I work with groups (for now, this is the best way).

bj_lastCreatedGroup: Use this group when you only need a group for enumerate units.

Put descriptive names to your functions.

Do you see the ExplosionsRawcode, ExplosionsSfx and DamageSfx functions?, I make them to make easy the job to the user (for configurate things).

Greetings/Saludos.

EDIT: Solamente trabajo en el bloque de condiciones porque éste se ejecuta primero que las acciones, por ende es más rápido. / I only work in the condition block because it executes first than the actions, so this way is more faster.

Usas JassNewGenPack?,, si es así por favor quiero que me digas como tenes configurado todo, porque yo no lo puedo usar correctamente... desde ya gracias por tu ayuda, voy a ir practicando más, recien empiezo con jass (; :ogre_hurrhurr:

Magtheridon96 · Dec 31, 2011

This would be a more optimal solution:

JASS:

function DamageSfx takes nothing returns string
    return "Abilities\\Weapons\\BoatMissile\\BoatMissile.mdl"
endfunction

function ExplosionsSfx takes nothing returns string
    return "abilities\\weapons\\catapult\\catapultmissile.mdl"
endfunction

function ExplosionsRawcode takes nothing returns integer
    return 'A000'
endfunction

function GetNumberExplosions takes integer level returns integer
    return 2 * level
endfunction

function GetExplosionsDamage takes integer level returns real
    return 10. + 10 * level
endfunction

function GetExplosionsAoE takes integer level returns real
    return 225.
endfunction

function ExplosionsAttackType takes nothing returns attacktype
    return ATTACK_TYPE_NORMAL
endfunction

function ExplosionsDamageType takes nothing returns damagetype
    return DAMAGE_TYPE_NORMAL
endfunction

function ExplosionsActions takes nothing returns boolean
    local unit caster
    local unit target
    local integer level
    local integer i = 0
    local integer explosions
    local real damage
    local real aoe
    local real x
    local real y
    local real casterX
    local real casterY
    local real angle
    local real randAngle
    local real randAoE
    local player owner
    
    if GetSpellAbilityId() == ExplosionsRawcode() then
        set caster = GetTriggerUnit()
        set level = GetUnitAbilityLevel(caster, ExplosionsRawcode())
        set explosions = GetNumberExplosions(level)
        set damage = GetExplosionsDamage(level)
        set aoe = GetExplosionsAoE(level)
        
        set angle = GetUnitFacing(caster) * bj_DEGTORAD
        
        set casterX = GetUnitX(caster) + aoe / 1.25 * Cos(angle)
        set casterY = GetUnitY(caster) + aoe / 1.25 * Sin(angle)
        
        set owner = GetTriggerPlayer()
        
        loop
            exitwhen i >= explosions
            
            set randAngle = GetRandomReal(0, 360) * bj_DEGTORAD
            set randAoE = GetRandomReal(0, aoe)
            
            set x = casterX + randAoE * Cos(randAngle)
            set y = casterY + randAoE * Sin(randAngle)
            
            call DestroyEffect(AddSpecialEffect(ExplosionsSfx(), x, y))
            
            call GroupEnumUnitsInRange(bj_lastCreatedGroup, x, y, aoe, null)
            loop
                set target = FirstOfGroup(bj_lastCreatedGroup)
                exitwhen target == null
                
                if IsUnitEnemy(target, owner) then
                    call UnitDamageTarget(caster, target, damage, false, false, ExplosionsAttackType(), ExplosionsDamageType(), null)
                    call DestroyEffect(AddSpecialEffect(DamageSfx(), GetUnitX(target), GetUnitY(target)))
                endif
                
                call GroupRemoveUnit(bj_lastCreatedGroup, target)
            endloop
            
            set i = i + 1
        endloop
        
        set caster = null
        set owner = null
    endif
    
    return false
endfunction

function InitTrig_Explosions1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(t, Condition(function ExplosionsActions))
    set t = null
endfunction

It doesn't require JNGP by the way.

Kratoz-X · Dec 31, 2011

xIceShotx said:
This doesn't even work properly ;o, If each person castes it, it orders all the units the casted the ability to recast it again ._.
-Translated to Spanish:-
Esto ni siquiera funciona bien ;o, si cada persona que las castas, que ordena todas las unidades del fundido la posibilidad de que la refundición de nuevo ._.

i talk spanish and dont use google translator google is just not good >.<
corectly translated

"Esto nisiquiera funciona bien ;O, si cada persona usa la habilidad entonces ordena todas las unidades usando la habilidad les ordena usarla de nuevo ._."

well more or less

translate wisely man ¬¬

Magtheridon96 · Dec 31, 2011

translate wisely man ¬¬

How else would you expect him to translate it?

Ruke · Dec 31, 2011

This would be a more optimal solution:

Agree with the extra functions, but the extra variables, they're just useless (my opinion).

set t = null

Why the people here do this?
It's not necessary, you will never destroy a spell trigger.

EDIT: Nice boobs link :ogre_hurrhurr:

EDIT2:

Usas JassNewGenPack?,, si es así por favor quiero que me digas como tenes configurado todo, porque yo no lo puedo usar correctamente... desde ya gracias por tu ayuda, voy a ir practicando más, recien empiezo con jass (;

Español

Si, uso el NewGen. Lo único que debes hacer es descargarlo, descomprimirlo en cualquier parte y abrirlo (NewGen WE.exe). Cuando lo abras, vas a Reinventing the craft (en los menú de arriba) y destildas la opción que dice: "Enable Reinventing the craft".
Después cerras, y te bajas la actualización del JassHelper (así podes usar las nuevas actualizaciones de vJASS, ZINC, etc.).

Actualización: http://www.wc3c.net/attachment.php?attachmentid=48033&d=1266209195

Cuando lo termines de descargar, abrilo y busca la carpeta que dice "executables". Abrila y extraé su contenido en la carpeta jasshelper de tu NewGen. Las demás carpetas extraelas así nomas también en la carpeta jasshelper del NewGen.

Acordate que NewGen puede tener algunos problemas con algunos anti-virus, así que agregalo a las excepciones para que no haya problemas.

Saludos

.

English

Yes I do. The only you need to do is download, decompress in any folder and open it (NewGen WE.exe). When you open it, go to Reinventing the craft (in the top menues) and remove the tick from the Enable Reinventing the craft option.
Close it, and download the updates to the JassHelper (so you will can use the new features of vJASS, ZINC, etc.).

Update: http://www.wc3c.net/attachment.php?attachmentid=48033&d=1266209195

When you finish, open it and find the executables folder. Open it and decompress their content in the jasshelper folder of your NewGen.
The other folders decompress it in the jasshelper too.

Remember, NewGen can get some troubles with some anti-virus, so add it to exceptions to prevent errors.

Greetings.

Magtheridon96 · Dec 31, 2011

Why the people here do this?
It's not necessary, you will never destroy a spell trigger.

type trigger extends agent

Thus, triggers increase the reference count.
The less the reference count, the greater the performance of the Jass Virtual Machine.
That's why nulling triggers is good

And those extra variables are used to make things run a tiny bit faster ;P

Ruke · Dec 31, 2011

Thus, triggers increase the reference count.
The less the reference count, the greater the performance of the Jass Virtual Machine.
That's why nulling triggers is good

Ah, now yes

And those extra variables are used to make things run a tiny bit faster ;P

~~owner has only 1 uses.~~

I don't know if those variables makes more faster the spell, I think that they are only to make easy read the code.

Magtheridon96 · Dec 31, 2011

owner is inside a loop if you haven't noticed

Ruke · Dec 31, 2011

owner is inside a loop if you haven't noticed

~~Isn't better call GetTriggerPlayer() instead?.~~
Ah, I got it xD

KhaosMachine · Dec 31, 2011

THANKSS to all, I will work in my spell now, I wish this spell works ! -.-"

Explosions

Made by KhaosMachine (Map)

Moderator

Moderator

Similar threads