[JASS] need help with a trigger

[defiled]

Hi everyone. Here's the code of trigger's Actions function:

    local integer i=0
    local location loc
    local unit u=GetSpellAbilityUnit()
    set i=GetPlayerId(GetOwningPlayer(u))
    call DisplayTextToPlayer(Player(i),0,0,I2S(GetUnitTypeId(u)))
    if RectContainsCoords(udg_INV_LOCS[i], GetUnitX(u), GetUnitY(u)) then
        //Moves unit not to the udg_inv_TP[i] but to (0; 0)
        call SetUnitX(u,GetLocationX(udg_inv_TP[i]))
        call SetUnitY(u,GetLocationY(udg_inv_TP[i]))
    else
        set loc=Location(GetUnitX(u),GetUnitY(u))
        set udg_inv_TP[i]=loc
        call SetUnitX(u,GetRectCenterX(udg_INV_LOCS[i]))
        call SetUnitY(u,GetRectCenterY(udg_INV_LOCS[i]))
    endif
    call PanCameraToTimedForPlayer(GetOwningPlayer(u),GetUnitX(u),GetUnitY(u),0.)
    call RemoveLocation(loc)
    set loc=null
    set u=null

I tried to use GetUnitLoc() instead of Location() but the result is the same. How this can be fixed?

 

[moyackx]

Hmmm, you don't' need the locations for anything, just use directly GetUnitX/Y.

local integer i=0
//local location loc
local unit u=GetSpellAbilityUnit()
set i=GetPlayerId(GetOwningPlayer(u))
call DisplayTextToPlayer(Player(i),0,0,I2S(GetUnitTypeId(u)))
if RectContainsCoords(udg_INV_LOCS[i], GetUnitX(u), GetUnitY(u)) then
    //Moves unit not to the udg_inv_TP[i] but to (0; 0)
    call SetUnitX(u,GetLocationX(udg_inv_TP[i])) // that means udg_inv_TP[i] has not been defined, it's null
    call SetUnitY(u,GetLocationY(udg_inv_TP[i]))
else
    set loc=Location(GetUnitX(u),GetUnitY(u))
    set udg_inv_TP[i]=loc
    call SetUnitX(u,GetRectCenterX(udg_INV_LOCS[i]))
    call SetUnitY(u,GetRectCenterY(udg_INV_LOCS[i]))
endif
call PanCameraToTimedForPlayer(GetOwningPlayer(u),GetUnitX(u),GetUnitY(u),0.)
call RemoveLocation(loc)
set loc=null
set u=null

What's the purpose of this code??

For more support in jass, visit www.wc3jass.com

 

[defiled]

it moves a hero to the location where his chest is located, and returns him back to the point where he casted spell.
udg_inv_TP cannot be null, as the first cast is surely not from the rect udg_INV_LOCS.

 

[moyackx]

Hmm, a gold rule in jass is to avoid locations as much as possible, you can use instead an array of reals, like X and Y. With this you ensure less leaks in your map.

Let me help you with a better code.

 

[defiled]

that's strange, but this

local unit u=GetSpellAbilityUnit()
set i=GetPlayerId(GetOwningPlayer(u))
...

leaves a leak, while this doesnt

local unit u=GetSpellAbilityUnit()
set i=GetPlayerId(GetOwningPlayer(GetSpellAbilityUnit()))
...

 

[moyackx]

It leak if you don't null the unit at the end of the script, before any return

set u = null

 

[defiled]

look at the first post, variable is nulled.

 

[PurgeandFire]

It's not working because you remove the location. Remember that variables are pointers, not representative of the actual object. So if you set the global to loc, you aren't copying the data, you are just making them both point to the same object in memory. Therefore, if you remove the location that loc points to, then that means you are also removing the location that the global points to. (because they are pointing to the same object)

Here is how the code should look:

local unit u = GetSpellAbilityUnit()
local integer i = GetPlayerId(GetOwningPlayer(u)) 
call DisplayTextToPlayer(Player(i),0,0,I2S(GetUnitTypeId(u)))
if RectContainsCoords(udg_INV_LOCS[i], GetUnitX(u), GetUnitY(u)) then
    //Moves unit not to the udg_inv_TP[i] but to (0; 0)
    call SetUnitX(u,GetLocationX(udg_inv_TP[i]))
    call SetUnitY(u,GetLocationY(udg_inv_TP[i]))
    call RemoveLocation(udg_inv_TP[i]) // clear the leak later on
else
    set udg_inv_TP[i]=GetUnitLoc(u)
    call SetUnitX(u,GetRectCenterX(udg_INV_LOCS[i]))
    call SetUnitY(u,GetRectCenterY(udg_INV_LOCS[i]))
endif
call PanCameraToTimedForPlayer(GetOwningPlayer(u),GetUnitX(u),GetUnitY(u),0.)
set u=null