moveing goods trigger help

countryboy · May 14, 2008

i have a map I'm working on that i need to figure out a way to spawn a person at a building and go to another one. but there is more than one building one and none of them are made at start. is it even possible?

Volvox · May 15, 2008

Of course it is possible, just a minor clarification of your post is needed. You want something like a network of waygates?

countryboy · May 15, 2008

no not gateways but something like in strong hold 2 where you make a lumber mill and then every so often a guy gos from the lumber mill and travels to the warehouse. but you have to have multiple mills.

Volvox · May 15, 2008

Oooh like that... Well, it would take some jass to seek the nearest building of choice and unfortunately, i am not that good at jass so you'll need someone else to do that for you. Sorry i couldn't be of more help.

countryboy · May 16, 2008

do you suggest i go to request or jass forum?

PurplePoot · May 16, 2008

I did a system exactly like that for a friend a little while ago.

The code would need to be configured for your purpose (could be done later), but here's how it looks;

(Uses I2U, H2I, and a global game cache called GameCache)

JASS:

function ConvoyReachesTargetConds takes nothing returns boolean
    return GetSpellAbilityId() == 'A003'
endfunction

function ConvoyReachesTarget takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    local string s = I2S(H2I(u))
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,s,"sender"))
    local unit u3 = I2U(GetStoredInteger(udg_GameCache,s,"target"))
    if GetOwningPlayer(u3) != p then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)*.75))
        call SetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    else
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    endif
    if GetWidgetLife(u2) > 0 and GetWidgetLife(u3) > 0 then
        call SendConvoy(p,u2,u3)
    endif
    call FlushStoredMission(udg_GameCache,s)
    call RemoveUnit(u)
    set u = null
    set u2 = null
    set u3 = null
endfunction

function InitTrig_ConvoyReachesTarget takes nothing returns nothing
    set gg_trg_ConvoyReachesTarget = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ConvoyReachesTarget,EVENT_PLAYER_UNIT_SPELL_CAST)
    call TriggerAddCondition(gg_trg_ConvoyReachesTarget,Condition(function ConvoyReachesTargetConds))
    call TriggerAddAction(gg_trg_ConvoyReachesTarget,function ConvoyReachesTarget)
endfunction

function SetConvoyDestinationConds takes nothing returns boolean
    return GetSpellAbilityId() == 'A004'
endfunction

function SetConvoyDestination takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    if GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD) > 299 and GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER) > 9 then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)-300)
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER,GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER)-10)
        call SendConvoy(p,u,GetSpellTargetUnit())
    endif
    set u = null
endfunction

function InitTrig_SetConvoyDestination takes nothing returns nothing
    set gg_trg_SetConvoyDestination = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_SetConvoyDestination,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_SetConvoyDestination,Condition(function SetConvoyDestinationConds))
    call TriggerAddAction(gg_trg_SetConvoyDestination,function SetConvoyDestination)
endfunction

function ReorderConvoyConds takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == 'h00Z' and GetIssuedOrderId() == 851971
endfunction

function ReorderConvoy takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,I2S(H2I(u)),"target"))
    call PauseUnit(u,true)
    call IssueImmediateOrder(u,"stop")
    call PauseUnit(u,false)
    call IssueImmediateOrder(u,"stop")
    if GetWidgetLife(u2) > 0 then
        call IssueTargetOrder(u,"cripple",u2)
    endif
    set u = null
    set u2 = null
endfunction

function InitTrig_ReorderConvoy takes nothing returns nothing
    set gg_trg_ReorderConvoy = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ReorderConvoy,EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ReorderConvoy,EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
    call TriggerAddCondition(gg_trg_ReorderConvoy,Condition(function ReorderConvoyConds))
    call TriggerAddAction(gg_trg_ReorderConvoy,function ReorderConvoy)
endfunction

function ConvoyDeathConds takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == 'h00Z'
endfunction

function ConvoyDeath takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    local string s = I2S(H2I(u))
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,s,"sender"))
    local unit u3 = I2U(GetStoredInteger(udg_GameCache,s,"target"))
    if GetWidgetLife(u2) > 0 and GetWidgetLife(u3) > 0 and u3 == I2U(GetStoredInteger(udg_GameCache,I2S(H2I(u2)),"target")) then
        call SendConvoy(p,u2,u3)
    endif
    call FlushStoredMission(udg_GameCache,s)
    set u = null
    set u2 = null
    set u3 = null
endfunction

function CleanupUselessConvoysFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == 'h00Z' and GetUnitCurrentOrder(GetFilterUnit()) != 852189
endfunction

function CleanupUselessConvoys takes nothing returns nothing
    local unit u
    call GroupEnumUnitsInRect(udg_enumGrp,bj_mapInitialPlayableArea,Filter(function CleanupUselessConvoysFilter))
    loop
        set u = FirstOfGroup(udg_enumGrp)
        exitwhen u == null
        call FlushStoredMission(udg_GameCache,I2S(H2I(u)))
        call RemoveUnit(u)
        call GroupRemoveUnit(udg_enumGrp,u)
    endloop
endfunction

function InitTrig_CleanupUselessConvoys takes nothing returns nothing
    set gg_trg_CleanupUselessConvoys = CreateTrigger()
    call TriggerRegisterTimerEvent(gg_trg_CleanupUselessConvoys,1,true)
    call TriggerAddAction(gg_trg_CleanupUselessConvoys,function CleanupUselessConvoys)
endfunction

~Moved to Spells And Systems

countryboy · May 16, 2008

how do i use it? i never use jass.

Volvox · May 16, 2008

Copy it into your map's header in trigger editor and change the code to suit yourself. Study the code carefully, you should be able to change the things you need to change.

countryboy · May 16, 2008

k thank you very much :thumbs_up:

PurplePoot · May 17, 2008

Now that I've got a second, I'll explain it --

The script contains five triggers:

ConvoyReachesTarget - This trigger detects when the convoy reaches its destination point, which is tracked by the convoy having been ordered to cast an ability on the target building. The trigger then gives the gold, and sends a new convoy (A convoy is sent every time the previous one reached the target)
SetConvoyDestination - This trigger starts sending convoys.
ReorderConvoy - Since convoys are selectable (so they can be killed), but should not be controllable by the player, the Ward classification is given to them, and this trigger blocks right-click orders.
ConvoyDeath - This trigger is an anti-leak trigger to get rid of the attached data from dying convoys
CleanupUselessConvoys - This trigger periodically finds convoys that are not doing their job (ie their target is removed) and removes them.

This system needs a few configuration changes at the moment -

Gold given - the current gold given is determined withing ConvoyReachesTarget, with

JASS:

    if GetOwningPlayer(u3) != p then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)*.75))
        call SetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    else
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    endif

(Note that it gives less if the player owning the convoy is trading with themself, you may want to also have that changed)

Ability and unit IDs, and orderstrings - You would need to specifically configure all ability and unit IDs as well as orderstrings used by the system to whatever they are in your map

Sending system - For example, if you want to send convoys periodically as opposed to when one reaches its destination, or if you don't want it to cost money to set up a route

Also, currently the convoys cost gold to send, in the following block in the SetConvoyDestination trigger:

JASS:

    if GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD) > 299 and GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER) > 9 then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)-300)
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER,GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER)-10)
        call SendConvoy(p,u,GetSpellTargetUnit())
    endif

I added some easy configuration settings to the code, tell me if you need other configurability options.

JASS:

//Constants
constant function ConvoyAbilityOrderString takes nothing returns string
    return "cripple" //orderstring of the ability the convoys cast on the target markets
endfunction

constant function ConvoyUnitTypeId takes nothing returns integer
    return 'h00Z' //unit id of the convoy
endfunction

constant function ConvoyAbilityId takes nothing returns integer
    return 'A003' //ability id of the ability the convoys cast on the target markets
endfunction

constant function ConvoySendAbilityId takes nothing returns integer
    return 'A004' //ability id of the ability to establish a trade route
endfunction

//Map Header
function H2I takes handle h returns integer
    return h
    return 0
endfunction

function I2U takes integer i returns unit
    return i
    return null
endfunction

function SendConvoy takes player p, unit send, unit targ returns nothing
    local unit u = CreateUnit(p,ConvoyUnitTypeId(),GetUnitX(send),GetUnitY(send),0)
    local string s = I2S(H2I(u))
    call IssueTargetOrder(u,ConvoyAbilityOrderString(),targ)
    call StoreInteger(udg_GameCache,s,"sender",H2I(send))
    call StoreInteger(udg_GameCache,s,"target",H2I(targ))
    set u = null
endfunction 

//Triggers

function ConvoyReachesTargetConds takes nothing returns boolean
    return GetSpellAbilityId() == ConvoyAbilityId()
endfunction

function ConvoyReachesTarget takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    local string s = I2S(H2I(u))
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,s,"sender"))
    local unit u3 = I2U(GetStoredInteger(udg_GameCache,s,"target"))
    if GetOwningPlayer(u3) != p then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)*.75))
        call SetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(GetOwningPlayer(u3),PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    else
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)+R2I(GetUnitState(u,UNIT_STATE_MANA)/4))
    endif
    if GetWidgetLife(u2) > 0 and GetWidgetLife(u3) > 0 then
        call SendConvoy(p,u2,u3)
    endif
    call FlushStoredMission(udg_GameCache,s)
    call RemoveUnit(u)
    set u = null
    set u2 = null
    set u3 = null
endfunction

function InitTrig_ConvoyReachesTarget takes nothing returns nothing
    set gg_trg_ConvoyReachesTarget = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ConvoyReachesTarget,EVENT_PLAYER_UNIT_SPELL_CAST)
    call TriggerAddCondition(gg_trg_ConvoyReachesTarget,Condition(function ConvoyReachesTargetConds))
    call TriggerAddAction(gg_trg_ConvoyReachesTarget,function ConvoyReachesTarget)
endfunction

function SetConvoyDestinationConds takes nothing returns boolean
    return GetSpellAbilityId() == ConvoySendAbilityId()
endfunction

function SetConvoyDestination takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    if GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD) > 299 and GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER) > 9 then
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD,GetPlayerState(p,PLAYER_STATE_RESOURCE_GOLD)-300)
        call SetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER,GetPlayerState(p,PLAYER_STATE_RESOURCE_LUMBER)-10)
        call SendConvoy(p,u,GetSpellTargetUnit())
    endif
    set u = null
endfunction

function InitTrig_SetConvoyDestination takes nothing returns nothing
    set gg_trg_SetConvoyDestination = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_SetConvoyDestination,EVENT_PLAYER_UNIT_SPELL_EFFECT)
    call TriggerAddCondition(gg_trg_SetConvoyDestination,Condition(function SetConvoyDestinationConds))
    call TriggerAddAction(gg_trg_SetConvoyDestination,function SetConvoyDestination)
endfunction

function ReorderConvoyConds takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == ConvoyUnitTypeId() and GetIssuedOrderId() == 851971
endfunction

function ReorderConvoy takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,I2S(H2I(u)),"target"))
    call PauseUnit(u,true)
    call IssueImmediateOrder(u,"stop")
    call PauseUnit(u,false)
    call IssueImmediateOrder(u,"stop")
    if GetWidgetLife(u2) > 0 then
        call IssueTargetOrder(u,ConvoyAbilityOrderString(),u2)
    endif
    set u = null
    set u2 = null
endfunction

function InitTrig_ReorderConvoy takes nothing returns nothing
    set gg_trg_ReorderConvoy = CreateTrigger()
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ReorderConvoy,EVENT_PLAYER_UNIT_ISSUED_TARGET_ORDER)
    call TriggerRegisterAnyUnitEventBJ(gg_trg_ReorderConvoy,EVENT_PLAYER_UNIT_ISSUED_POINT_ORDER)
    call TriggerAddCondition(gg_trg_ReorderConvoy,Condition(function ReorderConvoyConds))
    call TriggerAddAction(gg_trg_ReorderConvoy,function ReorderConvoy)
endfunction

function ConvoyDeathConds takes nothing returns boolean
    return GetUnitTypeId(GetTriggerUnit()) == ConvoyUnitTypeId()
endfunction

function ConvoyDeath takes nothing returns nothing
    local unit u = GetTriggerUnit()
    local player p = GetOwningPlayer(u)
    local string s = I2S(H2I(u))
    local unit u2 = I2U(GetStoredInteger(udg_GameCache,s,"sender"))
    local unit u3 = I2U(GetStoredInteger(udg_GameCache,s,"target"))
    if GetWidgetLife(u2) > 0 and GetWidgetLife(u3) > 0 and u3 == I2U(GetStoredInteger(udg_GameCache,I2S(H2I(u2)),"target")) then
        call SendConvoy(p,u2,u3)
    endif
    call FlushStoredMission(udg_GameCache,s)
    set u = null
    set u2 = null
    set u3 = null
endfunction

function CleanupUselessConvoysFilter takes nothing returns boolean
    return GetUnitTypeId(GetFilterUnit()) == ConvoyUnitTypeId() and GetUnitCurrentOrder(GetFilterUnit()) != 852189
endfunction

function CleanupUselessConvoys takes nothing returns nothing
    local unit u
    call GroupEnumUnitsInRect(udg_enumGrp,bj_mapInitialPlayableArea,Filter(function CleanupUselessConvoysFilter))
    loop
        set u = FirstOfGroup(udg_enumGrp)
        exitwhen u == null
        call FlushStoredMission(udg_GameCache,I2S(H2I(u)))
        call RemoveUnit(u)
        call GroupRemoveUnit(udg_enumGrp,u)
    endloop
endfunction

function InitTrig_CleanupUselessConvoys takes nothing returns nothing
    set gg_trg_CleanupUselessConvoys = CreateTrigger()
    call TriggerRegisterTimerEvent(gg_trg_CleanupUselessConvoys,1,true)
    call TriggerAddAction(gg_trg_CleanupUselessConvoys,function CleanupUselessConvoys)
endfunction

countryboy · May 17, 2008

um ty so much im kinda overwelmed ill get back after i fully read

countryboy · May 17, 2008

how do find ids of all things

PurplePoot · May 17, 2008

In the Object Editor, press Control+D, then before their name on the left there will be a four-digit ID (or maybe two, for custom abilities).

The one for units, and the one that starts with A0 for abilities are the right ones.

countryboy · May 17, 2008

thank you if I have any questions I'll reply

countryboy · May 17, 2008

um what ability is used to make the trade route

PurplePoot · May 18, 2008

Any unit-targeted ability that can only target the target building type.

countryboy · May 18, 2008

so like storm hammer set to only buildings?

PurplePoot · May 18, 2008

Well actually, set to some property only that specific building has.

You could always let it target all buildings and I could just add a check to make sure it's the right one, if you want.

countryboy · May 18, 2008

hmmm im getting no where can you do me big favor? ill give you my map and can you put it in it. then ill try to learn from that.

PurplePoot · May 18, 2008

Sure, PM me a link to the map in the pastebin, and also outline what exactly you need me to do.

countryboy · Jun 9, 2008

Did it work????????????????????

moveing goods trigger help

Similar threads