How to trigger permanent Immolation?

[Geshishouhu]

Any idea? It is like an aura in GUI or Jass version that can deal constant damage to enemy units around the hero.

Update: I know there is such an ability, I just want to make it by GUI or Jass.

 

[Garfield1337]

There's permanent immolation ability by default; check out Abilities\Special\Units.

 

[Geshishouhu]

There's permanent immolation ability by default; check out Abilities\Special\Units.

Yea, I know. I just want to make it by using GUI or Jass.
I also have a problem with the default one. It seems the damage option of the spell only has one level.

 

[Kusanagi Kuro]

I think u just need to add a buff to ur unit when it learns that skill. Then add it to a unit group. After that, create a periodic trigger to pick every unit in that unit group, then deal damage to the nearby enemies. U can setup everything for ur spell (Damage, AOE, etc).

 

[Geshishouhu]

I think u just need to add a buff to ur unit when it learns that skill. Then add it to a unit group. After that, create a periodic trigger to pick every unit in that unit group, then deal damage to the nearby enemies. U can setup everything for ur spell (Damage, AOE, etc).

Thanks a lot. I did something like this and it seemed to work.

function Trig_XG_001 takes nothing returns boolean
    return(IsUnitEnemy(GetFilterUnit(),GetOwningPlayer(gg_unit_Hblm_0002)))
endfunction
function Trig_XG_Actions takes nothing returns nothing
    local group g
    local unit u
    local location p
    local real a = I2R(GetUnitAbilityLevel(gg_unit_Hblm_0002,'A353'))*50.+300.
    set p = GetUnitLoc(gg_unit_Hblm_0002)
    set g = GetUnitsInRangeOfLocMatching(a, p,Condition(function Trig_XG_001))
    set u = FirstOfGroup(g) 
    loop
        exitwhen u==null
        set u = FirstOfGroup(g)
        call UnitDamageTarget(gg_unit_Hblm_0002,u,I2R(GetHeroInt(gg_unit_Hblm_0002,false)),true,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_DEMOLITION,WEAPON_TYPE_WHOKNOWS)
        call GroupRemoveUnit(g,u)
    endloop 
    call DestroyGroup(g)
    call RemoveLocation(p)
    set g = null
    set u = null
    set p = null
endfunction

//===========================================================================
function InitTrig_XG takes nothing returns nothing
    set gg_trg_XG = CreateTrigger()
    call TriggerRegisterTimerEventPeriodic( gg_trg_XG, 1.00 )
    call TriggerAddAction(gg_trg_XG, function Trig_XG_Actions)
endfunction

 

[Kusanagi Kuro]

Ure welcome. .

 

[Maker]

Try to get rid of the location, use GetUnitX and GetUnitY instead. You could then use IsUnitInRangeXY

 

[Malhorne]

This is better :

function Trig_XG_001 takes nothing returns boolean
    return(IsUnitEnemy(GetFilterUnit(),GetOwningPlayer(gg_unit_Hblm_0002)))
endfunction
function Trig_XG_Actions takes nothing returns nothing
    local group g = CreateGroup( )
    local unit u
    local real x = GetUnitX( gg_unit_Hblm_0002 )
    local real y = GetUnitY( gg_unit_Hblm_0002 )
    local real a = I2R(GetUnitAbilityLevel(gg_unit_Hblm_0002,'A353'))*50.+300.
    call GroupEnumUnitsInRange( g, x, y, a, Condition( function Trig_XG_001 ) )
    loop
        set u = FirstOfGroup( g )
        exitwhen u==null
        call UnitDamageTarget(gg_unit_Hblm_0002,u,I2R(GetHeroInt(gg_unit_Hblm_0002,false)),true,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_DEMOLITION, null)
        call GroupRemoveUnit(g,u)
    endloop 
    call DestroyGroup(g)
    set g = null
endfunction

//===========================================================================
function InitTrig_XG takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterTimerEvent( t, 1.00, true )
    call TriggerAddAction(t, function Trig_XG_Actions)
    set t = null
endfunction

 

[Doomlord]

This is better :

function Trig_XG_001 takes nothing returns boolean
    return(IsUnitEnemy(GetFilterUnit(),GetOwningPlayer(gg_unit_Hblm_0002)))
endfunction
function Trig_XG_Actions takes nothing returns nothing
    local group g
    local unit u
    local real x = GetUnitX( gg_unit_Hblm_0002 )
    local real y = GetUnitY( gg_unit_Hblm_0002 )
    local real a = I2R(GetUnitAbilityLevel(gg_unit_Hblm_0002,'A353'))*50.+300.
    call GroupEnumUnitsInRange( g, x, y, a, Condition( function Trig_XG_001 ) )
    loop
        set u = FirstOfGroup( g )
        exitwhen u==null
        call UnitDamageTarget(gg_unit_Hblm_0002,u,I2R(GetHeroInt(gg_unit_Hblm_0002,false)),true,false,ATTACK_TYPE_CHAOS,DAMAGE_TYPE_DEMOLITION,WEAPON_TYPE_WHOKNOWS)
        call GroupRemoveUnit(g,u)
    endloop 
    call DestroyGroup(g)
    set g = null
    set u = null
endfunction

//===========================================================================
function InitTrig_XG takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterTimerEvent( t, 1.00, true )
    call TriggerAddAction(t, function Trig_XG_Actions)
    set t = null
endfunction

Your code won't work because group g is never created.

Fix'd below.

function Trig_XG_Conditions takes nothing returns boolean
    local group g = CreateGroup()
    local unit u
    local real r = I2R(GetHeroInt(gg_unit_Hblm_0002, false))
    local player p = GetOwningPlayer(gg_unit_Hblm_0002)

    call GroupEnumUnitsInRange(g, GetUnitX(gg_unit_Hblm_0002), GetUnitY(gg_unit_Hblm_0002), I2R(GetUnitAbilityLevel(gg_unit_Hblm_0002,'A353'))*50.+300., null)

    loop
        set u = FirstOfGroup(g)
        exitwhen u == null

        if IsUnitEnemy(u, p) then
            call UnitDamageTarget(gg_unit_Hblm_0002, u, r, true, false, ATTACK_TYPE_CHAOS, DAMAGE_TYPE_DEMOLITION, null)
        endif
        
        call GroupRemoveUnit(g, u)
    endloop
    
    call DestroyGroup(g)

    // u doesn't need to be nulled because the loop stops when u == null
    set g = null
    
    return false
endfunction

//===========================================================================
function InitTrig_XG takes nothing returns nothing
    local trigger t = CreateTrigger()
    call TriggerRegisterTimerEvent(t, 1.00, true)
    call TriggerAddCondition(t, function Trig_XG_Conditions)
    set t = null
endfunction

 

[Malhorne]

Oh yes forgot the initiate xD !
Thanks Doomlord for correting this dumb error ^^

EDIT : Corrected.

 

[Doomlord]

Oh yes forgot the initiate xD !
Thanks Doomlord for correting this dumb error ^^

EDIT : Corrected.

You are welcome

And no it is not a dumb error. It is a slip-up that we all made from time to time

 

[Geshishouhu]

You are welcome

And no it is not a dumb error. It is a slip-up that we all made from time to time

Thanks for the help.

@Malhorne, thanks you all the same.

Mistake, message deleted. Sorry.

 

[Malhorne]

Oh you're welcome

 

[Maker]

You might want to include int bonuses, set the boolean to true in GetHeroInt