Triggers

//TESH.scrollpos=0
//TESH.alwaysfold=0
scope Explosions initializer Initialization

    globals
        private constant integer SPELL_ID = 'A000'//Spell rawcode
        private constant string EFFECT_AOE = "abilities\\weapons\\catapult\\catapultmissile.mdl"//Special effect of the explosion
        private constant attacktype ATTACK_TYPE = ATTACK_TYPE_NORMAL//Attack type
        private constant damagetype DAMAGE_TYPE = DAMAGE_TYPE_NORMAL//Damage type
        private constant boolean KILL_TREES = true//Requires FFTSystem by KhaosMachine
        private constant boolean TERRAIN_DEFORMATION = true//If you want enable/disable the terrain deformations
        private constant boolean PRELOAD = true//Preload special effect
    endglobals

    function GetExplosions takes integer level returns integer
        return 3 + level//Total of explosions each level
    endfunction

    function GetDamage takes integer level returns real
        return 15. + 15. * level//Damage of each explosion each level
    endfunction

    private constant function GetAreaOfEffect takes integer level returns real
        return 120. + 20. * level//Area of effect of the explosions each level
    endfunction
    
    private constant function GetTargetType takes unit target, player owner returns boolean
        if /*
        */not IsUnitType(target, UNIT_TYPE_DEAD) /*//Target isn't dead
        */and not IsUnitType(target, UNIT_TYPE_STRUCTURE) /*//Target isn't a structure
        */and not IsUnitType(target, UNIT_TYPE_MAGIC_IMMUNE) /*//Target isn't magic immune
        */and IsUnitEnemy(target, owner) /*//Target is enemy of caster
        */then
            return true
        endif
        return false
    endfunction
    
    globals
        private constant group TempGroup = CreateGroup()
    endglobals

    function Actions takes nothing returns boolean
        local unit caster
        local integer level
        local integer i = 0
        local integer explosions
        local real damage
        local real aoe
        local real aoeoe
        local real x
        local real y
        local unit j
        local unit du
        local location loc
        if GetSpellAbilityId() == SPELL_ID then
            set caster = GetTriggerUnit()
            set level = GetUnitAbilityLevel(caster, SPELL_ID)
            set explosions = GetExplosions(level)
            set damage = GetDamage(level)
            set aoeoe = GetAreaOfEffect(level)
            set aoe = aoeoe * 1.2
            loop
                exitwhen i >= explosions
                    set x = (GetUnitX(caster) + aoe / 1.25 * Cos(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Cos(GetRandomReal(0, 360) * bj_DEGTORAD)
                    set y = (GetUnitY(caster) + aoe / 1.25 * Sin(GetUnitFacing(caster) * bj_DEGTORAD)) + GetRandomReal(0, aoe) * Sin(GetRandomReal(0, 360) * bj_DEGTORAD)
                    call GroupEnumUnitsInRange(TempGroup, x, y, aoeoe, null)
                    loop
                        set j = FirstOfGroup(TempGroup)
                        exitwhen j == null
                        call GroupRemoveUnit(TempGroup, j)
                        if GetTargetType(j, GetTriggerPlayer()) then
                           call UnitDamageTarget(caster, j, damage, true, false, ATTACK_TYPE, DAMAGE_TYPE, null)
                        endif
                    endloop
                    call DestroyEffect(AddSpecialEffect(EFFECT_AOE, x, y))
                    if TERRAIN_DEFORMATION then
                        call TerrainDeformWave(x, y, x, y, 3, 500, aoeoe, 20, 100, 3)
                    endif
                    if KILL_TREES then
                        set loc = Location(x, y)
                        set udg_FFT_Real_AreaOfEffect = aoeoe
                        set udg_FFT_Point_TargetPoint = loc
                        call ExecuteFunc("FFT_Kill")
                        call RemoveLocation(loc)
                    endif
                set i = i + 1
            endloop
            set caster = null
        endif
        return false
    endfunction

    public function PreloadSpell takes nothing returns nothing
        call Preload(EFFECT_AOE)
    endfunction

    function Initialization takes nothing returns nothing
        local trigger t = CreateTrigger()
        call TriggerRegisterAnyUnitEventBJ(t, EVENT_PLAYER_UNIT_SPELL_EFFECT)
        call TriggerAddCondition(t, Condition(function Actions))
        if PRELOAD then
            call PreloadSpell()
        endif
        set t = null
    endfunction

endscope