Well, it has to do with how Blizzard coded the GUI cinematic toggle action. Here is an excerpt from their Blizzard.j that explains what it does:
JASS:
//===========================================================================
// Makes many common UI settings changes at once, for use when beginning and
// ending cinematic sequences. Note that some affects apply to all players,
// such as game speed. This is unavoidable.
// - Clear the screen of text messages
// - Hide interface UI (letterbox mode)
// - Hide game messages (ally under attack, etc.)
// - Disable user control
// - Disable occlusion
// - Set game speed (for all players)
// - Lock game speed (for all players)
// - Disable black mask (for all players)
// - Disable fog of war (for all players)
// - Disable world boundary fog (for all players)
// - Dim non-speech sound channels
// - End any outstanding music themes
// - Fix the random seed to a set value
// - Reset the camera smoothing factor
//
function CinematicModeExBJ takes boolean cineMode, force forForce, real interfaceFadeTime returns nothing
// If the game hasn't started yet, perform interface fades immediately
if (not bj_gameStarted) then
set interfaceFadeTime = 0
endif
if (cineMode) then
// Save the UI state so that we can restore it later.
if (not bj_cineModeAlreadyIn) then
set bj_cineModeAlreadyIn = true
set bj_cineModePriorSpeed = GetGameSpeed()
set bj_cineModePriorFogSetting = IsFogEnabled()
set bj_cineModePriorMaskSetting = IsFogMaskEnabled()
set bj_cineModePriorDawnDusk = IsDawnDuskEnabled()
set bj_cineModeSavedSeed = GetRandomInt(0, 1000000)
endif
// Perform local changes
if (IsPlayerInForce(GetLocalPlayer(), forForce)) then
// Use only local code (no net traffic) within this block to avoid desyncs.
call ClearTextMessages()
call ShowInterface(false, interfaceFadeTime)
call EnableUserControl(false)
call EnableOcclusion(false)
call SetCineModeVolumeGroupsBJ()
endif
// Perform global changes
call SetGameSpeed(bj_CINEMODE_GAMESPEED)
call SetMapFlag(MAP_LOCK_SPEED, true)
call FogMaskEnable(false)
call FogEnable(false)
call EnableWorldFogBoundary(false)
call EnableDawnDusk(false)
// Use a fixed random seed, so that cinematics play consistently.
call SetRandomSeed(0)
else
set bj_cineModeAlreadyIn = false
// Perform local changes
if (IsPlayerInForce(GetLocalPlayer(), forForce)) then
// Use only local code (no net traffic) within this block to avoid desyncs.
call ShowInterface(true, interfaceFadeTime)
call EnableUserControl(true)
call EnableOcclusion(true)
call VolumeGroupReset()
call EndThematicMusic()
call CameraResetSmoothingFactorBJ()
endif
// Perform global changes
call SetMapFlag(MAP_LOCK_SPEED, false)
call SetGameSpeed(bj_cineModePriorSpeed)
call FogMaskEnable(bj_cineModePriorMaskSetting)
call FogEnable(bj_cineModePriorFogSetting)
call EnableWorldFogBoundary(true)
call EnableDawnDusk(bj_cineModePriorDawnDusk)
call SetRandomSeed(bj_cineModeSavedSeed)
endif
endfunction
//===========================================================================
function CinematicModeBJ takes boolean cineMode, force forForce returns nothing
call CinematicModeExBJ(cineMode, forForce, bj_CINEMODE_INTERFACEFADE)
endfunction
Which you can find by searching for the function CinematicModeExBJ in the Blizzard.j file.
The behavior you are experiencing is intended. I am not sure why they made some decisions. Disabling black mask / fog of war might simply be to prevent vision problems during the cinematic (and disabling/enabling black mask/fog of war desync if you do them only for the local player).
In any case, you will have to write your own cinematic transition function if you want to stop some behaviors enforced by the GUI action.
If you want to simply remove the black mask / fog of war bits from the Blizzard GUI cinematic action, just copy over the function I copied above and remove lines that have "FogMaskEnable" and "FogEnable". Then just call upon your custom function to enable/disable cinematics.
Well, hopefully you have some rudimentary knowledge of JASS to handle that. If not, just say so.
Also, no idea if problems may occur by removing the black mask / fog of war handling parts.
