[JASS] Dealing completly fixed damage

[looking_for_help]

Hello all,

I was woundering if there is a way to deal a certain amount of damage to a unit with completly ignoring its armortypes/resistances/customized damage table/everything.

Of course it could be done with

call SetUnitState(target,UNIT_STATE_LIFE,GetUnitState(target,UNIT_STATE_LIFE) - amount)

BUT if the unit dies, the damager wont get any xp (as there is no damager).

Is there a way?

Greetings,
lfh

 

[Cokemonkey11]

You can conditionally check if the unit will die to the damage - if so, make the damager kill it instantly, otherwise, use SetWidgetLife()

 

[looking_for_help]

You can conditionally check if the unit will die to the damage - if so, make the damager kill it instantly,

Yeah, but how?

KillUnit(whichUnit)

Does not influence the damager XP either.

 

[Cokemonkey11]

//let u be a global unit with an unknown quantity of hp
//let attacker be a global unit who must deal exactly fixed r damage to u.
//let bigD be a global real whose value is significantly larger than r

scope example initializer i
    private function i takes nothing returns nothing
        local real hp=GetUnitState(u,UNIT_STATE_LIFE)
        if hp>r then
            call SetUnitState(u,hp-r)
        else
            call UnitDamageTarget(attacker,u,bigD,null,DAMAGE_TYPE_UNIVERSAL,null)
        endif
    endfunction
endscope

make sense?

 

[looking_for_help]

make sense?[/QUOTE]

Yes, but what if I customized the damage table in that way that I set damage from Spells to zero for a certain armor type? Then even the biggest damage amount won't help.

Of course I could use all different damagetypes in a row but then a damageevent will be fired everytime the unit is immune to the corresponding attack. Even worse, the amount of damage is returned as 1 although it is zero (unit doesn't get damaged). Therefore one can't filter it out by checking for zero damage.

 

[Cokemonkey11]

Yes, but what if I customized the damage table...

Then this method wouldn't work. Did you customize the damage table in that way?

 

[looking_for_help]

Then this method wouldn't work. Did you customize the damage table in that way?

For one of the maps I'm currently developing, yes. That's why I was woundering how this could be achieved.

 

[Cokemonkey11]

Can you just choose a DAMAGE_TYPE_? which will effect all units?

I can't imagine you have a damage table where no damagetype is able to effect all armor types.

Perhaps the solution lies in choosing an attack type as you discovered here?

 

[looking_for_help]

Perhaps the solution lies in choosing an attack type as you discovered here?

Lol, I totally forgot about this :facepalm:

This works now allways, even if you set the whole damage table to zero:

function DealFixDamage takes unit source, unit target, real amount returns nothing

    local real UNIT_MIN_LIFE = 0.406
    local attacktype ATTACK_TYPE_UNIVERSAL = ConvertAttackType(7)

    local real beforeHitpoints = GetUnitState(target,UNIT_STATE_LIFE)
    local real newHitpoints = beforeHitpoints - amount

    // This is used to have access to the damage amount in the DamageEvent
    set udg_fixDamage = amount

    if newHitpoints >= UNIT_MIN_LIFE then
        call SetUnitState(target,UNIT_STATE_LIFE,newHitpoints)
        call UnitDamageTarget( source, target, 0, true, false, ATTACK_TYPE_UNIVERSAL, DAMAGE_TYPE_UNIVERSAL, null)
    else
        call SetUnitInvulnerable( target, false )
        call UnitDamageTarget( source, target, 1000000000, true, false, ATTACK_TYPE_UNIVERSAL, DAMAGE_TYPE_UNIVERSAL, null)
    endif

    set ATTACK_TYPE_UNIVERSAL = null

endfunction

function Trig_DamageEvent_Actions takes nothing returns nothing
    set udg_damage = GetEventDamage()

    // Check if the damage was a fixed damage
    if udg_fixDamage != 0 then
        set udg_damage = udg_fixDamage
        set udg_fixDamage = 0
    endif

    // Display the correct amount of damage
    call BJDebugMsg("Damage: "+R2S(udg_damage))
        
endfunction

function test takes nothing returns nothing
    // Do 100 fixed damage
    call DealFixDamage( source, target, 100.00 )
endfunction

Cool, this really works great. Thanks!

lfh