[Snippet] [Needs work] Stun {UnitIndexer/Lua}

[Nestharus]

Installation Script

//! externalblock extension=lua ObjectMerger $FILENAME$
    //! runtextmacro LUA_FILE_HEADER()
    //! i dofile("GetVarObject")
    
    //! i local id2 = getvarobject("BSTN", "buffs", "BUFFS_STUN", true)
    //! i createobject("BSTN",id2)
    //! i makechange(current,"fnam","STUN")
    
    //! i local id = getvarobject("ACfb", "abilities", "ABILITIES_STUN", true)
    //! i createobject("ACfb", id)
    //! i makechange(current,"anam","Stun")
    //! i makechange(current,"amat","")
    //! i makechange(current,"amsp","0")
    //! i makechange(current,"arac","0")
    //! i makechange(current,"Htb1","1","0")
    //! i makechange(current,"aran","1","92083")
    //! i makechange(current,"acdn","1","0")
    //! i makechange(current,"ahdu","1","0")
    //! i makechange(current,"adur","1","0")
    //! i makechange(current,"amcs","1","0")
    //! i makechange(current,"atar","1","")
    //! i makechange(current,"abuf","1",id2)
    //! i makechange(current,"aord","firebolt")
    
    //! i updateobjects()
//! endexternalblock

Code

library Stun /* v1.0.0.4
*************************************************************************************
*
*   Supports stunning units.
*       -remaining stun time on a unit retrieval
*       -add stun time to unit
*       -set stun time for unit
*       -remove stun from unit
*
*************************************************************************************
*
*   */uses/*
*       */ UnitIndexer /*       hiveworkshop.com/forums/jass-functions-413/snippet-worldbounds-180494/
*       */ DummyCaster /*       hiveworkshop.com/forums/submissions-414/snippet-dummy-caster-197087/
*       */ Table /*             hiveworkshop.com/forums/jass-functions-413/snippet-new-table-188084/
*
*************************************************************************************
*
*    Functions
*
*       function UnitGetStun takes unit u returns real
*       function UnitAddStun takes unit u, real time returns nothing
*       function UnitSetStun takes unit u, real time returns nothing
*       function UnitRemoveStun takes unit u, real time returns nothing
*
************************************************************************************/
    globals
        private Table h=0
        private timer array t
        private boolean array r
    endglobals
    //stun expire
    private function B takes nothing returns nothing
        local integer i=h[GetHandleId(GetExpiredTimer())]
        set r[i]=false
        call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
    endfunction
    //unit death
    private function E takes nothing returns boolean
        local integer i=GetUnitUserData(GetTriggerUnit())
        if (r[i]) then
            set r[i]=false
            call PauseTimer(t[i])
        endif
        return false
    endfunction
    //unit index
    private function M takes nothing returns boolean
        local integer i=GetIndexedUnitId()
        set t[i]=CreateTimer()
        set h[GetHandleId(t[i])]=i
        return false
    endfunction
    //unit deindex
    private function D takes nothing returns boolean
        local integer i=GetIndexedUnitId()
        call h.remove(GetHandleId(t[i]))
        call DestroyTimer(t[i])
        set t[i]=null
        set r[i]=false
        return false
    endfunction
    //init
    private module I
        private static method onInit takes nothing returns nothing
            local trigger q=CreateTrigger()
            local integer i=15
            call DummyCaster[ABILITIES_STUN].register()
            call RegisterUnitIndexEvent(Condition(function M),UnitIndexer.INDEX)
            call RegisterUnitIndexEvent(Condition(function D),UnitIndexer.DEINDEX)
            loop
                call TriggerRegisterPlayerUnitEvent(q,Player(i),EVENT_PLAYER_UNIT_DEATH,null)
                exitwhen 0==i
                set i=i-1
            endloop
            call TriggerAddCondition(q,Condition(function E))
            set h=Table.create()
            set q=null
        endmethod
    endmodule
    private struct N extends array
        implement I
    endstruct
    function UnitGetStun takes unit u returns real
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return 0.
        debug endif
        if (r[i]) then
            return TimerGetRemaining(t[i])
        endif
        return 0.
    endfunction
    function UnitAddStun takes unit u, real time returns nothing
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        if (r[i]) then
            set time=time+TimerGetRemaining(t[i])
        else
            set r[i]=true
        endif
        if (0<time) then
            call TimerStart(t[i],time,false,function B)
            call DummyCaster[852231].castTarget(u)
        else
            call PauseTimer(t[i])
            set r[i] = false
            call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        endif
    endfunction
    function UnitSetStun takes unit u, real time returns nothing
        local integer i = GetUnitUserData(u)
        debug if (time<0) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID TIME")
            debug return
        debug endif
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        if (0<time) then
            set r[i]=true
            call TimerStart(t[i],time,false,function B)
            call DummyCaster[852231].castTarget(u)
        else
            set r[i]=false
            call PauseTimer(t[i])
            call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        endif
    endfunction
    function UnitRemoveStun takes unit u, real time returns nothing
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        set r[i]=false
        call PauseTimer(t[i])
    endfunction
endlibrary

 

[Nestharus]

Optimized comparisons and removed extra spaces.

 

[Bribe]

What about if a unit reincarnates? I think you should
recreate an order event here to catch undefends, then
check if the widget's life is below 0 (or UnitAlive, etc.)

That way at least the stun can deallocate properly.

 

[Nestharus]

I'll make this use UnitEvent then to capture reincarnates.

 

[LuizBills]

This system needs to be updated, because DummyCaster don't uses register now.

 

[Nestharus]

yup, I will update it today

 

[Bribe]

Any plans to update this? I think a simple library that stuns a unit for "X" time is all this really needs to be, using a stun buff with 0 duration (infinite) and removing the buff with a timer. The timer would be paused and re-started if the unit already has a buff.

Get/set of a stun is not needed. Typically you'll just use an "add" method and if the duration is less than the current stun duration you just use whichever one has a greater duration (that's how the wc3 engine handles it anyway).

 

[Nestharus]

I'll update this soon yes.

Might as well have the get/set ; P. Some abilities might cancel an entire stun or a % of a stun : ).

 

[-Kobas-]

Can I suggest test map with everything your system use already imported.

 

[Nestharus]

Uh sure ; )


This still needs an update tho, lol =). It's on my queue for updates, no worries.

 

[Magtheridon96]

1- Steal Acquire Nestharus' buggy system
2- Fix system
3- Upload system to hive
4- Nestharus gets /jelly/
5- Nestharus updates system
6- ???
7- Profit!

It worked on Vexorian, and I'm betting it should work on you

 

[Nestharus]

I honestly don't mind if you do that, that's less work for me ; )


However, it needs to meet the same level of performance methinks ; P

 

[WaterKnight]

Does not work against magic immunes, invulnerables and is not instant. Does SetUnitStun with RemoveUnitStun right afterwards even release the unit?

 

[Nestharus]

Does not work against magic immunes, invulnerables and is not instant.

I can make dif versions that work against magic immunes + invulnerables ; ). I did what I did purposefully here =). Also, I'll investigate making it instant.

Does SetUnitStun with RemoveUnitStun right afterwards even release the unit?

It should, but I'l investigate =).

 

[WaterKnight]

I guess the only instant stun is 'War Stomp', not that the delay would matter outside of code though.

 

[Magtheridon96]

War Stomp creates a terrain derformation effect though.
I guess moving the dummy unit with 0 collision to the position of the target and casting War Stomp with a 1 AoE would be fine. (The deformation won't be visible)

 

[WaterKnight]

0 also works but deformations from abilities leak btw. You can see the counter rising.

 

[Bribe]

Those deformations also increase the counter? Total suckage. So Tauren Chieftan is the biggest fail hero with both war stomp AND shockwave.

 

[Magtheridon96]

I guess we need a coded Shockwave/War Stomp spell :/

 

[Nestharus]

Shockwave/War Stomp spell

You can't use any terrain deformations tho... all terrain deformations will leak as they can't be destroyed...


You know what... imma post on blizzard forums about this : )

 

[Laiev]

You know what... imma post on blizzard forums about this : )

Again lol

Why you need this? >.>

Seriously, you'll use that ugly effect on terrain?

 

[-Kobas-]

Carrion swarm and shock wave are like 2 same spells, dunno why they added terrain deformation into it, they just ruined whole idea, effect isn't so awesome, there is no so great difference and game usually lag like hell, especially on computers with "not so great" performance.

 

[Magtheridon96]

@Nestharus:

Link us when you're done

 

[WaterKnight]

Nah, stopped deformations and those of abilities hardly matter. Infact, it might just be an easy id allocation.

 

[Dirac]

I just want to point out that this is completely broken
Doesn't compile with the newest version of dummy caster
Bugs with the hashtable use (i don't know why)
I fixed it here but it uses TimerUtils instead

library Stun /* v1.0.0.4
*************************************************************************************
*
*   Supports stunning units.
*       -remaining stun time on a unit retrieval
*       -add stun time to unit
*       -set stun time for unit
*       -remove stun from unit
*
*************************************************************************************
*
*   */uses/*
*       */ UnitIndexer /*       hiveworkshop.com/forums/jass-functions-413/snippet-worldbounds-180494/
*       */ DummyCaster /*       hiveworkshop.com/forums/submissions-414/snippet-dummy-caster-197087/
*       */ TimerUtils  /*       wc3c.net/showthread.php?t=101322
*
*************************************************************************************
*
*    Functions
*
*       function UnitGetStun takes unit u returns real
*       function UnitAddStun takes unit u, real time returns nothing
*       function UnitSetStun takes unit u, real time returns nothing
*       function UnitRemoveStun takes unit u returns nothing
*
************************************************************************************/
    globals
        private timer array t
        private boolean array r
    endglobals
    //stun expire
    private function B takes nothing returns nothing
        local integer i=GetTimerData(GetExpiredTimer())
        set r[i]=false
        call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
    endfunction
    //unit death
    private function E takes nothing returns boolean
        local integer i=GetUnitUserData(GetTriggerUnit())
        if (r[i]) then
            set r[i]=false
            call PauseTimer(t[i])
        endif
        return false
    endfunction
    //unit index
    private function M takes nothing returns boolean
        set t[GetIndexedUnitId()]=NewTimerEx(GetIndexedUnitId())
        return false
    endfunction
    //unit deindex
    private function D takes nothing returns boolean
        call ReleaseTimer(t[GetIndexedUnitId()])
        set t[GetIndexedUnitId()]=null
        set r[GetIndexedUnitId()]=false
        return false
    endfunction
    //init
    private module I
        private static method onInit takes nothing returns nothing
            local trigger q=CreateTrigger()
            local integer i=15
            call RegisterUnitIndexEvent(Condition(function M),UnitIndexer.INDEX)
            call RegisterUnitIndexEvent(Condition(function D),UnitIndexer.DEINDEX)
            loop
                call TriggerRegisterPlayerUnitEvent(q,Player(i),EVENT_PLAYER_UNIT_DEATH,null)
                exitwhen 0==i
                set i=i-1
            endloop
            call TriggerAddCondition(q,Condition(function E))
            set q=null
        endmethod
    endmodule
    private struct N extends array
        implement I
    endstruct
    function UnitGetStun takes unit u returns real
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return 0.
        debug endif
        if (r[i]) then
            return TimerGetRemaining(t[i])
        endif
        return 0.
    endfunction
    function UnitAddStun takes unit u, real time returns nothing
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        if (r[i]) then
            set time=time+TimerGetRemaining(t[i])
        else
            set r[i]=true
        endif
        if (0<time) then
            call TimerStart(t[i],time,false,function B)
            call DummyCaster[ABILITIES_STUN].castTarget(Player(15),1,852231,u)
        else
            call PauseTimer(t[i])
            set r[i] = false
            call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        endif
    endfunction
    function UnitSetStun takes unit u, real time returns nothing
        local integer i = GetUnitUserData(u)
        debug if (time<0) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID TIME")
            debug return
        debug endif
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        if (0<time) then
            set r[i]=true
            call TimerStart(t[i],time,false,function B)
            call DummyCaster[ABILITIES_STUN].castTarget(Player(15),1,852231,u)
        else
            set r[i]=false
            call PauseTimer(t[i])
            call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        endif
    endfunction
    function UnitRemoveStun takes unit u returns nothing
        local integer i = GetUnitUserData(u)
        debug if (0==i) then
            debug call DisplayTimedTextToPlayer(GetLocalPlayer(),0,0,60,"STUN ERROR: INVALID UNIT")
            debug return
        debug endif
        call UnitRemoveAbility(GetUnitById(i),BUFFS_STUN)
        set r[i]=false
        call PauseTimer(t[i])
    endfunction
endlibrary

 

[Nestharus]

I;m going to get back to this. I know that it's broken. The end of the semester is coming up and I've been busy as hell. When the semester ends, I will have tons of free time again.

 

[Magtheridon96]

    //unit index
    private function M takes nothing returns boolean
        local integer i=GetIndexedUnitId()
        set t[i]=NewTimerEx(i)
        return false
    endfunction
    //unit deindex
    private function D takes nothing returns boolean
        local integer i=GetIndexedUnitId()
        call DestroyTimer(t[i])
        set t[i]=null
        set r[i]=false
        return false
    endfunction

->

    //unit index
    private function M takes nothing returns boolean
        set t[GetIndexedUnitId()]=NewTimerEx(GetIndexedUnitId())
        return false
    endfunction
    //unit deindex
    private function D takes nothing returns boolean
        call DestroyTimer(t[GetIndexedUnitId()])
        set t[GetIndexedUnitId()]=null
        set r[GetIndexedUnitId()]=false
        return false
    endfunction

UnitIndexer's functions (except for GetUnitId) all get inlined to variable reads/array lookups.

 

[Dirac]

Orly? i thought that because they were functions that it would consume a thread creation for it's retrieval

 

[Bribe]

Functions don't create a new thread.

Also, GetIndexedUnitId() is an inlining function.

 

[Magtheridon96]

Function don't create a thread, but they append it.

Function executes {
    code
    code
    code
    code
    Function call {
        code
        code
        code
        code
        code
    } End function call
    Calling function continues;
    code
    code
    code
} End function call

 

[Bribe]

"Suspend" would be the more appropriate word, append would imply adding to the end.

 

[Magtheridon96]

Oh right. I just got that word because I thought that you're AppendThread resource does that

 

[Bribe]

AppendThread executes the code after a 0-second timer, meaning that thread will run at the end of the current thread. Calling to a function does quite the opposite, it runs from within the current thread. In fact threads and functions have nothing to do with each other. The only way in wc3 to make a new thread is by using the "code" type or by using ExecuteFunc.

 

[kStiyl]

    function IsUnitStunned takes unit u returns boolean
        return r[GetUnitId(u)]
    endfunction

?

 

[Magtheridon96]

That function determines whether a unit is stunned or not.
When you stun a unit, he sets r[GetUnitUserData(unit)] to true.
When the stun duration ends, it's set to false.

 

[kStiyl]

So wouldn't that function be a good addition?

 

[Magtheridon96]

Oh! I thought you were asking what it does!
It turns out, it's not in there =P
Yes, I think that's a great addition, but unfortunately, it would require people to ONLY use this system for stuns... actually, no, that's not a problem. Nes would only have to add a disclaimer.

 

[Bribe]

One way that will always work: have a dummy unit with the transport ability. Order him to load the unit. The order boolean will correspond directly with the units stun status

 

[Nestharus]

This is going to be going under a dramatic change. Went over a design with Laiev that is very excellent (he pointed out that the code is identical for different effects, so I came up with a new design). A new Core resource will be created/submitted and then each effect (like stun) will essentially just be an Lua script so that you can plug the constant into the core ;p.


This new design should be able to replace the Status library ^)^.

 

[Laiev]

I agreed about the design, but you know that I can't do it alone ;O, some part of the main library will need your view Nes.

 

[Nestharus]

uh huh, just pastebin it and send me a pm and I'll review it ;p