[JASS] Polled Waits vs Timers for desyncs

[Shyhalu]

Was wondering if PolledWaits are any good with stopping a map from desyncing

IE: I want the trigger to wait a second before taking an action.

Sample code below, would a polled wait be sufficient in not desyncing the game? Or do I need to implement a timer?

function MCA takes nothing returns nothing
      local unit u = GetTriggerUnit()
      local player p = GetOwningPlayer(u)     
      local unit z = GetSpellTargetUnit()  
      local integer i = GetUnitAbilityLevel(u, 'A01P')
      local real x = GetUnitX(z)
      local real y = GetUnitY(z)
        
     call TriggerSleepAction(1)

     loop
         exitwhen i == 0
            set u = CreateUnit(p,'nmrl',x,y,0)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\CrushingWave\\CrushingWaveDamage.mdl",u,"overhead"))
            call IssueTargetOrder(u,"attack",z)           
            
         set i = i-1
     endloop
 
     set z = null
     set u = null
     set p = null
endfunction

 

[Pharaoh_]

Don't mess up with waits, whatever they are. A timer would do the job without any doubts.

 

[PurgeandFire]

That is fine. Polled wait leaks though. (But you're using TSA so it is fine)

Since the waiting time is not that low (1 second), it should be fairly accurate with TriggerSleepAction().

Using a timer, yes it would be more accurate, but it wouldn't make the greatest difference and would be a hassle to use attachments just for a simple 1 second wait.

Waits don't necessarily cause desyncs btw, so there shouldn't be anything to really worry about.

 

[Shyhalu]

Don't mess up with waits, whatever they are. A timer would do the job without any doubts.

I know timers are as accurate as we can get, but they are a bit of a hassle to work with. So if I can get away with polled waits I'd be glad.

That is fine. Polled wait leaks though. (But you're using TSA so it is fine)

Since the waiting time is not that low (1 second), it should be fairly accurate with TriggerSleepAction().

Using a timer, yes it would be more accurate, but it wouldn't make the greatest difference and would be a hassle to use attachments just for a simple 1 second wait.

Waits don't necessarily cause desyncs btw, so there shouldn't be anything to really worry about.

So what numbers will TSAs cause a desync? I use around .3 to 1 second. Majority of my ~.3s are breaks in the code so there is less of a lag spike.

 

[PurgeandFire]

It won't cause desyncs, but around .3 seconds or less it'll start to get inaccurate. Or so I've heard. Not largely inaccurate, (like it won't wait 5 seconds when it is supposed to wait 0.27 or something, it'll be off only by maybe a few milliseconds)

 

[Berb]

This is what it would look like with a timer, though depending on what you're using it for you may be able to use different methods.

scope Example
    globals
        private hashtable hashData = InitHashtable()
    endglobals

    struct s_data
        unit u  = null
        unit t  = null
        
        real x
        real y
        
        integer i
    endstruct

    function MCADelayed takes nothing returns nothing
        local timer t=GetExpiredTimer()
        local s_data d=s_data(LoadInteger(hashData, GetHandleId(t), 1))
        local player p=GetOwningPlayer(d.u)
        local unit u
        
        loop
            exitwhen (d.i==0)
            set u=CreateUnit(p, 'nmrl', d.x, d.y, 0)
            call DestroyEffect(AddSpecialEffectTarget("Abilities\\Spells\\Other\\CrushingWave\\CrushingWaveDamage.mdl",u,"overhead"))
            call IssueTargetOrder(u, "attack", d.t)
            
            set d.i=d.i-1
        endloop
        
        call RemoveSavedInteger(hashData, GetHandleId(t), 1)
        call d.destroy()        

        set p=null
        set u=null
        set t=null
    endfunction
    
    function MCA takes nothing returns nothing
        local s_data d = s_data.create()
        local timer t = CreateTimer()
        
        set d.u = GetTriggerUnit()
        set d.t = GetSpellTargetUnit()
        set d.i = GetUnitAbilityLevel(d.u, 'A01P')
        set d.x = GetUnitX(d.t)
        set d.y = GetUnitY(d.t)

        call SaveInteger(hashData, GetHandleId(t), 1, d)
        call TimerStart(t, 1, false, function MCADelayed)
        
        set t=null
    endfunction
endscope

it'll be off only by maybe a few milliseconds)

Actually it can be off by seconds, and its varying. Its completely inaccurate.

 

[Shyhalu]

This is what it would look like with a timer, though depending on what you're using it for you may be able to use different methods.

Actually it can be off by seconds, and its varying. Its completely inaccurate.

The accuracy is not a problem if its not going to cause a desync/server split.

Theres two areas in my map that cause server splits almost without fail when area effectish abilities, and sometimes even general fighting. I figured it was use of too many TSAs.

It happens even more since i've gone through some triggers and made them more efficient/faster.

 

[Berb]

Since when does TriggerSleepAction cause desyncs?

If you were to do:

if (GetLocalPlayer() == somePlayer) then
    call TriggerSleepAction(0)
endif

This may cause somePlayer to desync, I'm not sure, but this is the only instance I can imagine that TriggerSleepAction would cause a desync.

 

[Shyhalu]

Beats me, could swear I read somewhere on here that they will cause splits.

If they don't then great.

 

[overload119]

TSA do not cause desyncs. PolledWaits are just awful.

I remember I was asking similar questions, but Rising_Dusk told me never use PolledWaits, as it is bad coding practice, leaks, and is just stupid (since it uses TSA anyway).

It took me a while to get use to it, but use Timers for everything wait-dependant.