[JASS] Combine Triggers

[Dr. Boom]

Moin moin =)

It's me again and I have a simple question. At all not simple for me, because if I try something
like this, it always gets buggy somehow.

As you see in the title, I want combine triggers. Let's say I have this two triggers:

Click (and yes I forgot set t = null ...)

function Actions1 takes nothing returns nothing
    local real x = GetRectCenterX(gg_rct_WhoKnows)
    local real y = GetRectCenterY(gg_rct_WhoKnows)
    
    call SetUnitX(GetTriggerUnit(),x)
    call SetUnitY(GetTriggerUnit(),y)
endfunction

//===========================================================================
function InitTrig_Enter1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterEnterRectSimple(t,gg_rct_KnowsWho)
    call TriggerAddAction(t,Actions1)
endfunction

function Actions2 takes nothing returns nothing
    local real x = GetRectCenterX(gg_rct_KnowsWho)
    local real y = GetRectCenterY(gg_rct_KnowsWho)
    
    call SetUnitX(GetTriggerUnit(),x)
    call SetUnitY(GetTriggerUnit(),y)
endfunction

//===========================================================================
function InitTrig_Enter1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterEnterRectSimple(t,gg_rct_WhoKnows)
    call TriggerAddAction(t,Actions2)
endfunction

Again, how must I do this, that I can use this in one trigger PLUS: I have more of this "Rect Enter" triggers, so I thought, that I need 3 globals for x,y and u (the triggerunit()). So how to combine all this, to one (bigger) good working trigger? =)

Greetings - Thanks - Peace
Dr. Boom

 

[PurgeandFire]

Something like this would probably work:

globals
    hashtable hash = InitHashtable()                
endglobals

function GetEnteredRect takes nothing returns rect
    return LoadRectHandle(hash,GetHandleId(GetTriggeringRegion()),0)
endfunction

function TriggerRegisterEnterRect takes trigger t, rect r returns event
    local region rectRegion = CreateRegion()
    call RegionAddRect(rectRegion,r)
    call SaveRectHandle(hash,GetHandleId(rectRegion),0,r)
    return TriggerRegisterEnterRegion(t,rectRegion,null)
endfunction

Just use TriggerRegisterEnterRect(trig,rect) and then use GetEnteredRect() in the actions function, like so:

function Actions1 takes nothing returns nothing
    local rect r = GetEnteredRect()
    local real x = GetRectCenterX(r)
    local real y = GetRectCenterY(r)
    
    call SetUnitX(GetTriggerUnit(),x)
    call SetUnitY(GetTriggerUnit(),y)
endfunction

//===========================================================================
function InitTrig_Enter1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterEnterRect(t,gg_rct_KnowsWho)
    call TriggerRegisterEnterRect(t,gg_rct_WhoKnows)
    call TriggerAddAction(t,Actions1)
endfunction

Untested, but that should work.

 

[Dr. Boom]

This maybe could work, but I don't understand this at all.

When a unit enters WhoKnows, how this triggers should know, that the unit should instantly move to KnowsWho?
Because as far as I understand, only the rect, which is entered is store in the hash, but not the rect, where the unit should be after.

 

[baassee]

Because the snippet doesn't do that. When the unit enters the region, it will move to the center of that region. You just have to change it in the Actions1 function.

 

[Dr. Boom]

Ahh I understand it, but this doesn't solve the question I had or? =O

Because I want combine both triggers (I posted) into only one trigger, but I can't see the way in this example =O
So it's like in one trigger, I have 2 events (enter rect 1 or 2), 1 condition for both (TriggerUnit = xx) and 2 actions (for action when enter rect 1 or rect 2)

 

[baassee]

This will probably do it.

function Actions1 takes nothing returns nothing
    local rect r = GetEnteredRect()
    if r == gg_rct_KnowsWho then
         call SetUnitX(GetTriggerUnit(),GetRectCenterX(gg_rct_WhoKnows))
         call SetUnitY(GetTriggerUnit(),GetRectCenterY(gg_rct_WhoKnows))
    else
         call SetUnitX(GetTriggerUnit(),GetRectCenterX(gg_rct_KnowsWho))
         call SetUnitY(GetTriggerUnit(),GetRectCenterY(gg_rct_KnowsWho))
    endif
endfunction

 

[Dr. Boom]

Maybe it wasn't 100% clear in my first post, but this two triggers are only an example, at all I have much more rects, which can be entered ...

 

[baassee]

Filter each region with in the if like I did (but with elseif) and then you can choose your actions for each and every region you have.

 

[Garfield1337]

Just put it like this (example)

function Actions1 takes nothing returns nothing
    local real x = GetRectCenterX(gg_rct_WhoKnows)
    local real y = GetRectCenterY(gg_rct_WhoKnows)
    
    call SetUnitX(GetTriggerUnit(),x)
    call SetUnitY(GetTriggerUnit(),y)
endfunction

function Actions2 takes nothing returns nothing
    local real x = GetRectCenterX(gg_rct_KnowsWho)
    local real y = GetRectCenterY(gg_rct_KnowsWho)
    
    call SetUnitX(GetTriggerUnit(),x)
    call SetUnitY(GetTriggerUnit(),y)
endfunction

//===========================================================================
function InitTrig_Enter1 takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterEnterRectSimple(t,gg_rct_KnowsWho)
    call TriggerAddAction(t,Actions1)
    set t = CreateTrigger()
    call TriggerRegisterEnterRectSimple(t,gg_rct_WhoKnows)
    call TriggerAddAction(t,Actions2)
    set t = null
endfunction

 

[baassee]

The result will be tons of extra functions when you simply only need one?

 

[Dr. Boom]

The result will be tons of extra functions when you simply only need one?

Anyway (thanks to Garfield1337) I will use the way from you baassee. But can you tell me then
what I should take as event? Because in the event I have to set the region which is entered, so I can't use
if - then - else =O

 

[baassee]

Use Purge's snippet and use the action function I provided.