[vJASS] Adding abilities to last created unit.

[ratel]

In this spell it creates a wolf and then it is supposed to add two abilities but it doesnt do anything, the wolf is a normal unit, the base unit was a peasant, when I try to add abilities by that way with a hero it works, why isn't this working?

scope Wolf initializer Init
globals
      private constant integer ABI_ID = 'A00K'
      private constant integer WOLF = 'h00C'
endglobals

private function Conditions takes nothing returns boolean
    return GetSpellAbilityId() == 'A00K'
endfunction

private function Actions takes nothing returns nothing
    local unit hero    = GetTriggerUnit()
    local player owner = GetOwningPlayer(hero)
    local integer pid  = GetPlayerId(owner) + 1 
    local real str     = GetHeroStr(hero, true)
    local real agi     = GetHeroAgi(hero, true)
    local real int     = GetHeroInt(hero, true)
    local unit wolf

    call CreateUnit(owner, WOLF, GetUnitX(hero), GetUnitY(hero), 0)
    set wolf = GetLastCreatedUnit()
    call UnitAddAbility(wolf, 'A016' )
    call UnitAddAbility(wolf, 'A012' )

 
    
    

    set wolf = null
    set hero = null
endfunction

//===========================================================================
private function Init takes nothing returns nothing
    local trigger WolfTrg = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ( WolfTrg, EVENT_PLAYER_UNIT_SPELL_EFFECT )
    call TriggerAddCondition( WolfTrg, Condition( function Conditions ) )
    call TriggerAddAction( WolfTrg, function Actions )
endfunction
endscope

 

[Tirlititi]

    call CreateUnit(owner, WOLF, GetUnitX(hero), GetUnitY(hero), 0)
set wolf = GetLastCreatedUnit()

Turn that into :

    set wolf = CreateUnit(owner, WOLF, GetUnitX(hero), GetUnitY(hero), 0)

 

[muzzel]

You will _NEVER_ need any of these "lastCreatedWhatever..." in jass, its only required for GUI. In Jass this kind of stuff is done by using the return value of a function (like in Tirlititis posts).

Maybe that helps you understand:

The GUI Create-Unit when converted to jass:

function CreateUnitAtLocSaveLast takes player id, integer unitid, location loc, real face returns unit
    if (unitid == 'ugol') then
        set bj_lastCreatedUnit = CreateBlightedGoldmine(id, GetLocationX(loc), GetLocationY(loc), face)
    else
        set bj_lastCreatedUnit = CreateUnitAtLoc(id, unitid, loc, face)
    endif

    return bj_lastCreatedUnit
endfunction

which is basically this:

function CreateUnitAtLocSaveLast takes player id, integer unitid, location loc, real face returns unit
    //...
    set bj_lastCreatedUnit = CreateUnitAtLoc(id, unitid, loc, face)
    //...
endfunction

The GetLastCreatedUnit() function:

function GetLastCreatedUnit takes nothing returns unit
    return bj_lastCreatedUnit
endfunction

 

[Chaosy]

make sure the ability you want to add is a unit ability not a hero ability

also id use this more simple ftw, there is no reason to use a scope there

function onInit takes nothing returns nothing
    local u = GetLastCreatedUnit()
    call UnitAddAbility(u, 'a000')
    call UnitAddAbility(u, 'a001')
    set u = null
endfunction

 

[defskull]

make sure the ability you want to add is a unit ability not a hero ability

This doesn't interrupt the process, at all.
Hero can use Unit ability and vice versa.