Baradé's Resources 1.0

[paladinjst]

This is the very exactly system I wanted ! Good job !

 

[Barade]

Thx it still needs some polishing.

Updates:

• Added a check for the target pathing of mines and return buildings. It has to match the movement type of the worker now. Previously, a floating worker could return resources to a ground/land return building. This should be fixed now.
• Add JASS function GetSingleSelectedUnit and use it to successfully detect the only selected unit per player for showing/hiding the custom GUI.
• Always prefer harvested resources for the two resources shown in the custom GUI.

 

[paladinjst]

Good work!! Will you add the Iron resources in your next updates ? I think iron is the necessary resource for the weapon~
And BTW , is there any way to show the extra UI icons of resources cost (such as stone or wheat), when you build, train or hire some units ?

 

[Barade]

I could add more example resources. However, it is just an example map on how to use the system and adding too many resources will probably make the multiboard unusable at some point. In my own map I have like 10 custom resources and only use multiboards for your own resources not the team ones.

I don't think there is any easy way to do this. The existing system I checked out also had it written in tooltips. You would have to modify the tooltip frame.

However, you can write a custom UI for shops etc. and add something like that.

 

[paladinjst]

I could add more example resources. However, it is just an example map on how to use the system and adding too many resources will probably make the multiboard unusable at some point. In my own map I have like 10 custom resources and only use multiboards for your own resources not the team ones.

I don't think there is any easy way to do this. The existing system I checked out also had it written in tooltips. You would have to modify the tooltip frame.

However, you can write a custom UI for shops etc. and add something like that.

Thanx for your reply，your resource and the sound system are really great useful ～ Wish you can produce more like those.

 

[Barade]

Changes:

• Fix hitting resources more than once.
• Fix showing/hiding resources UI.
• Do not show stop message on targeting loaded mines for harvesting.
• Allow harvesting from loaded mines which do not belong to you.
• Allow ignoring players in resources multiboard.
• Custom resource Ore with loaded mines.
• Shredder like unit Drillbot to harvest Rock based on Goblin Drillbot 3000.

 

[paladinjst]

Big updates! ~ Love to see you still do the works to improve your system~ And Chronicles of the Second War was released . in that mod they used more or less the same system . But they put the oil resource icon on the origin UI frame to instead the multiboard . I really wish you can solve the new custom resource on UI tiptools . Maybe this can be more like your sound system , We can set a unit custom resources cost in the codes.

You really did a great job~

 

[Barade]

Big updates! ~ Love to see you still do the works to improve your system~ And Chronicles of the Second War was released . in that mod they used more or less the same system . But they put the oil resource icon on the origin UI frame to instead the multiboard . I really wish you can solve the new custom resource on UI tiptools . Maybe this can be more like your sound system , We can set a unit custom resources cost in the codes.

You really did a great job~

thx
I was thinking about providing some custom UI instead of the multiboard below the resource icons but the multiboard also shows allied resources.

There might be some way to access the tooltip frame similar to CustomConsoleUI but even if that would work I would need to get which tooltip you are looking at (maybe one can extract the text from the frame) to show the correct cost.

 

[paladinjst]

thx
I was thinking about providing some custom UI instead of the multiboard below the resource icons but the multiboard also shows allied resources.

There might be some way to access the tooltip frame similar to CustomConsoleUI but even if that would work I would need to get which tooltip you are looking at (maybe one can extract the text from the frame) to show the correct cost.

Thanx for your reply ~ "I was thinking about providing some custom UI instead of the multiboard below the resource icons but the multiboard also shows allied resources" this is brilliant ! I agree with this , cause if you are playing melee mode , the enemy's resources shouldnt be shown with ours . I wish you can improve this much better ! I found this maybe it can give you some ideas~ResourceBar ItemShop
Sadly the attention to this spells section is too low now , but your system is really good and useful ~

 

[Barade]

Update:

• Improve the performance for loaded mines.
• Do not show custom resources UI when the progress bar of a unit is shown: upgrades, researches and trainings.

 

[Wrda]

Resources script:

Spoiler

private function GetAlliesWithSharedControl takes player owner returns force
    local force allies = CreateForce()
    local player slotPlayer = null
    local integer i = 0
    call ForceAddPlayer(allies, owner)
    loop
        exitwhen (i == bj_MAX_PLAYERS)
        set slotPlayer = Player(i)
        if (slotPlayer == owner or GetPlayerAlliance(owner, slotPlayer, ALLIANCE_SHARED_ADVANCED_CONTROL)) then
            call ForceAddPlayer(allies, slotPlayer)
        endif
        set slotPlayer = null
        set i = i + 1
    endloop
    return allies
endfunction

The first condition seems redundant, since "slotPlayer" will inevitably be "owner", which you are already adding beforehand.

Spoiler

function AddPlayerResource takes player whichPlayer, Resource resource, integer amount returns nothing
    call SetPlayerResource(whichPlayer, resource, GetPlayerResource(whichPlayer, resource) + amount)
endfunction

function RemovePlayerResource takes player whichPlayer, Resource resource, integer amount returns nothing
    call SetPlayerResource(whichPlayer, resource, IMaxBJ(0, GetPlayerResource(whichPlayer, resource) - amount))
endfunction

This is essentially the same, the first one can become the second if amount is negative. Simplify it.

function AddMine takes unit whichUnit returns nothing
    call GroupAddUnit(mines, whichUnit)
    call SetMineWorkers(whichUnit, CreateGroup())
endfunction

I suppose SetMineWorkers shouldn't be called if unit is already in unit group, it would also leak a new group.

function AddWorker takes unit whichUnit returns nothing
    local integer i = 0
    local integer max = GetMaxResources()
    call GroupAddUnit(workers, whichUnit)
endfunction

Unused variables.

Spoiler

function CustomBountyEx takes unit worker, player whichPlayer, Resource resource, integer amount returns nothing
    call AddPlayerResource(whichPlayer, resource, amount)
    call CustomBountyFadingText(worker, resource, amount)
endfunction

function CustomBounty takes unit worker, Resource resource, integer amount returns nothing
    call CustomBountyEx(worker, GetOwningPlayer(worker), resource, amount)
endfunction

There's a risk of conflicting names with an actual custom bounty, related to unit kills.
Also, You don't need to clear groups if you're going to destroy them.

GetUnitReturnResource returns a boolean, I think the name should somewhat reflect that, e.g. IsUnitReturnResource.
Likewise for GetUnitDisableStopMiningOnError.

Spoiler

function NextReturnBuilding takes unit worker returns unit
    local group returnBuildings = CreateGroup()
    local Resource resource = 0
    local unit groupMember = null
    local real groupMemberDistance = 0.0
    local real distance = 0.0
    local unit result = null
    local integer i = 0
    local integer max = 0
    local integer j = 0
    local integer max2 = 0
    local boolean valid = false
    set filterWorker = worker
    call GroupEnumUnitsOfPlayer(returnBuildings, GetOwningPlayer(worker), Filter(function FilterFunctionReturnBuilding))
    set max = BlzGroupGetSize(returnBuildings)
    loop
        exitwhen (i == max)
        set groupMember = BlzGroupUnitAt(returnBuildings, i)
        //call BJDebugMsg("Checking return building "  + GetUnitName(groupMember))
        
        set valid = false
        set j = 0
        set max2 = GetMaxResources()
        loop
            exitwhen (j == max2)
            set resource = GetResource(j)
            //call BJDebugMsg("Resource "  + GetResourceName(resource) + " carrying " + I2S(GetUnitResource(worker, resource)))
            if (GetUnitReturnResource(groupMember, resource) and GetUnitResource(worker, resource) > 0) then
                //call BJDebugMsg("Enable for resource "  + GetResourceName(resource))
                set valid = true
            endif
            set j = j + 1
        endloop
        
        if (valid) then
            set groupMemberDistance = DistanceBetweenUnits(worker, groupMember)
            if (result == null or groupMemberDistance < distance) then
                set result = groupMember
                set distance = groupMemberDistance
            endif
        else
            //call BJDebugMsg("Disabled")
        endif
        set groupMember = null
        set i = i + 1
    endloop
    
    call GroupClear(returnBuildings)
    call DestroyGroup(returnBuildings)
    set returnBuildings = null
    
    return result
endfunction

Return early on valid being true. setting "groupMember" to null should be done outside of the loop.

Spoiler

private function TimerFunctionReleaseWorkerFromMine takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer handleId = GetHandleId(t)
    local unit worker = LoadUnitHandle(h, handleId, 0)
    local unit mine = LoadUnitHandle(h, handleId, 1)
    local Resource resource = LoadInteger(h, handleId, 2)
    local integer amount = Gather(worker, mine)
    
    // did not explode
    if (IsUnitAliveBJ(mine)) then
        call ReleaseWorkerFromMine(worker, mine)
        //all BJDebugMsg("Release worker with resource " + GetResourceName(resource))
    endif
    
    //call BJDebugMsg("Show and order return ability " + GetObjectName(GetUnitReturnAbilityId(worker, resource)))
    call BlzUnitHideAbility(worker, GetUnitHarvestAbilityId(worker, resource), true)
    call BlzUnitHideAbility(worker, GetUnitReturnAbilityId(worker, resource), false)
    call IssueImmediateOrderById(worker, GetUnitReturnOrderId(worker, resource))
    
    call FlushChildHashtable(h, handleId)
    call PauseTimer(t)
    call DestroyTimer(t)
    call SetUnitQueueWorkerReleaseTimer(worker, null)
    set t = null
endfunction

Unused variable "amount".

private function CancelUnitQueueWorkerReleaseTimer takes unit worker returns nothing
    local timer t = GetUnitQueueWorkerReleaseTimer(worker)
    if (t != null) then
        call FlushChildHashtable(h, GetHandleId(t))
        call PauseTimer(t)
        call DestroyTimer(t)
    endif
endfunction

Missing nulling inside the conditon. There are reference leaks (local unit not being nulled or being returned) also, including in some of the other scripts.

TriggerActionCast function:

elseif (not gatherInside and foundResource != 0 and amount == 0 or HasMaxOfMineResources(worker, mine)) then // return resources if necessary

Amount is always 0 if gatherInside is true.


Barades Resource Multiboard Gui script:

function ShowPlayerResourceMultiboard takes player whichPlayer returns nothing
    call MultiboardDisplay(GetPlayerResourceMultiboard(whichPlayer), true)
endfunction


function HidePlayerResourceMultiboard takes player whichPlayer returns nothing
    call MultiboardDisplay(GetPlayerResourceMultiboard(whichPlayer), false)
endfunction

This could be merged by adding a boolean parameter. Likewise for ShowAllPlayerResourceMultiboards, and the team multiboard.

function ShowAllPlayerResourceMultiboards takes nothing returns nothing
     local integer i = 0
    loop
        exitwhen (i == bj_MAX_PLAYERS)
        call MultiboardDisplay(GetPlayerResourceMultiboard(Player(i)), false)
        set i = i + 1
    endloop
endfunction

Seems like an error, should be "true" and not "false".
This script is using StringUtils, but isn't requiring it.

Barades Resources Gui script:

Spoiler

private function ShowResourcesUI takes player whichPlayer returns nothing
    call SetResourcesUIVisible(whichPlayer, true)
endfunction

private function HideResourcesUI takes player whichPlayer returns nothing
    call SetResourcesUIVisible(whichPlayer, false)
endfunction

private function ShowResourcesGatheredUI takes player whichPlayer returns nothing
    call SetResourcesUIGatheredVisible(whichPlayer, true)
endfunction

private function HideResourcesGatheredUI takes player whichPlayer returns nothing
    call SetResourcesUIGatheredVisible(whichPlayer, false)
endfunction

Again, can be reduced to 2 functions. ShowResourcesUI and HideResourcesUI are unused.

Spoiler

private function GetPrimaryResourceEx takes unit mine, Resource ignore returns Resource
    local Resource resource = 0
    local Resource result = 0
    local integer current = 0
    local integer currentMax = 0
    local integer v = 0
    local integer w = 0
    local integer i = 0
    local integer max = GetMaxResources()
    loop
        exitwhen (i == max)
        set resource = GetResource(i)
        if (resource != ignore) then
            set v = GetUnitResource(mine, resource)
            set w = GetUnitResourceMax(mine, resource)
            if (v > current) then
                set result = resource
                set current = v
            elseif (not IsStandardResource(resource) and current == 0 and w > currentMax) then
                set result = resource
                set currentMax = w
            endif
        endif
        set i = i + 1
    endloop
    return result
endfunction

I'd appreciate better variable names than 'v' and 'w'.
All Frames are using absolute point, the same parent and frame level. You should use more BlzFrameSetPoint as it sets a frame relative to another without worrying too much about many variables of positioning. You won't need to set frame level if you make most frames as child frames of the two main frames. Hit me up if you need a clearer explanation to deal with frames.

Barades Resources Cost script:

Why is there SetCosts when there is SetObjectTypeResourcesCosts? Same thing with GetCostsForLevel and GetCosts.
Also, GetCosts has player parameter but SetCosts not? Not very consistent. You can have dedicated "ForPlayer" functions besides the "AllPlayer" ones.

Spoiler

private function TimerFunctionCancel takes nothing returns nothing
    local timer t = GetExpiredTimer()
    local integer handleId = GetHandleId(t)
    local unit whichUnit = LoadUnitHandle(h2, handleId, 0)
    call DisableCancelTriggers()
    call IssueImmediateOrderById(whichUnit, CANCEL_ORDER_ID)
    call IssueImmediateOrder(whichUnit, "stop") // for constructions
    call EnableCancelTriggers()
    call FlushChildHashtable(h2, handleId)
    call PauseTimer(t)
    call DestroyTimer(t)
endfunction

private function TriggerActionIssue takes nothing returns nothing
    local timer t = CreateTimer()
    call SaveUnitHandle(h2, GetHandleId(t), 0, GetTriggerUnit())
    call TimerStart(t, 0.0, false, function TimerFunctionCancel)
endfunction

Reference leaks on local variables, to name a few.

private function GetUnitShop takes nothing returns integer
    return 'ngme' // This is the raw code for the goblin shop
endfunction

private function GetUnitSell takes nothing returns integer
    return 'Hpal' // This is the raw code for the paladin
endfunction

This is falling under the assumption that the shop and the hero has the abilities necessary for this to work. Most of the time users might not modify these units, but it can be risky.

Spoiler

private function GetItemValueGoldFresh takes integer i returns integer
    local real x= 0
    local real y= 0
    local unit u1= CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), ('ngme'), x, y, 0) // INLINED!!
    local unit u2= CreateUnit(Player(PLAYER_NEUTRAL_PASSIVE), ('Hpal'), x, y - 100, 90) // INLINED!!
    local item a= UnitAddItemByIdSwapped(i, u2)
    local integer g1= GetPlayerState(Player(PLAYER_NEUTRAL_PASSIVE), PLAYER_STATE_RESOURCE_GOLD)
    local integer g2= 0
    call UnitDropItemTarget(u2, a, u1)
    set g2=GetPlayerState(Player(PLAYER_NEUTRAL_PASSIVE), PLAYER_STATE_RESOURCE_GOLD) - g1
    call SetPlayerState(Player(PLAYER_NEUTRAL_PASSIVE), PLAYER_STATE_RESOURCE_GOLD, GetPlayerState(Player(PLAYER_NEUTRAL_PASSIVE), PLAYER_STATE_RESOURCE_GOLD) - g2)
    call RemoveUnit(u1)
    call RemoveUnit(u2)
    set u1=null
    set u2=null
    set a=null
    return g2
endfunction

Perhaps have the shop and the hero to be always the same units, just hidden, and then if required to get the gold amount, then show, move nearby, and get the gold difference.

Barades Resources Warnings Script:

Spoiler

private function TriggerConditionGather takes nothing returns boolean
    local Resource resource = GetTriggerResource()
    local unit mine = GetTriggerMine()
    local unit worker = GetTriggerWorker()
    local player owner = GetOwningPlayer(worker)
    if (GetLowResourcesSound(owner, resource) != null and GetUnitResource(mine, resource) <= GetResourceLowValue(resource) and  GetUnitResource(mine, resource) + resource > GetResourceLowValue(resource)) then
        call StartSoundForAllies(owner, GetLowResourcesSound(GetOwningPlayer(GetTriggerWorker()), resource))
        call PingMinimapForAllies(owner, GetUnitX(mine), GetUnitY(mine))
        if (GetLowResourcesMessage(owner, resource) != null and GetLowResourcesMessage(owner, resource) != "") then
            call SimErrorForAllies(owner, GetLowResourcesMessage(owner, resource))
        endif
    endif
    if (GetCollapsedResourcesSound(owner, resource) != null and GetUnitResource(mine, resource) <= 0) then
        call StartSoundForAllies(owner, GetCollapsedResourcesSound(owner, resource))
        call PingMinimapForAllies(owner, GetUnitX(mine), GetUnitY(mine))
        if (GetCollapsedResourcesMessage(owner, resource) != null and GetCollapsedResourcesMessage(owner, resource) != "") then
            call SimErrorForAllies(owner, GetCollapsedResourcesMessage(owner, resource))
        endif
    endif
    set mine = null
    set worker = null
    set mine = null
    set owner = null
    return false
endfunction

(Double variable nulling )

Barades Resources Chat Commands script:

Spoiler

function GetResourceFromString takes string s returns Resource
    local string lower = StringCase(s, false)
    local integer index = S2I(s)
    local Resource resource = 0
    local integer i = 0
    local integer max = GetMaxResources()
    loop
        exitwhen (i == max)
        set resource = GetResource(i)
        if (StringCase(GetResourceName(resource), false) == lower) then
            return resource
        endif
        set i = i + 1
    endloop
    
    if (i >= 1 and i <= max) then
        return GetResource(i - 1)
    endif
    
    return 0
endfunction

I'm not sure why this belongs in another script other than the primary system. It might be used only in this script, but in reality it's another form of "GetResource" function.
local integer index = S2I(s) not being used.

I'm not sure but I didn't see Barades Resources Gui script's frames showing at all, even when enabled.
"Not enough X" sounds stop playing if one clicks the button again to train whatever unit that uses custom resources. IsSoundPlaying should prove useful here.
Documentation and a list of all the available API are missing, although you gave specific examples on the page and on a great demo map.
Please also provide links to the other resources on the page and/or in the map. And a changelog on the page/or in the map.
This resource should also have contains external material tag.

Took a while to review everything.

 

[Barade]

thx for the review I will update/fix the stuff when I get more time. I fixed the UI not shown bug. The condition for the progressbar being shown was wrong.

I will fix the rest some time later.