[JASS] Dubbel free

Ciebron · Aug 30, 2010

Hai gays and gals. I have a little problem with my dot system. I get a dubbel free of typ DotInterface, when i destroy it. I think the problem is in the "indexer". Well time to go to work cya all later and thanks in advance

JASS:

    globals
        private constant    integer     FPS                     = 30
        private constant    real        FREC                    = 1/FPS
    endglobals
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Interface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    interface DoTInterface
//*
//*        
        method DoTonLoop       takes nothing returns nothing       defaults nothing // Will trigger once even if .toGroup is true
//*    
        
        method DoTonDamage     takes nothing returns nothing       defaults nothing // Will trigger once when the unit get damaged.
//*                                                                              // If .toGroup is true then it will trigger once for every unit 
//*                                                                              
        method DoTonFinish     takes nothing returns nothing       defaults nothing // Will run when the duration is over
//*
//*        
        method DoTonDeath      takes nothing returns nothing       defaults nothing // Will trigger every interval if the unit is death
//*                                                                              // If you want the trigger to stop destroy the struct
//*                                                                              // If .toGroup is true it wont repeat on dead units
//*                                                                            
    endinterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT struct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    struct DoTAdV extends DoTInterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT aka Damage over Time
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*    
        boolean         toDestroy           = true
        //NYI//boolean         toGroup             = false
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*
        unit            DotSource
        unit            DotTarget
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*  
        real            DotDamage
        real            DotDuration
        real            DotInterval
        real            DotTick
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* 
        integer         DotDamageType       = DAMAGE_TYPE_SPELL
        integer         DotIndex
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*

        //NYI// group           DotGroup
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*       
static  timer           DotTimer
static  integer array   IndexArray
static  integer         Index               = 0
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Damage Loop
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯        
        static method Loop takes nothing returns nothing
            local thistype this
            local integer index = .Index - 1
            
            loop
                exitwhen (index < 0)
                
                set this = .IndexArray[index]
                
                set .DotTick = .DotTick + 0.03
                
                if .DotTick >= .DotInterval then
                    
                    call UnitDamageTargetEx(.DotSource, .DotTarget,.DotDamage ,ATTACK_TYPE_MAGIC, .DotDamageType,false)
            
                    call .DoTonDamage()
                    
                        set .DotDuration        = .DotDuration - .DotInterval

                        if GetWidgetLife(.DotTarget) <= .305 then
                        
                            call .DoTonDeath()
                            
                        endif
                        
                        if .DotDuration <= 0. then
                        
                            call .DoTonFinish()
                            
                            if .toDestroy then
                            
                                call .destroy()
                                
                            endif
                            
                        endif
                    
                    set .DotTick = 0
                        
                endif
                    
                set index = index - 1
            endloop
            
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Start DoT method
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        method DotStart takes unit Target, real Damage, real Intervals, real Duration returns nothing
            //Yay to berb for giving me the idea to this method from hes projectile system
            if not (Duration <= 0.0) or not (Intervals <= 0.0) or not (Damage == 0.0) or Duration < Intervals then
                
                set .DotTarget             = Target
                set .DotDamage             = Damage
                set .DotInterval           = Intervals
                set .DotDuration           = Duration
                set .DotIndex              = .Index
                
                set .IndexArray[.Index]    = this
            
                set .Index                 = .Index + 1

                    if .Index == 1 then
                        call TimerStart(.DotTimer, .03, true, function thistype.Loop)
                    endif
                
               //NYI//if .toGroup then
                    //    set .DotGroup           = CreateGroup()
                    //endif
                
            else
                
                debug call BJDebugMsg(SCOPE_PREFIX+" Failed to start DoT")
                return
                
            endif
        
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Creation
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        static method create takes unit Source, unit Target returns thistype
            local thistype this      = thistype.allocate()
            
            set .DotSource      = Source
            
            return this
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Destruction
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯      
        method onDestroy takes nothing returns nothing
        
            set .Index = .Index - 1
            set .IndexArray[.DotIndex] = .IndexArray[.Index]

            if (.Index == 0) then
                call PauseTimer(.DotTimer)
            endif
            
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Initializer
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
        static method onInit takes nothing returns nothing
        
            set thistype.DotTimer   = CreateTimer()
            
        endmethod
    
    endstruct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* End of Library
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
endlibrary

Berb · Aug 30, 2010

Double free of type: DotInterface is an error that sprouts when a struct instance is destroyed twice. When a struct is destroyed (remember it is an integer value) it is set to 0. When a struct of value "0" is destroyed, that error is displayed.

It commonly occurs when you've got many sources of death for whatever it is you're doing. If you do:

JASS:

if yourStruct != 0 then
    call yourStruct.destroy( )
endif

It will ensure that a null struct is not destroyed. The error itself is harmless, but it can be the roots of more complicated problems - it is best if you try to fix it now. Just look for all the places where you destroy your DoTAdV struct (it reads as an interface because the struct extends the interface) and ensure that there is no possibility that they could have been destroyed prior - or if they can then use an if-statement like I have shown.

Ciebron · Aug 30, 2010

Yeah i know what double free is, it just that i can't find the problem.. I have used indexer's before but this one is busting my balls

Even if i do this (which i tried before it still gives me double frees

JASS:

if .toDestroy and (this != 0) then
                                
call .destroy()
                                
endif

it works well, when there are like 1-2 instances up but when i get like 3+ it starts to double free

PS. I only destroy the struct in the loop function

Berb · Aug 31, 2010

Just to be absolutely sure.

JASS:

                        if .DotDuration <= 0. then
                        
                            call .DoTonFinish()
                            
                            if .toDestroy then
                            
                                call .destroy()
                                
                            endif
                            
                        endif

Try putting two debug messages one before and one after, make sure that this is the call that is causing the double-free error. If it is, then the error message should come between your two encapsulating messages. I don't see anything in particular that is wrong with it, and if you're ensuring that this != 0 it seems odd that the message still shows.

JASS:

                        if .DotDuration <= 0. then
                        
                            call .DoTonFinish()
                            
                            if .toDestroy and this != 0 then
                            
                                call BJDebugMsg("This should come before the error message.")
                                call .destroy()
                                call BJDebugMsg("This should come after the error message.")
                                
                            endif
                            
                        endif

Ciebron · Aug 31, 2010

Yeah the BJDebugMsg display as they should.

Berb · Aug 31, 2010

I'm not sure, I'll keep reading.

By the way I just saw this line: "//Yay to berb for giving me the idea to this method from hes projectile system" - for a second there I thought you were Bribe.

It makes no sense to me that you're getting a double-free error when you're ensuring that the struct is not null. I've got something else for you to try though; sometimes it can be logically confusing when you use the name this in a static method, and this may in fact be causing some strange unpredicted activity. When you've got a struct-variable named this in a static method it will essentially convert the method to an instance-method for that specific instance. In your loop you use both static members and instance members however you never use the thistype. prefix - my guess is that some of your names are being confused with each other internally. I'm not sure, but it is worth a try to figure out what is wrong; try changing the name of the variable (and don't cast the static method into an instance method).

Axarion · Aug 31, 2010

As far as I remeber I had this error once too, and the problem was the onDestroy method. Maybe don't use onDestroy but destroy itself and call .deallocate() at the end.

Ciebron · Sep 1, 2010

I added linkedList to the system, now it crashes wc3 instead... This system is cursed...

JASS:

library DoTSystem needs DamageSystem
//*
//* Globals
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
    globals
        private constant    integer     FPS                     = 30
        private constant    real        FREC                    = 1/FPS
    endglobals
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Interface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    interface DoTInterface
//*
//*        
        method DoTonLoop       takes nothing returns nothing       defaults nothing // Will trigger once even if .toGroup is true
//*    
        
        method DoTonDamage     takes nothing returns nothing       defaults nothing // Will trigger once when the unit get damaged.
//*                                                                              // If .toGroup is true then it will trigger once for every unit 
//*                                                                              
        method DoTonFinish     takes nothing returns nothing       defaults nothing // Will run when the duration is over
//*
//*        
        method DoTonDeath      takes nothing returns nothing       defaults nothing // Will trigger every interval if the unit is death
//*                                                                              // If you want the trigger to stop destroy the struct
//*                                                                              // If .toGroup is true it wont repeat on dead units
//*                                                                            
    endinterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT struct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    struct DoTAdV extends DoTInterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT aka Damage over Time
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*    
        boolean         toDestroy           = true
        //NYI//boolean         toGroup             = false
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*
        unit            DotSource
        unit            DotTarget
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*  
        real            DotDamage
        real            DotDuration
        real            DotInterval
        real            DotTick
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* 
        integer         DotDamageType       = DAMAGE_TYPE_SPELL
        integer         DotIndex
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*

        //NYI// group           DotGroup
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* 
private static timer DotTimer

implement List
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Damage Loop
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯        
        static method Loop takes nothing returns nothing
            local thistype this = .getFirst
            local integer index = 0
            
            loop
                exitwhen this == 0
                
                set .DotTick = .DotTick + 0.03
                
                if .DotTick >= .DotInterval then
                    
                    call UnitDamageTargetEx(.DotSource, .DotTarget,.DotDamage ,ATTACK_TYPE_MAGIC, .DotDamageType,false)
            
                    call .DoTonDamage()
                    
                        set .DotDuration        = .DotDuration - .DotInterval

                        if GetWidgetLife(.DotTarget) <= .305 then
                        
                            call .DoTonDeath()
                            
                        endif
                        
                        if .DotDuration <= 0. then
                        
                            call .DoTonFinish()
                            
                            if .toDestroy and this != 0 then
                                call .destroy()
                            endif
                            
                        endif
                    
                    set .DotTick = 0
                        
                endif
                    
                set this = .getNext
            endloop
            
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Start DoT method
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        method DotStart takes unit Target, real Damage, real Intervals, real Duration returns nothing
        
            if not (Duration <= 0.0) or not (Intervals <= 0.0) or not (Damage == 0.0) or Duration < Intervals then
                
                set .DotTarget             = Target
                set .DotDamage             = Damage
                set .DotInterval           = Intervals
                set .DotDuration           = Duration
                
                call .addList()
                call BJDebugMsg(I2S(.getLength))
                    if .getLength == 1 then
                        
                        call TimerStart(.DotTimer, .03, true, function thistype.Loop)
                    endif
                
               //NYI//if .toGroup then
                    //    set .DotGroup           = CreateGroup()
                    //endif
                
            else
                
                debug call BJDebugMsg(SCOPE_PREFIX+" Failed to start DoT")
                return
                
            endif
        
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Creation
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        static method create takes unit Source returns thistype
            local thistype this      = thistype.allocate()
            
            set .DotSource      = Source
            
            return this
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Destruction
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯      
        method onDestroy takes nothing returns nothing
        
            call .removeList()

            if (.getLength == 0) then
                call BJDebugMsg("PAUSE")
                call PauseTimer(.DotTimer)
            endif
          
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Initializer
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
        static method onInit takes nothing returns nothing
        
            set thistype.DotTimer   = CreateTimer()
            
        endmethod
    
    endstruct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* End of Library
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
endlibrary

Berb · Sep 1, 2010

What if you replace your loop method with:

JASS:

        static method Loop takes nothing returns nothing
            local thistype data
            local integer index = Index - 1
            
            loop
                exitwhen (index < 0)
                
                set data = IndexArray[index]
                set data.DotTick = data.DotTick + 0.03
                
                if data.DotTick >= data.DotInterval then
                    call UnitDamageTargetEx(data.DotSource, data.DotTarget, data.DotDamage, ATTACK_TYPE_MAGIC, data.DotDamageType,false)
                    call data.DoTonDamage() 
                    set data.DotDuration = data.DotDuration - data.DotInterval

                    if GetWidgetLife(data.DotTarget) <= .305 then
                        call data.DoTonDeath()
                        
                    endif
                    if data.DotDuration <= 0. then
                        call data.DoTonFinish()
                        if data.toDestroy and data != 0 then
                            call data.destroy()
                            
                        endif
                    endif
                    set data.DotTick = 0
                        
                endif
                    
                set index = index - 1
                
            endloop
            
        endmethod

It's the exact same code but instead of this I've used the name data - I seem to recall running into some tiny problems like this when avoiding explicitly defining scope parameters. Do not use the name this, there is no necessity of doing so and if anything it just makes your code harder to read. When I look at a static method I do not expect to see instance method implementations.

Either way, try it out; get back to meh.

Ciebron · Sep 1, 2010

Well berb your way didn't work either but i have solved it now with "List". Thank all for your intrest anyway

EDIT:

well this is the code any ideas for improvement?

JASS:

library DoTSystem needs DamageSystem
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoTSystem by Ciebron
//* Beta version
//* 
//* Credits
//* Berb for inspiring me to some of the code
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Globals
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
    globals
        private constant    integer     FPS                     = 30
        private constant    real        FREC                    = 1/FPS
    endglobals
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Interface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    interface DoTInterface
//*
//*        
        method DoTonLoop       takes nothing returns nothing       defaults nothing // Will trigger once even if .toGroup is true
//*    
        
        method DoTonDamage     takes nothing returns nothing       defaults nothing // Will trigger once when the unit get damaged.
//*                                                                              // If .toGroup is true then it will trigger once for every unit 
//*                                                                              
        method DoTonFinish     takes nothing returns nothing       defaults nothing // Will run when the duration is over
//*
//*        
        method DoTonDeath      takes nothing returns nothing       defaults nothing // Will trigger every interval if the unit is death
//*                                                                              // If you want the trigger to stop destroy the struct
//*                                                                              // If .toGroup is true it wont repeat on dead units
//*                                                                            
    endinterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT struct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
    struct DoTAdV extends DoTInterface
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* DoT aka Damage over Time
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*    
        boolean         toDestroy           = true
        //NYI//boolean         toGroup             = false
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*
        unit            DotSource
        unit            DotTarget
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//*  
        real            DotDamage
        real            DotDuration
        real            DotInterval
        real            DotTick
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* 
        integer         DotDamageType       = DAMAGE_TYPE_SPELL
        integer         DotIndex
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//*

        //NYI// group           DotGroup
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* 
private static timer DotTimer
private static integer array IndexStack
private static integer Index = 0

implement List
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Damage Loop
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯        
        static method Loop takes nothing returns nothing
            local thistype this = .getFirst()
            
            loop
                exitwhen this == 0
                
                set .DotTick = .DotTick - 0.03
                
                if .DotTick <= 0.0 then
                    
                    call UnitDamageTargetEx(.DotSource, .DotTarget,.DotDamage ,ATTACK_TYPE_MAGIC, .DotDamageType,false)
            
                    call .DoTonDamage()
                    
                        set .DotDuration        = .DotDuration - .DotInterval
                        
                        if .DotDuration <= 0. then
                        
                            call .DoTonFinish()
                            
                            if .toDestroy then
                                call .destroy()
                            endif
                            
                        elseif GetWidgetLife(.DotTarget) <= .305 then
                        
                            call .DoTonDeath()
                            
                            if .toDestroy then
                                call .destroy()
                            endif
                            
                        endif
                    
                    set .DotTick = .DotInterval
                        
                endif
                    
                set this = .getNext()
            endloop
            
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Start DoT method
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        method DotStart takes unit Target, real Damage, real Intervals, real Duration returns nothing
        
            if not (Duration <= 0.0) or not (Intervals <= 0.0) or not (Damage == 0.0) or Duration < Intervals then
                
                set .DotTarget             = Target
                set .DotDamage             = Damage
                set .DotInterval           = Intervals
                set .DotDuration           = Duration
                set .DotTick               = Intervals
                
                call .addList()
                
                    if .getLength() == 1 then
                        call TimerStart(.DotTimer, .03, true, function thistype.Loop)
                    endif
                
               //NYI//if .toGroup then
                    //    set .DotGroup           = CreateGroup()
                    //endif
                
            else
                
                debug call BJDebugMsg(SCOPE_PREFIX+" Failed to start DoT")
                return
                
            endif
        
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
//* Creation
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯ 
        static method create takes unit Source returns thistype
            local thistype this      = thistype.allocate()
            
            set .DotSource      = Source
            
            return this
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Destruction
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯      
        method onDestroy takes nothing returns nothing
        
            call .removeList()
            
            if (.getLength() == 0) then
                call PauseTimer(.DotTimer)
            endif
        endmethod
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* Initializer
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
        static method onInit takes nothing returns nothing
        
            set thistype.DotTimer   = CreateTimer()
            
        endmethod
    
    endstruct
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
//* End of Library
//* ¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯¯
endlibrary

Berb · Sep 1, 2010

For a constantly iterated loop structure you're definitely better off using arrays than a "list" system. It really doesn't matter what order you sift through your data, as long as it is all done properly.

Ciebron · Sep 2, 2010

Yeah i know but i keep it like this for now.

Deaod · Sep 3, 2010

Youve forgotten to update DotIndex in the onDestroy method (of your original code).

[JASS] Dubbel free

Similar threads