[Solved] "Missing end block" compilation error

[Death Adder]

I can't seem to find where the missing end block is...

When I disabled this trigger it disappeared so it's somewhere here.

All it's supposed to do is split all 12 players + 3 neutrals into 3 teams.

function Trig_Map_Inital_Player_Team_Settings_Actions takes nothing returns nothing
    local integer i = 0
    local integer j
    local player p
    loop
        exitwhen i > 14
        p = Player(i)
        j = 0
        if ModuloInteger(i, 3) == 0 then                                    // team 0
            call ForceAddPlayer( udg_mapInit_playerG_team[0], p )
            loop
                if j == i then j = j + 1 endif
                exitwhen j > 14
                if ModuloInteger(j, 3) == 0 then
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_ALLIED_VISION )
                else
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_UNALLIED )
                endif
                set j = j + 1
            endloop
        elseif ModuloInteger(i, 3) == 1 then                                //Team 1
            call ForceAddPlayer( udg_mapInit_playerG_team[1], p )
            loop
                if j == i then j = j + 1 endif
                exitwhen j > 14
                if ModuloInteger(j, 3) == 1 then
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_ALLIED_VISION )
                else
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_UNALLIED )
                endif
                set j = j + 1
            endloop
        elseif ModuloInteger(i, 3) == 2 then                                //team 2
            call ForceAddPlayer( udg_mapInit_playerG_team[2], p )
            loop
                if j == i then j = j + 1 endif
                exitwhen j > 14
                if ModuloInteger(j, 3) == 2 then
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_ALLIED_VISION )
                else
                    call SetPlayerAllianceStateBJ( p, Player(j), bj_ALLIANCE_UNALLIED )
                endif
                set j = j + 1
            endloop
        else
            //call DisplayTimedTextToPlayer(GetLocalPlayer(), 0, 0, 15, "fuck's wrong?")
        endif
        set i = i + 1
    endloop
endfunction

//===========================================================================
function InitTrig_Map_Inital_Player_Team_Settings takes nothing returns nothing
    set gg_trg_Map_Inital_Player_Team_Settings = CreateTrigger(  )
    call TriggerAddAction( gg_trg_Map_Inital_Player_Team_Settings, function Trig_Map_Inital_Player_Team_Settings_Actions )
endfunction

 

[Flux]

if j == i then j = j + 1 endif

Is this even legit??

 

[Death Adder]

if j == i then j = j + 1 endif
Is this even legit??

I thought so? Why wouldn't it?

edit: apparently that was it (And I also took the oppertunity to add in all the missing "set") lol >.<

edit 2: Maybe it works in some other programming languages because you use the {} brackets instead of just indents I guess?

You know like writing if true/false then { do thing } endif

 

[Chaosy]

Try it in Zinc. It uses { } just like C and Java

 

[edo494]

the problem here is that Jass is made in such a way that everything has to be placed on separate line, so every expression must occupy one and only one line, and no two expressions can be in same line, so you have to split it

 

[LeP]

the problem here is that Jass is made in such a way that everything has to be placed on separate line, so every expression must occupy one and only one line, and no two expressions can be in same line, so you have to split it

what you describe is usually called a statement.
expressions are things you can return or use as an argument to a function call or things you an assign a variable to or things you can use as an array index or ... aka. values.

 

[edo494]

it depends on language, but something like "a + 3 / b" is more of expression than a statement to me personally. But yes I can be very wrong in the naming

 

[Chaosy]

This compiles for me.

//! zinc
	library waddup
	{
		function onInit()
		{
			if(true){BJDebugMsg("hej");}
		}
	}
//! endzinc

 

[edo494]

yes but that is zinc, and it will obviously replace it with new lines and endif blocks

 

[Chaosy]

So? I am just presenting solutions.

 

[edo494]

he wrote it in pure Jass, chances are he wont use Zinc, one of the reasons may be that he doesnt use JNGP for any reason, which kind of limits usage of Zinc and vJass to, well, 0.

 

[Death Adder]

Yeah, I'd probably make even more mistakes if I had to remember to always use the brackets or semicolons.

I just didn't realise that I couldn't put one liners on one line like I've done elsewhere.

Learning new things is for when I come to the point that what I already know is insufficient for my needs.

 

[Anitarf]

I also had trouble with semicolons when I started writing in zinc (had no trouble with brackets though), but you get used to it. I still forget them from time to time, but it's the first thing I check when I get a compile error so the errors get fixed quickly and aren't really an issue. Nowadays however, when I occasionally still go back to JASS (like when I'm writing examples for people who don't use zinc), I find it really tedious to write all those "call"s and "set"s and "end*"s and "globals" and so on and so on. So I'd recommend zinc as well.

 

[Dr Super Good]

I thought so? Why wouldn't it?

Because JASS syntax does not permit that?

edit 2: Maybe it works in some other programming languages because you use the {} brackets instead of just indents I guess?

Other languages such as C/C++ and Java have special syntax cases to support such lines. Specifically they support blocks of a single statement without having to declare a block.

if (sometest)
    dosomething();

Also they are not line aware to some extent due to the end of statement terminator so you can chain many statements together on the same line, although not recommended due to how unreadable it makes things.

dosomething(); dosomething(); dosomething(); dosomethingelse(); dosomethingevenmore();

Or in the previous case...

if (sometest) dosomething();

JASS just does not support this due to how the language syntax is specified.

 

[lang_dye]

this is jass,not other language.

 

[Anitarf]

Other languages such as C/C++ and Java have special syntax cases to support such lines. Specifically they support blocks of a single statement without having to declare a block.

if (sometest)
    dosomething();

Forgot to mention, this is also true in zinc, you don't need the brackets for one-statement blocks.

 

[Arad MNK]

this is jass,not other language.

Thanks for reminding.