[JASS] Random Rect...XY...

[mckill2009]

SOLVED!

Why the unit is not created in RANDOM locations in this setup?...

    local integer lev = GetRandomInt(1, 10)
    local rect r = bj_mapInitialPlayableArea   
    local location l = Location(GetRandomReal(GetRectMinX(r), GetRectMaxX(r)), GetRandomReal(GetRectMinY(r), GetRectMaxY(r)))
    local unit u = CreateUnitAtLoc(Player(14), ChooseRandomCreep(lev), l, bj_UNIT_FACING)
    call RemoveRect(r)
    call RemoveLocation(l)
    set u = null
    set l = null
    set r = null

While this is OK...

    local integer lev = GetRandomInt(1, 10)   
    local location l = Location(GetRandomReal(GetRectMinX(bj_mapInitialPlayableArea), GetRectMaxX(bj_mapInitialPlayableArea)), GetRandomReal(GetRectMinY(bj_mapInitialPlayableArea), GetRectMaxY(bj_mapInitialPlayableArea))) 
    local unit u = CreateUnitAtLoc(Player(14), ChooseRandomCreep(lev), l, bj_UNIT_FACING)
    call RemoveLocation(l)
    set u = null
    set l = null

 

[Dr. Boom]

Well, who care as long the other way works

No joke don't know, seems to be your local rect r makes an error, but hey anyway we don't use locations, we use x and y coordinates! .. also if you just create the unit and do nothing more with it, you don't need to use an extra local unit u variable.

 

[mckill2009]

No error in rect r local, just the RANDOM creep spawn on locations doesnt work...

And yeah I can use coordinates ofc, but I just want to know why the above doesnt work properly...

 

[Bribe]

call RemoveRect(r)

- You don't want to remove bj_mapInitialPlayableArea. Delete this line and it will work.

local rect r = bj_mapInitialPlayableArea   
local unit u = CreateUnit(Player(14), ChooseRandomCreep(GetRandomInt(1, 10)), GetRandomReal(GetRectMinX(r), GetRectMaxX(r)), GetRandomReal(GetRectMinY(r), GetRectMaxY(r)), 0)
set u = null
set r = null

 

[mckill2009]

A simple solution but it worked!...thanks Bribe!...

function AttackAction takes nothing returns nothing
    local rect r = bj_mapInitialPlayableArea   
    local real x = GetRandomReal(GetRectMinX(r), GetRectMaxX(r)) 
    local real y = GetRandomReal(GetRectMinY(r), GetRectMaxY(r))
    call CreateUnit(Player(14), ChooseRandomCreep(GetRandomInt(1, 10)), x, y, bj_UNIT_FACING)
    set r = null
endfunction