[Solved] How to stop a peasant from building?

[stan0033]

This might be a silly question, but what's the correct way to detect if a peasant is ordered to build ANY building and order him to stop?

 

[RvP21]

There is not an easy way to see if a peasant has a building order when they are moving. The only way i know how to see if a peasant has been ordered to build something is the following: if you click on an individual peasant, you can see if the building button is highlighted. If it is highlighted, the peasant (or any other worker) is ordered to build a structure.
If you want your worker to stop, just give him any other order (move, patrol, etc.)

 

[Warseeker]

Create three variables:

BuildTrigger = Trigger (Array)
i = Integer
t = Trigger

Now, create a trigger called "Prevent Build", convert it to custom text and copy paste this script in it:

function BuildActions takes nothing returns nothing
    set udg_i = 0
    set udg_t = GetTriggeringTrigger()
    loop
        exitwhen udg_i>11
        if udg_t == udg_BuildTrigger[udg_i] then
            call DisplayTimedTextToPlayer(Player(udg_i), 0, 0, 60, "You cannot build")
            call ForceUICancelBJ( Player(udg_i) )
            return
        endif
        set udg_i = udg_i + 1
    endloop
endfunction

function InitTrig_Prevent_Build takes nothing returns nothing
    local integer i = 0
    loop
        exitwhen i>11
        set udg_BuildTrigger[i] = CreateTrigger()
        call TriggerAddAction(udg_BuildTrigger[i], function BuildActions)
        if GetLocalPlayer() == Player(i) then
            call TriggerRegisterGameEvent(udg_BuildTrigger[i], EVENT_GAME_BUILD_SUBMENU)
        endif
        set i = i + 1
    endloop
endfunction

Whenever the worker open up the build menu, it will close automatically.

 

[stan0033]

you couuld do it in GUI tho with some scripts but ok.


Does this work also for custom buildings? cuz the build order for these starts with custom_ + the ID

Would you modify your code to include condition "if unit has buff X"?

 

[Itachi2020]

Hi Stan

I spent quite a lot of time trying to solve this issue but there didn't seem to be a simple way to just stop the construction.

I had to resort to this:

Trigger

• Stop building
  • Events
    • Unit - A unit Begins construction
  • Conditions
    • (Unit-type of (Constructing structure)) Equal to Building
  • Actions
    • Unit - Kill (Constructing structure)
    • Player - Add 250 to (Owner of (Triggering unit)).Current lumber

Obviously add any extra conditions you may need. However, if there are multiple buildings obv you will need to do this trigger a few times with variants.

Not the most streamlined way but in terms of a GUI solution, it works.

 

[stan0033]

look at warseeker's code. He did it perfectly. I jsut asked him to add a buff check condition but he probably didnt see

@Warseeker can you edit your code to check if the peasant has a specific buff?

 

[Warseeker]

function CancelBuild takes nothing returns nothing
    if IsUnitSelected(GetEnumUnit(), Player(udg_i)) == true and UnitHasBuffBJ(GetEnumUnit(), 'BUfa') == true then //'BUfa' = Frost Armor Buff
        call ForceUICancelBJ( Player(udg_i) )
        call DisplayTimedTextToPlayer(Player(udg_i), 0, 0, 60, "This worker cannot build")
    else
    endif
endfunction

function BuildActions takes nothing returns nothing
    set udg_i = 0
    set udg_t = GetTriggeringTrigger()
    loop
        exitwhen udg_i>11
        if udg_t == udg_BuildTrigger[udg_i] then
            set bj_wantDestroyGroup = true
            call ForGroupBJ( GetUnitsOfPlayerAndTypeId(Player(udg_i), 'hpea'), function CancelBuild) //'hpea' = Peasant
            return
        endif
        set udg_i = udg_i + 1
    endloop
endfunction

function InitTrig_Prevent_Build takes nothing returns nothing
    local integer i = 0
    loop
        exitwhen i>11
        set udg_BuildTrigger[i] = CreateTrigger()
        call TriggerAddAction(udg_BuildTrigger[i], function BuildActions)
        if GetLocalPlayer() == Player(i) then
            call TriggerRegisterGameEvent(udg_BuildTrigger[i], EVENT_GAME_BUILD_SUBMENU)
        endif
        set i = i + 1
    endloop
endfunction

 

[Dr Super Good]

This might be a silly question, but what's the correct way to detect if a peasant is ordered to build ANY building and order him to stop?

The peasant gets issued a point target order of the building's unit type (4 character raw data value). This can be detected like any point target order and also cancelled like any point target order. Cancelling the order requires that the unit be pause cycled as the event fires before the actual order is issued so issuing "stop" or other approaches would require being done in a separate trigger thread to occur in the correct order.

This will not detect if a peasant is ordered to assist construction of an existing building. In this case the peasant is not building the building, but rather repairing an existing building to make it construct faster.

 

[stan0033]

function CancelBuild takes nothing returns nothing
    if IsUnitSelected(GetEnumUnit(), Player(udg_i)) == true and UnitHasBuffBJ(GetEnumUnit(), 'BUfa') == true then //'BUfa' = Frost Armor Buff
        call ForceUICancelBJ( Player(udg_i) )
        call DisplayTimedTextToPlayer(Player(udg_i), 0, 0, 60, "This worker cannot build")
    else
    endif
endfunction

function BuildActions takes nothing returns nothing
    set udg_i = 0
    set udg_t = GetTriggeringTrigger()
    loop
        exitwhen udg_i>11
        if udg_t == udg_BuildTrigger[udg_i] then
            set bj_wantDestroyGroup = true
            call ForGroupBJ( GetUnitsOfPlayerAndTypeId(Player(udg_i), 'hpea'), function CancelBuild) //'hpea' = Peasant
            return
        endif
        set udg_i = udg_i + 1
    endloop
endfunction

function InitTrig_Prevent_Build takes nothing returns nothing
    local integer i = 0
    loop
        exitwhen i>11
        set udg_BuildTrigger[i] = CreateTrigger()
        call TriggerAddAction(udg_BuildTrigger[i], function BuildActions)
        if GetLocalPlayer() == Player(i) then
            call TriggerRegisterGameEvent(udg_BuildTrigger[i], EVENT_GAME_BUILD_SUBMENU)
        endif
        set i = i + 1
    endloop
endfunction

uhhh @Warseeker , also my Engineer unit can build buildings. My mistake. You now made it to check the peasant instead of any unit that can build


EDIT: It's OK, I added call ForGroupBJ( GetUnitsOfPlayerAndTypeId(Player(udg_i), 'engi'), function CancelBuild)