Using Set X and Y

[pOke]

Hello, I was wondering if someone could tell me how to use the setX and setY and incorporate it in a GUI Trigger. I'm trying to make a unit slide but not lose its current orders. Any help would be very much appreciated!

Thanks!

 

[Chaosy]

In gui we use this insted of x and y

• Actions
  • Set loc1 = (Position of (Triggering unit))
  • Set loc2 = (loc1 offset by 5.00 towards angle degrees)

 

[Binsu]

Using Set X and Y

This might help you bro =)

 

[Spartipilo]

You basically do it in JASS, since GUI doesn't give you easy direct access to X/Y movement.

Do your movement thing in GUI with "Unit - Set unit position". Then post it here and i'll give you some tips to turn it into JASS, replacing "Set unit position" with "SetUnitX" and "SetUnitY"

Note. If you aditionaly pick the trigger and go to Edit -> Convert to Custom Text" and paste that text here within jass tags [code=jass]TheText[/code] would be a lot better.

Note 2: You can do it in GUI, but with some (several) custom scripts

 

[Almia]

SetUnitX/Y has no GUI version. Unit Move Instantly uses SetUnitPosition,which is very bad because it takes account pathing and uses Order Stop. Its better to use Custom script than Move Unit Instantly.

 

[Spartipilo]

Assuming he doesn't know the math behind moving unit towards angle based on X/Y, I asked him to post the trigger and script in order to take him, step by step, to the X/Y movement from the GUI positioning movement.

 

[MasterTrainer]

From what I have learned so far, Set Unit X/Y is much better than SetUnitPositionLoc.

 

[Chaosy]

its faster but not easier to use in GUI

 

[MasterTrainer]

It's pretty easy once you're really familiar with it's parameters:

• Custom script : local real x = GetLocationX( GetUnitLoc(GetTriggerUnit()))
• Custom script : local real y = GetLocationY( GetUnitLoc(GetTriggerUnit()))
• Custom script : call SetUnitX( GetTriggerUnit(), x)
• Custom script : call SetUnitY( GetTriggerUnit(), y)

See? It just takes a short amount of time to type, and (as far as I know) has no leaks. Just 4 lines of custom script.

 

[Spartipilo]

That's the easy part. Using 4 times GetTriggerUnit() is not good, and using twice "GetUnitLoc" means 2 leaks. The "Hard" part is the math involved in moving the unit towards angle via x/y. I say "Hard" because not many people is familiar with maths, polar projections, vectors, reals, coords, etc. In fact, I'm just able to do it because JNPG has the Bj's formulas.

BTW, using SetUnitX and SetUnitY is better than SetUnitPosition(newX, newY)?

 

[MasterTrainer]

That's easy to fix. Store GetTriggerUnit() in a variable, and store GetUnitLoc in a variable, then remove and null that location afterwards.

 

[Chaosy]

compared to my way x and y are harder to use

 

[MasterTrainer]

But then again, some are hard and some are a little impractical, though most of the time they're efficient and rewarding.

 

[Chaosy]

Have to agree on that point. But as said I recomend using locations in GUI unless you got big lagg problems

 

[pOke]

Wow! Thank you all for your replies.

@Chaosy
That's what I use right now, but I'm looking to expand my knowledge and also retain orders the moving unit has.

@Spartipilo
Is there some place to learn these "maths", I'm mainly looking to move the unit in a straight line so I figured it would be pretty easy xD

@MasterTrainer
If I save my unit to a variable would I just change GetTriggerUnit() to udg_myUnit?

 

[MasterTrainer]

Wow! Thank you all for your replies.
@MasterTrainer
If I save my unit to a variable would I just change GetTriggerUnit() to udg_myUnit?

Yes. And the same goes for the other parameters. You'll replace GetUnitLoc with udg_YourLoc

 

[PurgeandFire]

BTW, using SetUnitX and SetUnitY is better than SetUnitPosition(newX, newY)?

SetUnitPosition() has its own quirks. SetUnitPosition() has pathing checks and will interrupt orders/animations. SetUnitX/Y() will retain orders/animations, but will not check pathing.

Because of the extra pathing checks, SetUnitPosition() becomes pretty slow.

Wow! Thank you all for your replies.

@Chaosy
That's what I use right now, but I'm looking to expand my knowledge and also retain orders the moving unit has.

@Spartipilo
Is there some place to learn these "maths", I'm mainly looking to move the unit in a straight line so I figured it would be pretty easy xD

@MasterTrainer
If I save my unit to a variable would I just change GetTriggerUnit() to udg_myUnit?

For the final question, yes you can just save it to a variable and replace GetTriggerUnit() with udg_<Variable Name>.

As for the question on how to learn the maths, you usually figure it out by looking at examples. This tutorial is pretty old, but it has solid information:
http://www.thehelper.net/threads/graphics-dynamic-effects-gui.35362/

You can also look up the GUI - JASS equivalents of certain calculations, such as DistanceBetweenUnits, AngleBetweenPoints, and polar position.

When you set a unit's position with an offset it is:
originalX + distance * Cos(some angle) = newX
originalY + distance * Sin(some angle) = newY

<some angle> should be in radians. If it is in degrees, you can multiply it by bj_DEGTORAD, or pi/180. This basically will get the new coordinates of a point, offset by some distance towards some angle.

You don't learn all of this stuff in normal math classes. You'll learn most of these concepts, but might not be able to put two and two together that easily. You learn the distance formula really early (I think Algebra 2), which is basically DistanceBetweenUnits(). AngleBetweenPoints() you'll also learn in either Geometry or Algebra2, but the form it is in [Atan2()], you might not be familiar with. Polar position you tend to learn in Calculus BC/college level calculus. You may be introduced to it earlier, though.

Basically, the point of that^ paragraph above is to say that it is kind of scattered information. Play around with it, and you'll begin to learn why certain things happen. Just look at examples. Don't be afraid to look up a slide or knockback in our spells section--there should be tons of them.

 

[Spartipilo]

as PurgeandFire said, you can check the maths involved in the GUI actions by turning them to custom script and looking for the natives of the BJ's.

 

[MasterTrainer]

But some actions that are GUI need more than 1 line of function to be non-bj, or needs a main function and some other sub functions (As far as I know).

 

[Spartipilo]

GUI Movement

• Actions
  • Set tempUnit = (Triggering unit)
  • Set tempLoc1 = (Position of tempUnit)
  • Set tempLoc2 = (tempLoc1 offset by 5.00 towards (Facing of tempUnit) degrees)
  • Unit - Move (Triggering unit) instantly to tempLoc2
  • Custom script: call RemoveLocation(udg_tempLoc1)
  • Custom script: call RemoveLocation(udg_tempLoc2)

GUI Movement turned to custom script (JASS)

function Trig_JASS_movement_Actions takes nothing returns nothing
    set udg_tempUnit = GetTriggerUnit()
    set udg_tempLoc1 = GetUnitLoc(udg_tempUnit)
    set udg_tempLoc2 = PolarProjectionBJ(udg_tempLoc1, 5.00, GetUnitFacing(udg_tempUnit))
    call SetUnitPositionLoc( GetTriggerUnit(), udg_tempLoc2 )
    call RemoveLocation(udg_tempLoc1)
    call RemoveLocation(udg_tempLoc2)
endfunction

Replacing Global Variables with Locals

function Trig_JASS_movement_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real facing = GetUnitFacing(u)
    local location loc1 = GetUnitLoc(u)
    local location loc2 = PolarProjectionBJ(loc1, 5.00, facing)
    call SetUnitPositionLoc( u, loc2)
    call RemoveLocation(loc1)
    call RemoveLocation(loc2)
    set u = null
    set loc1 = null
    set loc2 = null
endfunction

PolarProjectionBJ function

function PolarProjectionBJ takes location source, real dist, real angle returns location
    local real x = GetLocationX(source) + dist * Cos(angle * bj_DEGTORAD)
    local real y = GetLocationY(source) + dist * Sin(angle * bj_DEGTORAD)
    return Location(x, y)
endfunction

Replacing PolarProjectionBJ with the natives it uses

function Trig_JASS_movement_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local location loc1 = GetUnitLoc(u)
    local real facing = GetUnitfacing(u)
    local real x = GetLocationX(loc1) + 5 * Cos(facing * bj_DEGTORAD)
    local real y = GetLocationY(loc1) + 5 * Sin(facing * bj_DEGTORAD)
    local location loc2 = Location(x, y)
    
    call SetUnitPositionLoc( u, loc2)
    
    call RemoveLocation(loc1)
    call RemoveLocation(loc2)
    
    set u = null
    set loc1 = null
    set loc2 = null
endfunction

Replacing GetLocationX/Y with GetUnitX/Y and removing loc1

function Trig_JASS_movement_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real facing = GetUnitFacing(u)
    local real x = GetUnitX(u) + 5 * Cos(facing * bj_DEGTORAD)
    local real y = GetUnitY(u) + 5 * Sin(facing * bj_DEGTORAD)
    local location loc2 = Location(x, y)
    
    call SetUnitPositionLoc( u, loc2)
    
    call RemoveLocation(loc2)
    
    set u = null
    set loc2 = null
endfunction

Adding (facing * bj_DEGTORAD) to "facing" variable to avoid repeating function AND replacing SetUnitPositionLoc(u, loc2) with SetUnitX/Y while removing loc2

function Trig_JASS_movement_Actions takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local real facing = (GetUnitFacing(u) * bj_DEGTORAD)
    local real x = GetUnitX(u) + 5 * Cos(facing)
    local real y = GetUnitY(u) + 5 * Sin(facing)
    
    call SetUnitX(u, x)
    call SetUnitY(u, y)
    
    set u = null
endfunction

I hope it makes it clear.

 

[MasterTrainer]

I knew it.